Laden von externen Daten

Viele APIs, die externe Daten laden, verwenden die URLRequest-Klasse, um die Eigenschaften der erforderlichen Netzwerkanforderung zu definieren.

Mithilfe der URLLoader-Klasse können Sie eine Anforderung an einen Server senden und auf die zurückgegebenen Informationen zugreifen. Außerdem können Sie mithilfe der URLLoader-Klasse auf Dateien im lokalen Dateisystem zugreifen, wenn der lokale Dateizugriff zulässig ist (beispielsweise in der Sandbox „local-with-filesystem“ von Flash Player oder in der Sandbox der AIR-Anwendung). Die URLLoader-Klasse lädt die Daten von einer URL als Text, Binärdaten oder URL-kodierte Variablen herunter. Die URLLoader-Klasse löst verschiedene Ereignisse aus, wie zum Beispiel complete , httpStatus , ioError , open , progress und securityError .

Das Ereignisverarbeitungsmodell in ActionScript 3.0 unterscheidet sich ganz erheblich von dem ActionScript 2.0-Modell, das die Ereignisprozeduren LoadVars.onData , LoadVars.onHTTPStatus und LoadVars.onLoad verwendet. Weitere Informationen zur Ereignisverarbeitung in ActionScript 3.0 finden Sie unter Verarbeiten von Ereignissen .

Die heruntergeladenen Daten stehen erst zur Verfügung, wenn der Download abgeschlossen ist. Sie können den Fortschritt des Downloads überwachen (geladene Byte und Byte gesamt), indem Sie auf die Auslösung des progress -Ereignisses warten. Doch wenn eine Datei sehr schnell geladen wird, wird möglicherweise kein progress -Ereignis ausgelöst. Sobald eine Datei erfolgreich heruntergeladen wurde, wird das complete -Ereignis ausgelöst. Durch Einstellen der URLLoader-Eigenschaft dataFormat können Sie festlegen, dass Daten als Text, in Form von unformatierten Binärdaten oder als URLVariables-Objekt empfangen werden.

Die URLLoader.load() -Methode (und wahlweise der Konstruktor der URLLoader-Klasse) arbeiten mit einem Parameter, request , bei dem es sich um ein URLRequest-Objekt handelt. Ein URLRequest-Objekt enthält alle Informationen einer HTTP-Anforderung, beispielsweise die Ziel-URL, die Anforderungsmethode ( GET oder POST ), zusätzliche Header-Informationen sowie den MIME-Typ.

Im folgenden Beispiel wird ein XML-Paket zu einem serverseitigen Skript hochgeladen:

var secondsUTC:Number = new Date().time; 
var dataXML:XML =  
    <clock> 
        <time>{secondsUTC}</time> 
    </clock>; 
var request:URLRequest = new URLRequest("http://www.yourdomain.com/time.cfm"); 
request.contentType = "text/xml"; 
request.data = dataXML.toXMLString(); 
request.method = URLRequestMethod.POST; 
var loader:URLLoader = new URLLoader(); 
loader.load(request); 

Mit diesem Codefragment wird ein XML-Dokument namens dataXML erstellt, welches das XML-Paket enthält, das an den Server gesendet wird. In diesem Beispiel wird die URLRequest-Eigenschaft contentType auf "text/xml" eingestellt und das XML-Dokument wird der URLRequest-Eigenschaft data zugewiesen. Abschließend erstellt das Beispiel ein URLLoader-Objekt und sendet die Anforderung über die load() -Methode an das Remote-Skript.

Die URLStream-Klasse ermöglicht den Zugriff auf die heruntergeladenen Daten direkt beim Datenempfang. Mit der URLStream-Klasse können Sie außerdem einen Stream beenden, bevor der Download abgeschlossen ist. Die heruntergeladenen Daten stehen als unformatierte Binärdaten zur Verfügung.

Verwenden Sie beim Lesen von Daten aus einem URLStream-Objekt die bytesAvailable -Eigenschaft, um festzustellen, ob vor dem Lesen ausreichend Daten zur Verfügung stehen. Eine EOFError-Ausnahme wird ausgelöst, wenn Sie versuchen, mehr Daten zu lesen als derzeit verfügbar sind.

