Ejemplo de XML en ActionScript: Carga de datos RSS desde Internet

La clase RSSParser incluye un método xmlLoaded() que convierte los datos RSS de entrada, almacenados en la variable rssXML , en una cadena que contiene la salida en formato HTML, rssOutput .

Casi al principio del método, el código establece el espacio de nombres XML predeterminado si el origen de datos RSS incluye un espacio de nombres predeterminado:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

Las líneas siguientes recorren el contenido del origen de datos XML, examinando cada propiedad descendente denominada item :

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

Las tres primeras líneas son simplemente un conjunto de variables de cadena para representar las propiedades de título, descripción y vínculo de la propiedad item de los datos XML. A continuación, la siguiente línea llama al método buildItemHTML() para obtener datos HTML en forma de objeto XMLList, utilizando las tres nuevas variables de cadena como parámetros.

Los datos HTML (un objeto XMLList) tienen la siguiente forma:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

Las primeras líneas del método borran el espacio de nombres XML predeterminado:

default xml namespace = new Namespace();

La directiva default xml namespace tiene ámbito de nivel de bloque de función. Esto significa que el ámbito de esta declaración es el método buildItemHTML() .

Las líneas siguientes crean el objeto XMLList basándose en los argumentos de cadena pasados a la función:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Este objeto XMLList representa una cadena datos adecuada para un campo de texto HTML de ActionScript.

El método xmlLoaded() utiliza el valor devuelto por el método buildItemHTML() y lo convierte en una cadena:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

El método xmlLoaded() establece una variable de cadena rssTitle a partir de la información de los datos XML RSS de origen:

rssTitle = rssXML.channel.title.toString();

Por último, el método xmlLoaded() genera un evento, que notifica a la aplicación que los datos ha sido analizados y están disponibles:

            dataWritten = new Event("dataWritten", true);