StorageVolume

Paket	flash.filesystem
Klasse	public class StorageVolume
Vererbung	StorageVolume Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Ein StorageVolume-Objekt enthält Eigenschaften für die Definition eines Massenspeichervolumes. Diese Klasse wird auf zwei Arten verwendet:

Die storageVolume-Eigenschaft eines StorageVolumeChangeEvent-Objekts ist ein StorageVolume-Objekt. Dieses Objekt repräsentiert das Speichervolume, das bereitgestellt bzw. dessen Bereitstellung aufgehoben wurde.
Die StorageVolumeInfo.storageVolumeInfo.getStorageVolumes()-Methode gibt einen Vektor von StorageVolume-Objekten zurück. Jedes dieser StorageVolume-Objekte repräsentiert ein bereitgestelltes Speichervolume.

Beispiele anzeigen

Verwandte API-Elemente

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		drive : String [schreibgeschützt] Der Volumebuchstabe unter Windows.	StorageVolume
		fileSystemType : String [schreibgeschützt] Das auf den Speichervolumes verwendete Dateisystem (zum Beispiel "FAT", "NTFS", "HFS" oder "UFS").	StorageVolume
		isRemovable : Boolean [schreibgeschützt] Ob das Betriebssystem das Speichervolume als austauschbar betrachtet (true) oder nicht (false).	StorageVolume
		isWritable : Boolean [schreibgeschützt] Ob ein Volume beschreibbar ist („true“) oder nicht („false“).	StorageVolume
		name : String [schreibgeschützt] Der Name des Volumes.	StorageVolume
		rootDirectory : File [schreibgeschützt] Ein File-Objekt, das dem Stammverzeichnis des Volumes entspricht.	StorageVolume

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) Die Konstruktorfunktion.	StorageVolume
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

Eigenschaftendetails

drive

Eigenschaft

drive:String [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Der Volumebuchstabe unter Windows. Bei anderen Plattformen ist diese Eigenschaft auf null gesetzt.

Implementierung
public function get drive():String

fileSystemType

Eigenschaft

fileSystemType:String [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Das auf den Speichervolumes verwendete Dateisystem (zum Beispiel "FAT", "NTFS", "HFS" oder "UFS").

Implementierung
public function get fileSystemType():String

Beispiel ( Verwendung dieses Beispiels )

Mit dem folgenden Code wird der native Pfad für das Stammverzeichnis und der Dateisystemtyp der einzelnen bereitgestellten Speichervolumes aufgelistet.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

Eigenschaft

isRemovable:Boolean [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Ob das Betriebssystem das Speichervolume als austauschbar betrachtet (true) oder nicht (false).

In der folgenden Tabelle sind die Werte der StorageVolume.isRemovable-Eigenschaft für verschiedene Gerätetypen aufgelistet:

Gerätetyp	Mac OS	Windows	Linux
CD/DVD (eingebaut)	true	true	true
USB-Flashlaufwerk	true	true	true
USB-Festplatte	false	false	true
FireWire-Festplatte	false	false	true
Gemeinsames Volume	true	false	- ¹
Netzwerklaufwerk	false	false	false
Speicherkartenleser (leer)	- ²	false	- ²
Speicherkartenleser (mit SD/CF-Karte)	true	true	true

¹ Unter Linux gibt es das Konzept freigegebener Volumes nicht.

² Unter Windows wird ein leerer Speicherkartenleser als nicht austauschbares Gerät aufgeführt. Unter Mac OS und Linux werden leere Kartenleser nicht als Speichervolumes aufgelistet.

Implementierung
public function get isRemovable():Boolean

Beispiel ( Verwendung dieses Beispiels )

Mit dem folgenden Code wird eine Liste aller nicht austauschbaren Speichervolumes gefolgt von einer Liste der austauschbaren Speichervolumes ausgegeben:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

Eigenschaft

isWritable:Boolean [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Ob ein Volume beschreibbar ist (true) oder nicht (false).

Hinweis: Sie können feststellen, wie viel Speicherplatz auf einem Volume verfügbar ist, indem Sie die rootDirectory.spaceAvailble-Eigenschaft des StorageVolume-Objekts aufrufen.

Implementierung
public function get isWritable():Boolean

Verwandte API-Elemente

flash.fileSystem.File.spaceAvailable

Beispiel ( Verwendung dieses Beispiels )

Mit dem folgenden Code wird eine Liste beschreibbarer Speichervolumes mit dem jeweils verfügbaren Speicherplatz ausgegeben:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

Eigenschaft

name:String [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Der Name des Volumes. Wenn keine Bezeichnung festgelegt wurde, wird diese Eigenschaft auf null gesetzt.

Implementierung
public function get name():String

Beispiel ( Verwendung dieses Beispiels )

Mit dem folgenden Code wird der native Pfad für das Stammverzeichnis und der Dateisystemname (sofern vorhanden) der einzelnen bereitgestellten Speichervolumes aufgelistet.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

Eigenschaft

rootDirectory:File [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Ein File-Objekt, das dem Stammverzeichnis des Volumes entspricht.

Implementierung
public function get rootDirectory():File

Beispiel ( Verwendung dieses Beispiels )

Mit dem folgenden Code wird der native Pfad für das Stammverzeichnis der einzelnen bereitgestellten Speichervolumes aufgelistet.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Konstruktordetails

()

Konstruktor

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 2

Die Konstruktorfunktion. Im Allgemeinen rufen Sie diese Konstruktorfunktion nicht direkt auf (um neue StorageVolume-Objekte zu erstellen). Sie verweisen vielmehr auf StorageVolume-Objekte, indem Sie auf die storageVolume-Eigenschaft eines StorageVolumeChangeEvent-Objekts zugreifen oder indem Sie StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() aufrufen.

Parameter

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Beispiele Verwendung dieses Beispiels

StorageVolumeExample.as

Im folgenden Code werden die Eigenschaften der einzelnen bereitgestellten Speichervolumes aufgelistet:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

Im folgenden Code sind die Eigenschaften der einzelnen Speichervolumes aufgelistet, die bereitgestellt werden bzw. deren Bereitstellung aufgehoben wird. Beachten Sie, dass die storageVolume-Eigenschaft von StorageVolumeChangeEvent nur für das storageVolumeMount-Ereignis gesetzt wird; sie ist null für das storageVolumeUnmount-Ereignis:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

StorageVolume - AS3

Klassen x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume