Datenformate in der Zwischenablage

Wenn ein Objekt in einem benutzerdefinierten Datenformat in die Zwischenablage geschrieben wird, können die Objektdaten als Verweis oder als serialisierte Kopie des Originalobjekts aus der Zwischenablage gelesen werden. Es gibt vier Übertragungsmodi, durch die festgelegt wird, ob Objekte als Verweise oder serialisierte Kopien übertragen werden:

Wenn Sie ein Objekt in die Zwischenablage schreiben, können Sie einen beliebigen String, der nicht mit den reservierten Präfixen air: oder flash: beginnt, für den format -Parameter verwenden. Verwenden Sie denselben String wie für das Format, um das Objekt zu lesen Im folgenden Beispiel wird gezeigt, wie Objekte in die Zwischenablage geschrieben und aus dieser gelesen werden:

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Verwenden Sie denselben Formatnamen und den Übertragungsmodus CLONE_ONLY oder CLONE_PREFFERED , um ein serialisiertes Objekt (nach einem Zieh- oder Einfügevorgang) aus dem Clipboard-Objekt zu extrahieren.

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

Dem Clipboard-Objekt wird immer eine Referenz hinzugefügt. Um statt des serialisierten Objekts den Verweis aus dem Clipboard-Objekt zu extrahieren (nach einem Drop- oder Einfügevorgang), verwenden Sie den ORIGINAL_ONLY - oder ORIGINAL_PREFFERED -Übertragungsmodus.

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Verweise sind nur gültig, wenn das Clipboard-Objekt aus der aktuellen Anwendung stammt. Greifen Sie mit dem ORIGINAL_PREFFERED -Übertragungsmodus auf den Verweis zu, wenn er verfügbar ist, oder auf den serialisierten Klon, wenn der Verweis nicht verfügbar ist.

Im folgenden Beispiel wird gezeigt, wie die Funktion für die zurückgestellte Wiedergabe eingesetzt wird.

Beim Klicken auf die Schaltfläche „Kopieren“ wird der Inhalt der Zwischenablage des Systems gelöscht, um sicherzustellen, dass keine Daten von vorherigen Vorgängen in der Zwischenablage verbleiben. Anschließend wird mithilfe der setDataHandler() -Methode die renderData() -Funktion als Darstellungsfunktion der Zwischenablage eingestellt.

Wenn der Benutzer im Kontextmenü des Zieltextfelds den Befehl „Einfügen“ auswählt, greift die Anwendung auf die Zwischenablage zu und legt den Zieltext fest. Da das Textdatenformat in der Zwischenablage nicht mit einem String sondern einer Funktion eingestellt wurde, ruft die Zwischenablage die renderData() -Funktion auf. Die Funktion renderData() gibt den Text im Quelltext zurück, der dann einem Zieltext zugeordnet wird.

Beachten Sie, das Bearbeitungsvorgänge am Quelltext vor dem Betätigen der Schaltfläche „Einfügen“ im eingefügten Text sichtbar sind, auch wenn die Änderungen nach dem Betätigen der Schaltfläche „Kopieren“ getätigt wurden. Die Wiedergabefunktion kopiert den Quelltext erst, wenn die Schaltfläche „Einfügen“ betätigt wird. (Bei Verwendung der zurückgestellten Wiedergabe in einer echten Anwendung sollten Sie daher die Quelldaten möglicherweise speichern oder schützen, um dieses Problem zu vermeiden.)

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>