URLRequestHeader

Paket	flash.net
Klasse	public final class URLRequestHeader
Vererbung	URLRequestHeader Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Ein URLRequestHeader-Objekt enthält einen einzelnen HTTP-Anforderungsheader und besteht aus einem Name/Wert-Paar. URLRequestHeader-Objekte werden in der Eigenschaft requestHeaders der URLRequest-Klasse verwendet.

In Adobe^® AIR^® kann Inhalt in der Sicherheitssandbox der Anwendung (zum Beispiel Inhalt, der mit der AIR-Anwendung installiert wurde) beliebige Anforderungsheader ohne Fehler verwenden. Für Inhalt, der in Adobe AIR ausgeführt wird und sich in einer anderen Sicherheitssandbox befindet, oder für Inhalt der in Flash^® Player ausgeführt wird, führt die Verwendung der folgenden Anforderungsheader zu einem Laufzeitfehler, und bei beschränkten Begriffen wird nicht zwischen Groß- und Kleinschreibung unterschieden (zum Beispiel sind Get, get und GET alle nicht zulässig):

In Flash Player und in Adobe AIR-Inhalt außerhalb der Sicherheitssandbox der Anwendung können die folgenden Anforderungsheader nicht verwendet werden und bei beschränkten Begriffen wird nicht zwischen Groß- und Kleinschreibung unterschieden (zum Beispiel sind Get, get und GET alle nicht zulässig). Mit Bindestrich versehene Begriffe gelten, wenn ein Unterstrichzeichen verwendet wird (so ist es nicht zulässig, sowohl Content-Length und Content_Length zu verwenden):

Accept-Charset, Accept-Encoding, Accept-Ranges, Age, Allow, Allowed, Authorization, Charge-To, Connect, Connection, Content-Length, Content-Location, Content-Range, Cookie, Date, Delete, ETag, Expect, Get, Head, Host, If-Modified-Since, Keep-Alive, Last-Modified, Location, Max-Forwards, Options, Origin, Post, Proxy-Authenticate, Proxy-Authorization, Proxy-Connection, Public, Put, Range, Referer, Request-Range, Retry-After, Server, TE, Trace, Trailer, Transfer-Encoding, Upgrade, URI, User-Agent, Vary, Via, Warning, WWW-Authenticate, x-flash-version.

Für URLRequestHeader-Objekte gelten Längenbeschränkungen. Wenn die Gesamtlänge eines URLRequestHeader-Objekts (die Länge der name-Eigenschaft plus die Länge der Eigenschaft value) oder eines Arrays von URLRequestHeader-Objekten (verwendet in der Eigenschaft URLRequest.requestHeaders) die zulässige Länge überschreitet, wird eine Ausnahme ausgelöst.

Inhalt, der in Adobe AIR ausgeführt wird, stellt den ACCEPT-Header auf Folgendes ein, sofern Sie nicht eine Einstellung für den ACCEPT-Header in der requestHeaders-Eigenschaft der URLRequest-Klasse festlegen:

text/xml, application/xml, application/xhtml+xml, text/html;q=0.9, text/plain;q=0.8, image/png, application/x-shockwave-flash, video/mp4;q=0.9, flv-application/octet-stream;q=0.8, video/x-flv;q=0.7, audio/mp4, */*;q=0.5

Nicht alle Methoden, die URLRequest-Parameter akzeptieren, unterstützen die requestHeaders-Eigenschaft. Informationen zu der von Ihnen aufgerufenen Methode finden Sie in der entsprechenden Dokumentation. Beispiel: Die FileReference.upload()- und die FileReference.download()-Methode unterstützen die URLRequest.requestHeaders-Eigenschaft nicht.

Aufgrund von Browsereinschränkungen werden benutzerdefinierte HTTP-Anforderungs-Header für POST-Anforderungen, aber nicht für GET-Anforderungen unterstützt.

Beispiele anzeigen

Verwandte API-Elemente

URLRequest
URLLoader

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		name : String Der Name eines HTTP-Anforderungsheaders (z. B. „Content-Type“ oder „SOAPAction“).	URLRequestHeader
		value : String Der mit der Eigenschaft „name“ verknüpfte Wert (z. B. „text/plain“).	URLRequestHeader

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		URLRequestHeader(name:String = "", value:String = "") Erstellt ein neues URLRequestHeader-Objekt, das einen einzelnen HTTP-Anforderungsheader umfasst.	URLRequestHeader
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

Eigenschaftendetails

name	Eigenschaft

public var name:String

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Der Name eines HTTP-Anforderungsheaders (z. B. Content-Type oder SOAPAction).

value

Eigenschaft

public var value:String

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Der mit der Eigenschaft name verknüpfte Wert (z. B. text/plain).

Konstruktordetails

()

Konstruktor

public function URLRequestHeader(name:String = "", value:String = "")

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9, Flash Lite 4

Erstellt ein neues URLRequestHeader-Objekt, das einen einzelnen HTTP-Anforderungsheader umfasst. URLRequestHeader-Objekte werden in der Eigenschaft requestHeaders der URLRequest-Klasse verwendet.

Parameter

	`name:String` (default = "") — Der Name eines HTTP-Anforderungsheaders (z. B. `Content-Type` oder `SOAPAction`).

	`value:String` (default = "") — Der mit der Eigenschaft `name` verknüpfte Wert (z. B. `text/plain`).

Beispiele Verwendung dieses Beispiels

URLRequestHeaderExample.as

Im folgenden Beispiel wird dem Array für die Eigenschaft requestHeaders ein einzelner HTTP-Anforderungsheader header hinzugefügt. Der Header gibt an, dass die Anwendung selbst dann die Anforderung an den Ursprungsserver weiterleiten sollte, wenn sie über eine zwischengespeicherte Kopie dessen verfügt, was angefordert wird.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.net.URLRequestHeader;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequestHeaderExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestHeaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var header:URLRequestHeader = new URLRequestHeader("pragma", "no-cache");
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/greeting.cfm");
            request.data = new URLVariables("name=John+Doe");
            request.method = URLRequestMethod.POST;
            request.requestHeaders.push(header);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

URLRequestHeader - AS3

Klassen x

name

value

URLRequestHeader