(Deprecated) Guide Layout Controls and Field Controls

You can create a button object that displays the first panel in the Guide, when a Guide filler clicks it at runtime. When the Guide renders, a button labeled First is inactive, and the user cannot click the button. After the user navigates to another panel in the Guide, the First button becomes active and the user can click it. Clicking the First button displays the first panel in the Guide.

package com.adobe.guides.controls 
{ 
    import mx.controls.Button; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 
    import ga.model.GAEvent; 
    import ga.model.PanelManager; 
 
    public class FirstPanelButton extends Button 
    { 
 
        // The PanelManager class controls the organization and behavior 
        // of panel instances at runtime. The class contains 
        // convenience properties and methods that are useful for  
        // manipulating panels within a Guide. 
        private var _pm:PanelManager; 
         
        protected override function createChildren():void   
        { 
            super.createChildren(); 
            this.label = "First"; 
            _pm = PanelManager.instance; 
 
            // Adds event listeners for the three events that can cause a 
            // change in the state of this button, and reevaluates if the button 
            // should display as enabled. 
            _pm.addEventListener(GAEvent.PAGE_SELECTION_CHANGE, pageChange); 
            _pm.addEventListener(GAEvent.PAGE_REMOVE, pageChange); 
            _pm.addEventListener(GAEvent.PAGE_ADD, pageChange); 
 
            // Sets the default behavior when the Guide renders. In this 
            // case, on the initial panel, the button should be dimmed. 
            super.enabled = false; 
        } 
 
        // When the button is clicked by a user, the current panel displayed 
        // is set to be the first panel in the Guide. 
        override protected function clickHandler(event:MouseEvent):void  
        {  
            if (super.enabled)  
            {  
                _pm.currentPage = _pm.firstPage; 
            }  
        } 
 
        // Conditionally sets the button's enabled property dependent on 
        // whether the current panel is the first panel in the Guide. 
        private function pageChange(event:Event):void  
        {  
            super.enabled = _pm.previousPage!=null; 
        } 
    } 
}

When creating custom navigation controls, be aware of the methods and properties of the PanelManager class. (See ActionScript Language Reference.)

You can create a button object that displays the last panel in the Guide, when the Guide filler clicks it at runtime. When the Guide renders, a button labeled Last is displayed. Clicking the button displays the last panel in the Guide.If the Guide filler is on the last panel of the Guide, the Last button is dimmed and the user cannot click it.

package com.adobe.guides.controls 
{ 
    import mx.controls.Button; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 
    import ga.model.GAEvent; 
    import ga.model.PanelManager; 
 
    public class LastPanelButton extends Button 
    { 
        // The PanelManager class controls the organization and behavior 
        // of panel instances at runtime. The class contains 
        // convenience properties and methods that are useful for  
        // manipulating panels within a Guide. 
        private var _pm:PanelManager; 
         
        protected override function createChildren():void   
        { 
            super.createChildren(); 
            this.label = "Last"; 
            _pm = PanelManager.instance; 
 
            // Adds event listeners for the three events that can cause a 
            // change in the state of this button, and reevaluates whether 
            // the button should display as enabled. 
            _pm.addEventListener(GAEvent.PAGE_SELECTION_CHANGE, pageChange); 
            _pm.addEventListener(GAEvent.PAGE_REMOVE, pageChange); 
            _pm.addEventListener(GAEvent.PAGE_ADD, pageChange); 
 
            // Sets the default behavior when the Guide renders. In this 
            // case, on the initial panel, the button should be disabled. 
            super.enabled = true; 
        } 
 
        // When the button is clicked by a user, the current panel displayed 
        // is set to be the last panel in the Guide. 
        override protected function clickHandler(event:MouseEvent):void  
        {  
            if (super.enabled)  
            {  
                _pm.currentPage = _pm.lastPage; 
            }  
        } 
 
        // Conditionally sets the button's enabled property dependent on 
        // whether the current panel is the last panel in the Guide. 
        private function pageChange(event:Event):void  
        {  
            super.enabled = _pm.nextPage!=null; 
        } 
    } 
}

You can create an HSlider control for mapping Guide items. This control assumes that the original Guide item specifies integer values from 0 through 100 that indicate a percentage.

When the Guide renders, an HSlider control replaces the original Guide item. The HSlider has the same caption as the original Guide item. The Guide filler can drag the slider to set a value from 0 through 100.

When the Guide filler switches to the PDF form, the value that they set with the slider appears in the corresponding field. If they change the value on the PDF form and then return to the Guide, the slider value updates.

package com.adobe.guides.controls 
{ 
    import mx.controls.HSlider; 
 
    public class CustomHSlider extends HSlider  
    { 
 
        protected override function createChildren():void   
        { 
            super.createChildren(); 
 
            // Sets the minimum, maximum, and initial values for the range. 
            this.minimum = 0; 
            this.maximum = 100; 
            this.value = 0; 
 
            // The increment range for the slider, and the increments for the 
            // increment label. 
            this.snapInterval = 1; 
            this.tickInterval = 10; 
 
            // The label for the range represented by the slider. 
            this.labels=['0%', '100%']; 
 
            // Sets interaction properties allowing the slider to update in 
            //real-time in response to user interaction. 
            this.allowTrackClick = true; 
            this.liveDragging = true;  
        } 
    } 
}