Visualización de ventanas a pantalla completa

Adobe AIR 1.0 y posterior

Al establecer la propiedad displayState de la clase Stage como StageDisplayState.FULL_SCREEN_INTERACTIVE la ventana pasa a modo de pantalla completa. La acción del teclado sí esta permitida en este modo. (En contenido SWF ejecutado en un navegador, no está permitida la acción del teclado). Para salir del modo de pantalla completa, el usuario debe pulsar la tecla Esc.

Nota: algunos administradores de ventanas de Linux no cambiarán las dimensiones de la ventana para que se rellene la pantalla si se establece un tamaño máximo para la ventana (aunque se elimina el fondo cromático del sistema de la ventana).

Por ejemplo, el siguiente código de Flex define una aplicación sencilla de AIR que configura un terminal simple a pantalla completa: 

<?xml version="1.0" encoding="utf-8"?> 
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"  
    layout="vertical"  
    applicationComplete="init()" backgroundColor="0x003030" focusRect="false"> 
    <mx:Script> 
        <![CDATA[ 
            private function init():void  
            { 
                stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE; 
                focusManager.setFocus(terminal); 
                terminal.text = "Welcome to the dumb terminal app. Press the ESC key to exit..\n"; 
                terminal.selectionBeginIndex = terminal.text.length; 
                terminal.selectionEndIndex = terminal.text.length; 
            } 
        ]]> 
    </mx:Script> 
    <mx:TextArea  
        id="terminal"  
        height="100%" width="100%"  
        scroll="false" 
        backgroundColor="0x003030"  
        color="0xCCFF00"  
        fontFamily="Lucida Console"  
        fontSize="44"/> 
</mx:WindowedApplication>

El siguiente ejemplo de ActionScript para Flash simula un terminal simple de texto a pantalla completa: 

    import flash.display.Sprite; 
    import flash.display.StageDisplayState; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
     
    public class FullScreenTerminalExample extends Sprite 
    { 
        public function FullScreenTerminalExample():void  
        { 
            var terminal:TextField = new TextField(); 
            terminal.multiline = true; 
            terminal.wordWrap = true; 
            terminal.selectable = true; 
            terminal.background = true; 
            terminal.backgroundColor = 0x00333333; 
             
            this.stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE; 
             
            addChild(terminal); 
            terminal.width = 550; 
            terminal.height = 400; 
             
            terminal.text = "Welcome to the dumb terminal application. Press the ESC key to exit.\n_"; 
             
            var tf:TextFormat = new TextFormat(); 
            tf.font = "Courier New"; 
            tf.color = 0x00CCFF00; 
            tf.size = 12; 
            terminal.setTextFormat(tf); 
             
            terminal.setSelection(terminal.text.length - 1, terminal.text.length); 
        } 
    }