Beispiel für reguläre Ausdrücke: Wiki-Parser

Die WikiParser-Klasse enthält Methoden zum Konvertieren von Wiki-Eingabetext in die entsprechende HTML-Ausgabe. Dies ist keine sehr stabile Anwendung für die Wiki-Konvertierung. Mit dieser Anwendung werden jedoch einige nützliche Einsatzmöglichkeiten von regulären Ausdrücken zum Suchen nach Übereinstimmungen mit Mustern und zum Konvertieren von Strings veranschaulicht.

Die Konstruktorfunktion in Verbindung mit der setWikiData() -Methode initialisiert wie folgt einen Beispielstring für den Wiki-Eingabetext:

public function WikiParser() 
{ 
    wikiData = setWikiData(); 
}

Wenn der Benutzer in der Beispielanwendung auf die Schaltfläche „Test“ klickt, wird die parseWikiString() -Methode des WikiParser-Objekts aufgerufen. In dieser Methode werden mehrere andere Methoden aufgerufen, mit denen der resultierende HTML-String zusammengesetzt wird.

public function parseWikiString(wikiString:String):String 
{ 
    var result:String = parseBold(wikiString); 
    result = parseItalic(result); 
    result = linesToParagraphs(result); 
    result = parseBullets(result); 
    return result; 
}

Bei jeder der aufgerufenen Methoden – parseBold() , parseItalic() , linesToParagraphs() und parseBullets() – werden die durch einen regulären Ausdruck definierten übereinstimmenden Muster mit der replace() -Methode des Strings ersetzt, sodass der Wiki-Eingabetext in Text im HTML-Format umgewandelt wird.

private function parseBold(input:String):String 
{ 
    var pattern:RegExp = /'''(.*?)'''/g; 
    return input.replace(pattern, "<b>$1</b>"); 
}

private function parseItalic(input:String):String 
{ 
    var pattern:RegExp = /''(.*?)''/g; 
    return input.replace(pattern, "<i>$1</i>"); 
}

private function parseBullets(input:String):String 
{ 
    var pattern:RegExp = /^\*(.*)/gm; 
    return input.replace(pattern, "<li>$1</li>"); 
}

var pattern:RegExp = /^$/gm; 
var result:String = input.replace(pattern, "");

Wenn der Benutzer in der Beispielanwendung auf die Schaltfläche „Test“ klickt und zuvor das Kontrollkästchen „ urlToATag aktiviert hat, wird die statische URLParser.urlToATag() -Methode aufgerufen, um URL-Strings aus dem Wiki-Eingabestring in <a> -HTML-Tags umzuwandeln.

var protocol:String = "((?:http|ftp)://)"; 
var urlPart:String = "([a-z0-9_-]+\.[a-z0-9_-]+)"; 
var optionalUrlPart:String = "(\.[a-z0-9_-]*)"; 
var urlPattern:RegExp = new RegExp(protocol + urlPart + optionalUrlPart, "ig"); 
var result:String = input.replace(urlPattern, "<a href='$1$2$3'><u>$1$2$3</u></a>");

Mithilfe der RegExp() -Konstruktorfunktion wird ein regulärer Ausdruck ( urlPattern ) aus mehreren Bestandteilen gebildet. Diese Bestandteile sind alle Strings, mit denen Teile des regulären Ausdrucks definiert werden.

Der erste Teil des regulären Ausdrucks, der durch den protocol -String definiert wird, legt ein URL-Protokoll fest: http:// oder ftp:// . Mit den Klammern wird eine nicht zwischengespeicherte Gruppe festgelegt, die durch das ? -Symbol angegeben wird. Dies bedeutet, dass die Klammern nur zum Definieren einer Gruppe für das | -Auswahlmuster verwendet werden. Die Gruppe entspricht keinem der Rückverweiscodes ( $1 , $2 , $3 ) im Ersetzungsstring der replace() -Methode.

Die anderen Bestandteile des regulären Ausdrucks verwenden jeweils zwischengespeicherte Gruppen (angegeben durch Klammern im Muster), die dann in den Rückverweiscodes ( $1 , $2 , $3 ) im Ersetzungsstring der replace() -Methode verwendet werden.