Wenn Sie dynamische Anwendungen erstellen, kann es hilfreich sein, Daten aus externen Dateien oder aus serverseitigen Skripts zu laden. Auf diese Weise können Sie dynamische Anwendungen erstellen, ohne dass Sie Ihre Anwendung bearbeiten oder neu kompilieren müssen. Angenommen, Sie erstellen eine Anwendung „Tipp des Tages“. In diesem Fall können Sie ein serverseitiges Skript erstellen, das einen zufälligen Tipp aus einer Datenbank abruft und einmal am Tag in einer Textdatei speichert. Dann kann Ihre Anwendung die Inhalte einer statischen Textdatei laden, anstatt jedes Mal die Datenbank abzufragen.

Der folgende Codeausschnitt erstellt ein URLRequest- und ein URLLoader-Objekt, welche die Inhalte einer externen Textdatei namens „params.txt“ laden:

var request:URLRequest = new URLRequest("params.txt"); 
var loader:URLLoader = new URLLoader(); 
loader.load(request);

var request:URLRequest = new URLRequest("sendfeedback.cfm"); 
request.method = URLRequestMethod.POST;

Das externe Dokument „params.txt“, das zur Laufzeit geladen wird, enthält die folgenden Daten:

monthNames=January,February,March,April,May,June,July,August,September,October,November,December&dayNames=Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday

Die Datei enthält zwei Parameter: monthNames und dayNames . Jeder Parameter enthält eine durch Kommas getrennte Liste, die als Strings geparst wird. Sie können diese Liste mit der String.split() -Methode in einen Array aufteilen.

Vermeiden Sie das Verwenden von reservierten Wörtern oder Sprachkonstrukten in externen Datendateien, da andernfalls das Lesen und Debuggen Ihres Codes schwieriger wird.

function completeHandler(event) 
{ 
    var loader2 = event.target; 
    air.trace(loader2.data); 
}

Wenn das Remote-Dokument Name-Wert-Paare enthält, können Sie die Daten mit der URLVariables-Klasse parsen, indem Sie den Inhalt der geladenen Datei wie folgt übergeben:

private function completeHandler(event:Event):void 
{ 
    var loader2:URLLoader = URLLoader(event.target); 
    var variables:URLVariables = new URLVariables(loader2.data); 
    trace(variables.dayNames); 
}

Jedes Name-Wert-Paare aus der externen Datei wird als eine Eigenschaft im URLVariables-Objekt erstellt. Im vorausgehenden Beispiel wird jede Eigenschaft im Variablenobjekt wie ein String behandelt. Handelt es sich beim Wert des Name-Wert-Paars um eine Liste mit Elementen, können Sie den String durch Aufrufen der String.split() -Methode wie folgt in ein Array umwandeln:

var dayNameArray:Array = variables.dayNames.split(",");

Wenn Sie numerische Daten aus externen Textdateien laden, wandeln Sie die Werte mithilfe einer Funktion auf oberster Ebene, wie z. B. int() , uint() oder Number() , in numerische Werte um.

Alternativ zum Laden der Inhalte der externen Datei als String und dem Erstellen eines neuen URLVariables-Objekts können Sie die URLLoader.dataFormat -Eigenschaft auf eine der statischen Eigenschaften der URLLoaderDataFormat-Klasse einstellen. Die drei möglichen Werte der URLLoader.dataFormat -Eigenschaft lauten:

• URLLoaderDataFormat.BINARY – Die Eigenschaft URLLoader.data enthält Binärdaten, die in einem ByteArray-Objekt gespeichert sind.

• URLLoaderDataFormat.TEXT – Die Eigenschaft URLLoader.data enthält Text in einem String-Objekt.

• URLLoaderDataFormat.VARIABLES – Die Eigenschaft URLLoader.data enthält URL-kodierte Variablen, die in einem URLVariables-Objekt gespeichert sind.

Der folgende Code zeigt, wie das Einstellen der Eigenschaft URLLoader.dataFormat auf URLLoaderDataFormat.VARIABLES es Ihnen ermöglicht, geladene Daten automatisch in ein URLVariables-Objekt zu analysieren:

