Nachdem Sie über eine Reihe von IGraphicsData-Instanzen verfügen, verwenden Sie
drawGraphicsData()
-Methoden der Graphics-Klasse, um die Grafiken darzustellen. Die
drawGraphicsData()
-Methode führt nacheinander mehrere Zeichnungsanweisungen eines Vektors von IGraphicsData-Instanzen aus:
// stroke object
var stroke:GraphicsStroke = new GraphicsStroke(3);
stroke.joints = JointStyle.MITER;
stroke.fill = new GraphicsSolidFill(0x102020);// solid stroke
// fill object
var fill:GraphicsGradientFill = new GraphicsGradientFill();
fill.colors = [0x0000FF, 0xEEFFEE];
fill.matrix = new Matrix();
fill.matrix.createGradientBox(70, 70, Math.PI/2);
// path object
var path:GraphicsPath = new GraphicsPath(new Vector.<int>(), new Vector.<Number>());
path.commands.push(GraphicsPathCommand.MOVE_TO, GraphicsPathCommand.LINE_TO, GraphicsPathCommand.LINE_TO);
path.data.push(125,0, 50,100, 175,0);
// combine objects for complete drawing
var drawing:Vector.<IGraphicsData> = new Vector.<IGraphicsData>();
drawing.push(stroke, fill, path);
// draw the drawing
graphics.drawGraphicsData(drawing);
Indem Sie einen Wert im Pfad, der von der Zeichnung verwendet wird, ändern, kann die Form mehrere Male neu gezeichnet werden, um ein komplexeres Bild zu erstellen:
// draw the drawing multiple times
// change one value to modify each variation
graphics.drawGraphicsData(drawing);
path.data[2] += 200;
graphics.drawGraphicsData(drawing);
path.data[2] -= 150;
graphics.drawGraphicsData(drawing);
path.data[2] += 100;
graphics.drawGraphicsData(drawing);
path.data[2] -= 50;graphicsS.drawGraphicsData(drawing);
IGraphicsData-Objekte können zwar Füll- und Strichstile definieren, diese Stile sind jedoch nicht unbedingt erforderlich. Anders ausgedrückt lassen sich Methoden der Graphics-Klasse verwenden, um Stile festzulegen, während IGraphicsData-Objekte verwendet werden, um eine gespeicherte Sammlung von Pfaden zu zeichnen oder umgekehrt.
Hinweis:
Verwenden Sie die
Graphics.clear()
-Methode, um eine vorherige Zeichnung zu löschen, bevor eine neue begonnen wird, es sei denn, Sie fügen der Originalzeichnung etwas hinzu wie im Beispiel oben. Wenn Sie einen Teil eines Pfades oder einer Sammlung von IGraphicsData-Objekten ändern, zeichnen Sie die gesamte Zeichnung neu, um die Änderungen zu sehen.
Wenn Sie Graphics-Datenklassen verwenden, wird die Füllung dargestellt, wenn drei oder mehr Punkte gezeichnet werden, da die Form an diesem Punkt inherent geschlossen ist. Auch wenn die Füllung geschlossen wird, wird es der Strich nicht. Dieses Verhalten unterscheidet sich von der Verwendung der Befehle
Graphics.lineTo()
oder
Graphics.moveTo()
.
