NetStatusEvent  - AS3

An object with properties that describe the object's status or error condition.

The information object could have a code property containing a string that represents a specific event or a level property containing a string that is either "status" or "error".

The information object could also be something different. The code and level properties might not work for some implementations and some servers might send different objects.

P2P connections send messages to a NetConnection with a stream parameter in the information object that indicates which NetStream the message pertains to.

For example, Flex Data Services sends Message objects that cause coercion errors if you try to access the code or level property.

The following table describes the possible string values of the code and level properties.

If you consistently see errors regarding the buffer, try changing the buffer using the NetStream.bufferTime property.

Related API Elements

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Creates an Event object that contains information about netStatus events. Event objects are passed as parameters to event listeners.

Related API Elements

Creates a copy of the NetStatusEvent object and sets the value of each property to match that of the original.

Returns a string that contains all the properties of the NetStatusEvent object. The string is in the following format:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Defines the value of the type property of a netStatus event object.

This event has the following properties:

Related API Elements

In this example, the netStatusHandler method is registered as a listener for the NetStatusEvent event NetConnection.netStatus. When the status (success or failure) of the NetConnection.connect() attempt is determined, the netStatus event triggers this method. If the attempt to connect to the NetConnection object is successful (in other words, if the info property of the NetStatusEvent object dispatched by the netStatus event has a code property that indicates success), the code creates the Video and NetStream objects and calls the Video.attachNetStream() and NetStream.play() methods.

Note: To run this example, you need an FLV file whose name and location match the variable passed to videoURL; in this case, an FLV file called Video.flv that is in the same directory as the SWF file.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }