API intégrée au navigateur et stockée dans le fichier AIR.SWF

Outre l’utilisation du fichier badge.swf fourni dans le SDK (kit de développement logiciel), vous avez également la possibilité de créer votre propre fichier SWF pour l’utiliser dans une page de navigateur. Le fichier SWF que vous avez personnalisé peut interagir avec le moteur d’exécution de différentes façons :

• Il peut installer une application AIR. Voir Installation d’une application AIR à partir du navigateur .

• Il peut vérifier si une application AIR particulière est installée. Voir Vérification à partir d’une page Web de la présence d’une application AIR installée .

• Il peut vérifier si le moteur d’exécution est installé. Voir Vérification de la présence du moteur d’exécution .

• Il peut lancer une application AIR installée sur le système d’un utilisateur. Voir Lancement d’une application AIR installée à partir du navigateur .

Ces possibilités sont toutes fournies en appelant des API dans un fichier SWF, nommé air.swf, et hébergé sur adobe.com. air.swf. Vous pouvez personnaliser le fichier badge.swf et appeler les API air.swf à partir de votre propre fichier SWF.

En outre, un fichier SWF s’exécutant dans le navigateur peut communiquer avec une application AIR en cours d’exécution grâce à l’utilisation de la classe LocalConnection. Pour plus d’informations, voir Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs ActionScript) ou Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs HTML).

Le fichier badge.swf, qui est intégré aux kits SDK AIR et Flex, facilite l’utilisation de la fonctionnalité d’installation transparente. Ce fichier peut installer le moteur d’exécution et une application AIR à partir d’un lien dans une page Web. Le fichier badge.swf et son code source vous sont fournis pour que vous en assuriez la distribution sur votre site Web.

Vous pouvez créer votre propre fichier SWF, il sert à utiliser les API dans le fichier air.swf pour interagir avec le moteur d’exécution et les applications AIR depuis une page Web affichée dans un navigateur. Le fichier air.swf est hébergé à l’adresse suivante http://airdownload.adobe.com/air/browserapi/air.swf. Pour référencer les API du fichier air.swf à partir de votre fichier SWF, chargez le fichier air.swf dans le même domaine d’application que celui de votre fichier SWF. Le code suivant illustre un exemple de chargement du fichier air.swf dans le domaine d’application du fichier SWF chargeant.

var airSWF:Object; // This is the reference to the main class of air.swf 
var airSWFLoader:Loader = new Loader(); // Used to load the SWF 
var loaderContext:LoaderContext = new LoaderContext();  
                                // Used to set the application domain  
 
loaderContext.applicationDomain = ApplicationDomain.currentDomain; 
 
airSWFLoader.contentLoaderInfo.addEventListener(Event.INIT, onInit); 
airSWFLoader.load(new URLRequest("http://airdownload.adobe.com/air/browserapi/air.swf"),  
                    loaderContext); 
 
function onInit(e:Event):void  
{ 
    airSWF = e.target.content; 
}

Une fois le fichier air.swf chargé (lorsque l’objet contentLoaderInfo de l’objet chargeur Loader distribue l’événement init ), vous pouvez appeler n’importe quelle API du fichier air.swf, comme indiqué ci-après.

Un fichier SWF peut vérifier si le moteur d’exécution est installé en appelant la méthode getStatus( ) dans le fichier air.swf chargé à partir de http://airdownload.adobe.com/air/browserapi/air.swf. Pour plus d’informations, voir Chargement du fichier air.swf .

Une fois le fichier air.swf chargé, le fichier SWF peut appeler la méthode getStatus( ) du fichier air.swf, comme suit :

var status:String = airSWF.getStatus();

La méthode getStatus() renvoie une des valeurs de chaîne suivantes en fonction de l’état du moteur d’exécution sur l’ordinateur :

La méthode getStatus() renvoie une erreur si la version requise de Flash Player (version 9 mise à jour 3 ou ultérieure sous Windows et Mac OS, ou version 10 sous Linux) n’est pas installée dans le navigateur.

Un fichier SWF peut vérifier si une application AIR (avec un ID d’application et un ID d’éditeur correspondants) est installée en appelant la méthode getApplicationVersion( ) dans le fichier air.swf chargé à partir de http://airdownload.adobe.com/air/browserapi/air.swf. Pour plus d’informations, voir Chargement du fichier air.swf .

Une fois le fichier air.swf chargé, le fichier SWF peut appeler la méthode getApplicationVersion( ) du fichier air.swf comme suit :

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
airSWF.getApplicationVersion(appID, pubID, versionDetectCallback); 
 
function versionDetectCallback(version:String):void 
{ 
    if (version == null) 
    { 
        trace("Not installed."); 
        // Take appropriate actions. For instance, present the user with 
        // an option to install the application. 
    } 
    else 
    { 
        trace("Version", version, "installed."); 
        // Take appropriate actions. For instance, enable the 
        // user interface to launch the application. 
    } 
}

La méthode getApplicationVersion() possède les paramètres suivants :

La méthode getApplicationVersion() renvoie une erreur si la version requise de Flash Player (version 9 mise à jour 3 ou ultérieure sous Windows et Mac OS, ou version 10 sous Linux) n’est pas installée dans le navigateur.

Un fichier SWF peut installer une application AIR en appelant la méthode installApplication() dans le fichier air.swf chargé à partir de http://airdownload.adobe.com/air/browserapi/air.swf . Pour plus d’informations, voir Chargement du fichier air.swf .

Une fois le fichier air.swf chargé, le fichier SWF peut appeler la méthode installApplication() du fichier air.swf comme suit :

var url:String = "http://www.example.com/myApplication.air"; 
var runtimeVersion:String = "1.0"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.installApplication(url, runtimeVersion, arguments); 

La méthode installApplication() installe l’application spécifiée sur l’ordinateur de l’utilisateur. Cette méthode est dotée des paramètres suivants :

La méthode installApplication() ne peut fonctionner que lorsqu’elle est appelée dans le gestionnaire d’événement pour un événement utilisateur, tel qu’un clic de souris.

La méthode installApplication() renvoie une erreur si la version requise de Flash Player (version 9 mise à jour 3 ou ultérieure sous Windows et Mac OS, ou version 10 sous Linux) n’est pas installée dans le navigateur.

Sous Mac OS, l’utilisateur doit détenir les droits système appropriés lui permettant d’installer une version de mise à jour d’une application dans le répertoire de cette application (et de privilèges d’administration si l’application met à jour le moteur d’exécution). S’il utilise Windows, l’utilisateur doit détenir des privilèges d’administration.

Vous pouvez également appeler la méthode getApplicationVersion() du fichier air.swf pour vérifier si une application est déjà installée. Vous avez le choix d’appeler cette méthode avant que la procédure d’installation de l’application débute, ou après le démarrage de l’installation. Pour plus d’informations, voir Vérification à partir d’une page Web de la présence d’une application AIR installée . Dès qu’elle est exécutée, l’application peut communiquer avec le contenu SWF dans le navigateur en utilisant la classe LocalConnection. Pour plus d’informations, voir Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs ActionScript) ou Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs HTML).

Pour utiliser la fonctionnalité d’appel du navigateur (lui permettant d’être lancé à partir du navigateur), le fichier descripteur d’application de l’application cible doit comporter le paramètre suivant :

<allowBrowserInvocation>true</allowBrowserInvocation>

Pour plus d’informations sur le fichier descripteur d’application, voir Fichiers descripteurs d’applications AIR .

Un fichier SWF présent dans le navigateur peut lancer une application AIR en appelant la méthode launchApplication() dans le fichier air.swf chargé à partir de http://airdownload.adobe.com/air/browserapi/air.swf. Pour plus d’informations, voir Chargement du fichier air.swf .

Une fois le fichier air.swf chargé, le fichier SWF peut appeler la méthode launchApplication() du fichier air.swf comme suit :

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.launchApplication(appID, pubID, arguments);

La méthode launchApplication() est définie au niveau supérieur du fichier air.swf (qui est chargé dans le domaine d’application du fichier SWF de l’interface utilisateur). Le fait d’appeler cette méthode déclenche le lancement de l’application spécifiée par AIR (si cette application est installée et si l’appel du navigateur est autorisé, par le biais du paramètre allowBrowserInvocation dans le fichier descripteur de l’application). Cette méthode prend en charge les paramètres suivants :

La méthode launchApplication() ne peut fonctionner que lorsqu’elle est appelée dans le gestionnaire d’événement pour un événement utilisateur, tel qu’un clic de souris.

La méthode launchApplication() renvoie une erreur si la version requise de Flash Player (version 9 mise à jour 3 ou ultérieure sous Windows et Mac OS, ou version 10 sous Linux) n’est pas installée dans le navigateur.

Si l’élément allowBrowserInvocation est défini sur false dans le fichier descripteur de l’application, l’appel de la méthode launchApplication() n’a aucune incidence.

Avant de présenter l’interface utilisateur pour lancer l’application, il est peut-être préférable d’appeler la méthode getApplicationVersion() dans le fichier air.swf. Pour plus d’informations, voir Vérification à partir d’une page Web de la présence d’une application AIR installée .

Lorsque l’application est invoquée par le biais de la fonctionnalité d’appel du navigateur, l’objet NativeApplication de l’application distribue un objet BrowserInvokeEvent. Pour plus d’informations, voir Appel d’une application AIR à partir du navigateur (développeurs ActionScript) ou Appel d’une application AIR à partir du navigateur (développeurs HTML).

Si vous utilisez la fonction d’appel du navigateur, tenez compte des implications au niveau de la sécurité. Ces implications sont décrites dans Appel d’une application AIR à partir du navigateur (développeurs ActionScript) et Appel d’une application AIR à partir du navigateur (développeurs HTML).

Dès qu’elle est exécutée, l’application peut communiquer avec le contenu SWF dans le navigateur en utilisant la classe LocalConnection. Pour plus d’informations, voir Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs ActionScript) ou Communications avec d’autres occurrences de Flash Player et d’AIR (développeurs HTML).