Arbeitsablauf für geschützte Inhalte

Im Folgenden wird der Arbeitsablauf zum Vorausladen des Gutscheins für eine geschützte Mediendatei mithilfe eines DRMContentData-Objekts beschrieben.

1. Rufen Sie die binären Metadaten für den verpackten Inhalt ab. Bei Verwendung des Flash Access Java Reference Packager wird diese Metadaten-Datei automatisch mit der .metadata-Erweiterung erstellt. Sie können diese Metadaten beispielsweise mit der URLLoader-Klasse herunterladen.

2. Erstellen Sie ein DRMContentData-Objekt und übergeben Sie die Metadaten an die Konstruktorfunktion:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. Die restlichen Arbeitsschritte sind mit dem Arbeitsablauf identisch, der unter Arbeitsablauf für geschützte Inhalte beschrieben wird.

Die folgenden Schritte beschreiben den Arbeitsablauf beim Vorausladen des Gutscheins für eine DRM-geschützte Mediendatei mithilfe von preloadEmbeddedMetadata():

1. Laden Sie die Mediendatei herunter und speichern Sie sie. (DRM-Metadaten können nur aus lokal gespeicherten Dateien vorausgeladen werden.)

2. Erstellen Sie die NetConnection- und NetStream-Objekte und stellen Sie Implementierungen für die onDRMContentData()- und onPlayStatus()-Rückruffunktionen des NetStream-Clientobjekts bereit.

3. Erstellen Sie ein NetStreamPlayOptions-Objekt und stellen Sie die stream-Eigenschaft auf die URL der lokalen Mediendatei ein.

4. Rufen Sie die NetStream-Methode preloadEmbeddedMetadata() auf und übergeben Sie dabei das NetStreamPlayOptions-Objekt, das die zu analysierende Mediendatei angibt.

5. Wenn die Mediendatei DRM-Metadaten enthält, wird die onDRMContentData()-Rückruffunktion aufgerufen. Die Metadaten werden als ein DRMContentData-Objekt an diese Funktion übergeben.

6. Verwenden Sie das DRMContentData-Objekt, um den Gutschein mit der loadVoucher()-Methode zu erhalten.

   Wenn die authenticationMethod-Eigenschaft des DRMContentData-Objekts den Wert userNameAndPassword hat, authentifizieren Sie den Benutzer auf dem Medienrechteserver, bevor der Gutschein geladen wird. Die Eigenschaften serverURL und domain des DRMContentData-Objekts können zusammen mit den Anmeldedaten des Benutzers an die authenticate()-Methode des DRMManager übergeben werden.

7. Die onPlayStatus()-Rückruffunktion wird aufgerufen, wenn das Dateiparsing abgeschlossen ist. Wenn die onDRMContentData()-Funktion nicht aufgerufen wurde, enthält die Datei nicht die für den Erhalt eines Gutscheins erforderlichen Metadaten. Dieser fehlende Aufruf kann auch bedeuten, dass diese Datei nicht von Flash Access geschützt wird.

Im folgenden Beispielcode für AIR wird veranschaulicht, wie ein Gutschein für eine lokale Mediendatei vorausgeladen wird:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}