Aspectos básicos del flujo de trabajo de contenido protegido

En los siguientes pasos se describe el flujo de trabajo para precargar la licencia de un archivo multimedia protegido mediante un objeto DRMContentData.

1. Obtenga los metadatos binarios del contenido empaquetado. Si utiliza Flash Access Java Reference Packager, este archivo de metadatos se genera automáticamente con la extensión .metadata. Puede, por ejemplo, descargar estos metadatos mediante la clase URLLoader.

2. Cree un objeto DRMContentData pasando los metadatos a la función constructora:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. El resto de los pasos son idénticos a los del flujo de trabajo descrito en Aspectos básicos del flujo de trabajo de contenido protegido.

Los siguientes pasos describen el flujo de trabajo para realizar la carga previa de la licencia para un archivo multimedia protegido por DRM usando preloadEmbeddedMetadata():

1. Descargue y almacene el archivo. (Los metadatos DRM sólo se pueden precargar desde archivos almacenados localmente.)

2. Cree los objetos NetConnection y NetStream, proporcionando implementaciones para las funciones callback onDRMContentData() y onPlayStatus() del objeto cliente NetStream.

3. Cree un objeto NetStreamPlayOptions y establezca la propiedad stream en la URL del archivo de medios local.

4. Llame al método preloadEmbeddedMetadata() de NetStream, transmitiendo el objeto NetStreamPlayOptions e identificando el archivo de medios para analizar.

5. Si el archivo contiene metadatos DRM, se invoca la función callback onDRMContentData(). Los metadatos se transmiten a esta función como un objeto DRMContentData.

6. Utilice el objeto DRMContentData para obtener la licencia utilizando el método loadVoucher() de DRMManager.

   Si el valor de la propiedad authenticationMethod del objeto DRMContentData es userNameAndPassword, debe autenticar al usuario en el servidor de derechos multimedia antes de cargar la licencia. Las propiedades serverURL y domain del objeto DRMContentData se pueden transmitir al método authenticate(), junto con las credenciales del usuario.

7. La función onPlayStatus() se invoca cuando el análisis del archivo ha finalizado. Si la función onDRMContentData() no se ha llamado, el archivo no contiene los metadatos necesarios para obtener una licencia. La ausencia de esta llamada también puede querer decir que Flash Access no protege este archivo.

El siguiente ejemplo de código para AIR muestra cómo precargar una licencia para un archivo multimedia local:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}