Der Teil des Musters, der über den urlPart -String definiert wird, entspricht mindestens einem der folgenden Zeichen: a-z , 0-9 , _ oder - . Mit dem + -Quantifizierer wird angegeben, dass mindestens eines dieser Zeichen übereinstimmen muss. Mit \. wird ein erforderlicher Punkt ( . ) angegeben. Der restliche Teil entspricht einem anderen String mit mindestens einem der folgenden Zeichen: a-z , 0-9 , _ oder - .

Der Teil des Musters, der über den optionalUrlPart -String definiert wird, entspricht keinem, einem oder mehreren der folgenden Zeichen: einem Punkt ( . ), gefolgt von einer beliebigen Anzahl alphanumerischer Zeichen (einschließlich _ und - ). Mit dem * -Quantifizierer wird angegeben, dass nach Übereinstimmungen mit keinem, einem oder mehreren dieser Zeichen gesucht wird.

Beim Aufrufen der replace() -Methode wird der reguläre Ausdruck verwendet und der HTML-Ersetzungsstring über Rückverweise zusammengesetzt.

Mit der urlToATag() -Methode wird dann die emailToATag() -Methode aufgerufen, mit der auf ähnliche Weise E-Mail-Muster durch <a> -Tags für Hyperlinkstrings ersetzt werden. Die regulären Ausdrücke für die Entsprechung mit HTTP-, FTP- und E-Mail-URLs in dieser Beispieldatei sind relativ einfach gehalten. Es sind sehr viel kompliziertere reguläre Ausdrücke für die korrekte Suche nach diesen URLs erforderlich.

Wenn der Benutzer in der Beispielanwendung auf die Schaltfläche „Test“ klickt und zuvor das Kontrollkästchen dollarToEuro aktiviert hat, wird die statische CurrencyConverter.usdToEuro() -Methode aufgerufen, um US-Dollar-Strings (z. B. „$9.95" ) wie folgt in Euro-Strings (z. B. „8.24 €" ) umzuwandeln:

var usdPrice:RegExp = /\$([\d,]+.\d+)+/g; 
return input.replace(usdPrice, usdStrToEuroStr); 

In der ersten Zeile ist ein einfaches Muster für US-Dollar-Strings definiert. Beachten Sie, dass dem $ -Zeichen ein umgekehrter Schrägstrich ( \ ) als Escape-Zeichen vorangestellt ist.

Die replace() -Methode verwendet den regulären Ausdruck zum Suchen von Mustern und ruft die usdStrToEuroStr() -Funktion auf, um den Ersetzungsstring zu ermitteln (ein Wert in Euro).

Wenn als zweiter Parameter der replace() -Methode der Name einer Funktion verwendet wird, werden folgende Elemente als Parameter an die aufgerufene Funktion übergeben:

• Der übereinstimmende Teil des Strings

• Alle übereinstimmenden zwischengespeicherten (in Klammern eingeschlossenen) Gruppen. Die Anzahl der auf diese Weise übergebenen Argumente hängt von der Anzahl der Übereinstimmungen mit einer zwischengespeicherten Gruppe ab. Sie können die Anzahl der Übereinstimmungen mit zwischengespeicherten Gruppen ermitteln, indem Sie im Funktionscode arguments.length - 3 überprüfen.

• Die Indexposition im String, an der die Übereinstimmung beginnt.

• Der vollständige String.

Mit der usdStrToEuroStr() -Methode werden US-Dollar-Strings wie folgt in Euro-Strings konvertiert:

private function usdToEuro(...args):String 
{ 
    var usd:String = args[1]; 
    usd = usd.replace(",", ""); 
    var exchangeRate:Number = 0.828017; 
    var euro:Number = Number(usd) * exchangeRate; 
    trace(usd, Number(usd), euro); 
    const euroSymbol:String = String.fromCharCode(8364); // € 
    return euro.toFixed(2) + " " + euroSymbol;  
}

Beachten Sie, dass args[1] die zwischengespeicherte Gruppe angibt, die dem regulären Ausdruck usdPrice entspricht. Dies ist der numerische Teil des US-Dollar-Strings, d. h. der Dollarbetrag ohne das $ -Zeichen. Mit der Methode wird eine Währungsumrechnung durchgeführt und der resultierende String zurückgegeben (mit einem nachgestellten €-Symbol anstelle des vorangestellten $-Symbols).