package 
{ 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLLoaderDataFormat; 
    import flash.net.URLRequest; 
 
    public class URLLoaderDataFormatExample extends Sprite 
    { 
        public function URLLoaderDataFormatExample() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/params.txt"); 
            var variables:URLLoader = new URLLoader(); 
            variables.dataFormat = URLLoaderDataFormat.VARIABLES; 
            variables.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                variables.load(request); 
            }  
            catch (error:Error) 
            { 
                trace("Unable to load URL: " + error); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
        var loader:URLLoader = URLLoader(event.target); 
        trace(loader.data.dayNames); 
        } 
    } 
}

Das folgende Beispiel zeigt, dass XML aus einer externen Datei auf die gleiche Weise geladen wird wie URLVariables. Sie können eine URLRequest-Instanz und eine URLLoader-Instanz erstellen, um mit ihnen ein remotes XML-Dokument herunterzuladen. Nachdem die Datei vollständig heruntergeladen wurde, wird das Event.COMPLETE -Ereignis ausgelöst, und die Inhalte der externen Datei werden in eine XML-Instanz umgewandelt, die Sie mit XML-Methoden und -Eigenschaften analysieren können.

package 
{ 
    import flash.display.Sprite; 
    import flash.errors.*; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 
 
    public class ExternalDocs extends Sprite 
    { 
        public function ExternalDocs() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/data.xml"); 
            var loader:URLLoader = new URLLoader(); 
            loader.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                loader.load(request); 
            } 
            catch (error:ArgumentError) 
            { 
                trace("An ArgumentError has occurred."); 
            } 
            catch (error:SecurityError) 
            { 
                trace("A SecurityError has occurred."); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
            var dataXML:XML = XML(event.target.data); 
            trace(dataXML.toXMLString()); 
        } 
    } 
}

Sie können die URLVariables-Klasse neben dem Laden von externen Datendateien auch zum Senden von Variablen an ein serverseitiges Skript und zum Bearbeiten der Antwort des Servers verwenden. Dies ist z. B. nützlich, wenn Sie ein Spiel programmieren und das Ergebnis des Benutzers an einen Server senden möchten, um zu berechnen, ob es zur Bestenliste hinzugefügt werden sollte, oder um die Anmeldeinformationen des Benutzers zur Validierung an einen Server zu senden. Ein serverseitiges Skript kann den Benutzernamen und das Kennwort verarbeiten, kann sie anhand einer Datenbank validieren und ggf. die Gültigkeit der vom Benutzer eingegebenen Benutzerangaben bestätigen.

Der folgende Codeausschnitt erstellt ein URLVariables-Objekt namens variables , das ein neues Objekt mit der Bezeichnung name erstellt. Als Nächstes wird ein URLRequest-Objekt erstellt, mit dem die URL des serverseitigen Skripts, an das die Variablen gesendet werden sollen, angegeben wird. Dann legen Sie mit der method -Eigenschaft des URLRequest-Objekts fest, dass die Variablen als eine POST -Anforderung von HTTP gesendet werden. Um das URLVariables-Objekt zur URL-Anforderung hinzuzufügen, stellen Sie die data -Eigenschaft des URLRequest-Objekts auf das zuvor erstellte URLVariables-Objekt ein. Daraufhin wird die URLLoader-Instanz erstellt, und die URLLoader.load() -Methode wird aufgerufen, die die Anforderung einleitet.

var variables:URLVariables = new URLVariables("name=Franklin"); 
var request:URLRequest = new URLRequest(); 
request.url = "http://www.[yourdomain].com/greeting.cfm"; 
request.method = URLRequestMethod.POST; 
request.data = variables; 
var loader:URLLoader = new URLLoader(); 
loader.dataFormat = URLLoaderDataFormat.VARIABLES; 
loader.addEventListener(Event.COMPLETE, completeHandler); 
try 
{ 
    loader.load(request); 
} 
catch (error:Error) 
{ 
    trace("Unable to load URL"); 
} 
 
function completeHandler(event:Event):void 
{ 
    trace(event.target.data.welcomeMessage); 
}

Der folgende Code enthält den Inhalt des Adobe ColdFusion®-Dokuments „greeting.cfm“, das im vorhergehenden Beispiel verwendet wurde:

<cfif NOT IsDefined("Form.name") OR Len(Trim(Form.Name)) EQ 0> 
    <cfset Form.Name = "Stranger" /> 
</cfif> 
<cfoutput>welcomeMessage=#UrlEncodedFormat("Welcome, " & Form.name)# 
</cfoutput>