Assemblage et transformation d’objets XML

Flash Player 9 et les versions ultérieures, Adobe AIR 1.0 et les versions ultérieures

Utilisez la méthode prependChild() ou appendChild() pour ajouter une propriété au début ou à la fin de la liste des propriétés d’un objet XML, comme indiqué dans l’exemple suivant :

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Utilisez la méthode insertChildBefore() ou insertChildAfter() pour ajouter une propriété avant ou après une propriété spécifiée, comme suit :

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Comme indiqué dans l’exemple suivant, vous pouvez également utiliser des accolades ( { et } ) pour transmettre des données par référence (à partir d’autres variables) lorsque vous construisez des objets XML :

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Vous pouvez affecter des propriétés et des attributs à un objet XML à l’aide de l’opérateur = , comme dans l’exemple suivant :

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Ceci définit l’objet XML x de la façon suivante :

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Vous pouvez utiliser les opérateurs + et += pour concaténer des objets XMLList :

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Ceci définit l’objet XMLList xList de la façon suivante :

<a>test1</a> 
<b>test2</b> 
<c>test3</c>