ムービークリップの例：RuntimeAssetsExplorer

エクスプローラーで正しく SWF ライブラリを操作できるようにするには、ランタイムアセットライブラリの構造を形式化する必要があります。 構造を形式化するには、インタフェースを作成します。これはメソッドの設計図であり、目的の構造を定義するという点ではクラスに似ていますが、メソッド本体は提供しない点がクラスとは異なります。インターフェイスを使用すると、ランタイムライブラリとエクスプローラーが相互にやり取りできます。 ブラウザーにロードされるランタイムアセットの SWF はそれぞれ、このインターフェイスを実装します。 インターフェイスとその利便性について詳しくは、『 ActionScript 3.0 の学習 』のインターフェイスに関する内容を参照してください。

RuntimeLibrary インターフェイスは非常にシンプルです。必要なのは、書き出されるシンボルのクラスパスの配列をエクスプローラーに提供でき、ランタイムライブラリで使用可能な関数だけです。このため、インタフェースには getAssets() というメソッドだけを含めます。

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

RuntimeLibrary インタフェースを定義すると、別の SWF ファイルにロード可能な複数のアセットライブラリ SWF ファイルを作成できます。個々の SWF アセットライブラリを作成する際には、次の 4 つのタスクを実行します。

• アセットライブラリ SWF ファイルのクラスを作成する

• ライブラリを含む各アセットのクラスを作成する

• 実際のグラフィックアセットを作成する

• グラフィックエレメントにクラスを関連付けて、ライブラリ SWF をパブリッシュする

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

必要な最後の機能は、アセットエクスプローラーのユーザーインターフェイスです。 この例では、ランタイムライブラリのパスは、 ASSETS_PATH という名前の変数としてハードコードされています。また、FileReference クラスを使用して、ハードドライブ上の特定の SWF ファイルを参照するインターフェイスの作成などを行うこともできます。

ランタイムライブラリが正常にロードされると、 runtimeAssetsLoadComplete() メソッドが呼び出されます。

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

このメソッドでは、rl 変数はロードされた SWF ファイルを示します。 このコードでは、ロードされた SWF ファイルの getAssets() メソッドを呼び出して、使用可能なアセットのリストを取得しています。その後、 populateDropDown() メソッドを呼び出し、使用可能なアセットのリストを使用して ComboBox コンポーネントを指定しています。このメソッドに各アセットの完全なクラスパスが保存されます。 ユーザーインタフェースの「追加」ボタンをクリックすると、 addAsset() メソッドがトリガーされます。

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

これにより、現在 ComboBox で選択しているアセットのクラスパスが取得され（ assetNameCbo.selectedItem.data ）、flash.utils パッケージから getDefinitionByName() 関数を使用して、アセットのクラスに対する実際の参照が入手され、そのアセットの新規インスタンスが作成されます。