In einer Musikshop-AIR-Anwendung sollen Remote-SWF-Dateien den Preis der Alben übermitteln, dabei sollen sie aber nicht angeben, ob es sich bei dem Preis um ein Sonderangebot handelt. Zu diesem Zweck stellt eine StoreAPI-Klasse eine Methode bereit, um den Preis anzugeben, der Angebotspreis wird jedoch verborgen. Eine Instanz dieser StoreAPI-Klasse wird der
parentSandboxBridge
-Eigenschaft des LoaderInfo-Objekts des Loader-Objekts, das die Remote-SWF-Datei lädt, zugewiesen.
Der Code für den AIR-Musikshop sieht folgendermaßen aus:
<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" title="Music Store" creationComplete="initApp()">
<mx:Script>
import flash.display.Loader;
import flash.net.URLRequest;
private var child:Loader;
private var isSale:Boolean = false;
private function initApp():void {
var request:URLRequest =
new URLRequest("http://[www.yourdomain.com]/PriceQuoter.swf")
child = new Loader();
child.contentLoaderInfo.parentSandboxBridge = new StoreAPI(this);
child.load(request);
container.addChild(child);
}
public function getRegularAlbumPrice():String {
return "$11.99";
}
public function getSaleAlbumPrice():String {
return "$9.99";
}
public function getAlbumPrice():String {
if(isSale) {
return getSaleAlbumPrice();
}
else {
return getRegularAlbumPrice();
}
}
</mx:Script>
<mx:UIComponent id="container" />
</mx:WindowedApplication>
Das StoreAPI-Objekt ruft die Hauptanwendung auf, um den normalen Albumpreis abzurufen, gibt jedoch „Not available“ (Nicht verfügbar) zurück, wenn die
getSaleAlbumPrice()
-Methode aufgerufen wird. Mit dem folgenden Code wird die StoreAPI-Klasse definiert:
public class StoreAPI
{
private static var musicStore:Object;
public function StoreAPI(musicStore:Object)
{
this.musicStore = musicStore;
}
public function getRegularAlbumPrice():String {
return musicStore.getRegularAlbumPrice();
}
public function getSaleAlbumPrice():String {
return "Not available";
}
public function getAlbumPrice():String {
return musicStore.getRegularAlbumPrice();
}
}
Der folgende Code stellt ein Beispiel einer PriceQuoter-SWF-Datei dar, die den Preis meldet, den Angebotspreis jedoch nicht melden kann:
package
{
import flash.display.Sprite;
import flash.system.Security;
import flash.text.*;
public class PriceQuoter extends Sprite
{
private var storeRequester:Object;
public function PriceQuoter() {
trace("Initializing child SWF");
trace("Child sandbox: " + Security.sandboxType);
storeRequester = loaderInfo.parentSandboxBridge;
var tf:TextField = new TextField();
tf.autoSize = TextFieldAutoSize.LEFT;
addChild(tf);
tf.appendText("Store price of album is: " + storeRequester.getAlbumPrice());
tf.appendText("\n");
tf.appendText("Sale price of album is: " + storeRequester.getSaleAlbumPrice());
}
}
}
