File  - AS3

包含应用程序已安装文件的文件夹。

此对象的 url 属性使用 app URL 架构（而不是 file URL 架构）。这意味着指定的 url 以"app:"开头（而不是以 "file:" 开头）。此外，如果创建一个相对于 File.applicationDirectory 目录的 File 对象（通过使用 resolvePath() 方法），则该 File 对象的 url 也使用 app URL 架构。

注意：您无法写入其路径使用 app: URL 方案的文件或目录。您也无法删除或创建其路径使用 app: URL 方案的文件或文件夹。出于安全原因，不推荐修改应用程序目录中的内容，有些平台上的操作系统会阻止此操作。如果要存储特定于应用程序的数据，请考虑使用应用程序存储目录 (File.applicationStorageDirectory)。如果希望应用程序存储目录中的任何内容能够访问应用程序特许功能 (AIR API)，您可以通过使用沙箱桥公开该功能。

applicationDirectory 属性可用于引用应用程序目录，它在所有平台上均有效。如果使用 nativePath 或 url 属性设置 File 对象，使其引用应用程序目录，此命令将仅在能够识别此路径的平台上有效。

在 Android 上，指向应用程序目录的 File 对象的 nativePath 属性是空字符串。使用 URL 属性访问应用程序文件。

相关 API 元素

应用程序的专用存储目录。

每个 AIR 应用程序都有一个唯一的、永久的应用程序存储目录，该目录是您首次访问 File.applicationStorageDirectory 时创建的。此目录对每个应用程序和用户是唯一的。此目录是存储特定于用户或特定于应用程序的数据的方便位置。

卸载 AIR 应用程序时，卸载程序是否删除应用程序存储目录及其文件取决于平台。

此对象的 url 属性使用 app-storage URL 架构（而不是 file URL 架构）。这意味着指定的 url 字符串以"app-storage:"开头（而不是以 "file:" 开头）。此外，如果创建一个相对于 File.applicationStoreDirectory 目录的 File 对象（通过使用 resolvePath() 方法），则该 File 对象的 url 也使用 app-storage URL 架构（如示例中所示）。

applicationStorageDirectory 属性可用于引用应用程序存储目录，它在所有平台上均有效。如果使用 nativePath 或 url 属性设置 File 对象，使其引用应用程序存储目录，此命令将仅在能够识别此路径的平台上有效。

注意（仅限 Mac OS）： 为了符合 Mac App Store 的要求，此目录的物理位置在 AIR 3.2 和 AIR 3.3 之间发生了变化：

• 3.2 命名空间和更早版本： ~/Library/Preferences/appid/Local Store/
• 3.3 命名空间和更高版本： path/Library/Application Support/appid/Local Store/，其中 path 是 ~/Library/Containers/bundle-id/Data（沙箱环境）或 ~（当在沙箱环境外运行时）

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

应用程序的缓存目录。

cacheDirectory 属性提供一种引用缓存目录的方式。您的应用程序应使用缓存目录来存储从服务器下载的文件或可以重新生成的文件。例如，应放在缓存目录中的文件包括数据库缓存文件以及杂志、报纸及地图应用程序使用的可下载内容。

如果使用 nativePath 或 url 属性设置 File 对象来引用缓存目录，该对象将仅在能够识别此路径的平台上有效。

如果操作系统不支持缓存目录，则 cacheDirectory 为 null

用户桌面目录。

desktopDirectory 属性可用于引用桌面目录，它在所有平台上均有效。如果使用 nativePath 或 url 属性设置 File 对象，使其引用桌面目录，此命令将仅在能够识别此路径的平台上有效。

如果操作系统不支持桌面目录，则使用文件系统中适当的目录。

AIR for TV 设备没有用户桌面目录的概念。因此，desktopDirectory 属性引用与 File.userDirectory 属性相同的目录位置。用户目录对于应用程序而言是唯一的。

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

用户文档目录。

在 Windows 中，这是“My Documents”目录（例如，C:\Documents and Settings\userName\My Documents）。在 Mac OS 中，默认位置是 /Users/userName/Documents。在 Linux 中，默认位置是 /home/userName/Documents（英语系统上），并且该属性遵守 xdg-user-dirs 设置。

documentsDirectory 属性可用于引用文档目录，它在所有平台上均有效。如果使用 nativePath 或 url 属性设置 File 对象，使其引用文档目录，此命令将仅在能够识别此路径的平台上有效。

如果操作系统不支持文档目录，则使用文件系统中适当的目录。

AIR for TV 设备没有用户文档目录的概念。因此，documentsDirectory 属性引用与 File.userDirectory 属性相同的目录位置。用户目录对于应用程序而言是唯一的。

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

表示是否已（从 Internet）下载参考文件或目录。

此属性仅在文件可以标记为已下载的操作系统上有意义：

• Windows XP Service Pack 2 和更高版本，在 Windows Vista 上
• Mac OS 10.5 和更高版本

在 Linux 等不标记已下载文件的系统上，此属性没有意义（其值设置为 false）。

相关 API 元素

表示引用的文件或目录是否存在。如果 File 对象指向现有的文件或目录，则该值为 true；否则为 false。

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

包含为文件定义的图标的 Icon 对象。Icon 对象是与各种图标状态相对应的 BitmapData 对象的数组。在 Linux 中，Icon 对象不包含图标。在 Android 上，icon 属性为 null。

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

表示是否为对目录的引用。如果 File 对象指向一个目录，则该值为 true；否则为 false。

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

表示引用的文件或目录是否为“隐藏”。如果引用的文件或目录是隐藏的，则该值为 true；否则为 false。

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

表示引用的目录是否为包。

如果引用的目录是包，则该值为 true；否则为 false。请注意，File 类不允许直接创建包。

• 在 Mac OS 中，目录可以指定为包并将作为单个文件而不是目录显示在 Finder 中。如果引用的目录是包，则将此属性设置为 true；如果该文件不是目录、不存在或不是包，则将此属性设置为 false。
• 在其他操作系统上，此属性始终设置为 false。

表示引用是否为符号链接。

如果 File 对象是一个符号链接，则该值为 true；否则为 false。请注意，File 类不允许直接创建符号链接。

符号链接允许一个文件指向磁盘上的另一个文件或目录。符号链接虽然与 Mac OS 中的别名和 Windows 中的快捷方式相似，但并不相同。别名或快捷方式始终报告为文件（而不是目录），读取或写入别名或快捷方式从不影响它指向的原始文件或目录。另一方面，符号链接的行为大体上与其所指向的文件或目录类似。它可以报告为文件或目录，读取或写入符号链接将会影响它指向的文件或目录，而不影响符号链接本身。删除符号链接，但删除的是链接，而非链接的目标。

Mac ^® OS ^®、Linux 和 Windows ^® Vista ^® 支持符号链接。此外，在 Windows 中，引用交接点（用于 NTFS 文件系统）的 File 对象的 isSymbolicLink 属性设置为 true。

主机操作系统使用的行结束字符序列。

在 Mac OS 和 Linux 中，这是换行符（十六进制字符代码 0x0A）。在 Windows 中，它是回车符（十六进制字符代码 0x0D），后跟换行符（十六进制字符代码 0x0A）。

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

采用主机操作系统表示形式的完整路径。在 Mac OS 和 Linux 中，使用正斜杠 (/) 字符作为路径分隔符。但在 Windows 中，可以使用正斜杠字符或反斜杠 (\) 字符作为路径分隔符来设置 nativePath 属性，AIR 会自动用相应的反斜杠字符来替换正斜杠。

在使用 set 命令，以代码形式直接设置 nativePath 属性之前，请考虑这是否会生成平台专用代码。例如，“C:\\Documents and Settings\\bob\\Desktop”这样的本机路径仅在 Windows 上有效。较好的方法是使用以下这些静态属性，它们可以表示常用目录，且在所有平台上均有效：

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

可以使用 resolvePath() 方法获取这些目录的相对路径。

某些 Flex API（如 SWFLoader 类的 source 属性）使用 URL（File 对象的 url 属性），而不使用本机路径（nativePath 属性）。

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

包含此 File 对象引用的文件或目录的目录。

如果文件或目录不存在，则 parent 属性仍然返回指向包含目录的 File 对象（即使该目录不存在）。

此属性与 resolvePath("..") 的返回值相同，只不过根目录的父级为 null。

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

确定应用程序是否已被授予文件系统访问权限。

相关 API 元素

指示运行时是否阻止此 File 对象备份到云。

如果此属性设为 true，则在提供云服务的平台上，不会自动将其备份到云。此属性的默认值是 false。

主机操作系统的路径组件分隔符。

在 Mac OS 和 Linux 中，这是正斜杠 (/) 字符。在 Windows 中，它是反斜杠 (\) 字符。

注意：当在字符串中使用反斜杠时，请记住键入该字符两次（例如“directory\\file.ext”）。字符串中的每一对反斜杠在字符串中均表示单个反斜杠。

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

可用于在此 File 位置使用的空间，以字节为单位。

如果 File 对象引用一个目录，则 spaceAvailable 将表示可供文件使用的目录空间。如果 File 对象引用一个文件，则 spaceAvailable 将表示可供该文件使用的空间。如果该文件位置不存在，则 spaceAvailable 将设置为 0。如果 File 对象引用一个符号链接，则 spaceAvailable 将表示符号链接指向的位置的可用空间。

通常，目录或文件的可用空间与包含目录或文件的卷上的可用空间相同。不过，可用空间与磁盘配额及每个目录的空间限制有关。

将文件或目录添加到卷中通常需要比文件的实际大小或目录中内容的实际大小更多的空间。例如，操作系统可能需要更多空间来存储索引信息。或者，所需的磁盘扇区可能会使用额外的空间。此外，可用空间是动态变化的。因此，您不能期望为文件存储分配报告的全部 空间。

主机操作系统使用的默认编码。

可能值包括“windows-1252”、“shift-jis”、“cn-gb”、“iso-8859-1”等。有关完整列表，请参阅支持的字符集。

在使用 FileStream 类的 readMultiByte() 和 writeMultiByte() 方法时，可以使用此值。

相关 API 元素

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

此文件路径的 URL。

如果这是对应用程序存储目录中的路径的引用，则 URL 架构为 "app-storage"；如果这是对应用程序目录中路径的引用，则 URL 架构为 "app"；否则此架构为 "file"。

在向 url 属性赋值时，可以使用空格字符（而不是 "%20"）；AIR 会自动对该字符串进行编码（例如，将空格转换为 "%20"）。

相关 API 元素

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

用户目录。

在 Windows 中，这是“My Documents”目录的父级（例如，C:\Documents and Settings\userName）。在 Mac OS 中，它是 /Users/userName. 在 Linux 中，它是 /home/userName。

userDirectory 属性可用于引用用户目录，它在所有平台上均有效。如果直接设置 File 对象的 nativePath 或 url 属性，此命令将仅在能够识别此路径的平台上有效。

如果操作系统不支持用户目录，则使用文件系统中适当的目录。

在 AIR for TV 设备上，userDirectory 属性引用对于应用程序是唯一的用户目录。

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

File 类的构造函数。

如果传递 path 参数，File 对象将指向指定的路径，并将设置 nativePath 属性和 url 属性以反映该路径。

尽管可以传递 path 参数来指定文件路径，但请考虑这是否会生成平台专用代码。例如，这样的本机路径 "C:\\Documents and Settings\\bob\\Desktop"，或这样的 URL "file:///C:/Documents%20and%20Settings/bob/Desktop" 仅在 Windows 上有效。较好的方法是使用以下这些静态属性，它们可以表示常用目录，且在所有平台上均有效：

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

然后可以使用 resolvePath() 方法来获取这些目录的相对路径。例如，以下代码可以设置 File 对象，使其指向应用程序存储目录中的 settings.xml 文件：

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

重要：如果在 path 参数中传递 URL 字符串，将解码 URL 以解析文件路径。例如，语句 new File("file:///c:/test/demo%20file%201%2e0.txt") 使用本机路径“c:\test\demo file 1.0.txt”创建一个 File 对象。（使用 file:、app: 或 app-storage: 方案前缀的 URL。）然而，如果省略了有效的 URL 前缀，则路径字符串将被作为本机路径处理，不会发生解码操作。在验证来自可能不受信任的源的路径时，必须考虑这种行为。如果仅验证输入字符串，URL 解码操作可能会让攻击者绕过您的验证检查。请始终验证实例化 File 对象的最终路径：

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

相关 API 元素

显示一个目录选择器对话框，用户可从中选择一个目录。当用户选择该目录时，将调度 select 事件。select 事件的 target 属性是指向所选目录的 File 对象。

目录选择器对话框并不始终显示在由另一个窗口（具有非空 owner 属性的窗口）拥有的窗口的前面。 要避免窗口顺序问题，请在调用此方法之前隐藏所拥有的窗口。

注意：在 Android 设备上，不支持 browseForDirectory()。File 对象立即调度 cancel 事件。

参数

相关 API 元素

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

显示“打开文件”对话框，用户可从中选择要打开的文件。

当用户选择该文件时，将调度 select 事件。select 事件的 target 属性是指向所选文件的 File 对象。

“打开文件”对话框并不始终显示在由另一个窗口（具有非空 owner 属性的窗口）拥有的窗口的前面。 要避免窗口顺序问题，请在调用此方法之前隐藏所拥有的窗口。

注意：在 Android 设备上，无法设置文件对话框标题。忽略 title 参数。

参数

相关 API 元素

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

显示“打开文件”对话框，用户可从中选择一个或多个要打开的文件。

当用户选择文件时，将调度 selectMultiple 事件。select 事件的 target 属性是此 File 对象。与 browseForOpen() 不同，使用 browseForOpenMultiple() 方法时，此 File 对象不会更新以引用任何所选的文件。相反，生成的 selectMultiple 事件包含所选文件的数组。

“打开文件”对话框并不始终显示在由另一个窗口（具有非空 owner 属性的窗口）拥有的窗口的前面。 要避免窗口顺序问题，请在调用此方法之前隐藏所拥有的窗口。

注意：在 Android 设备上，无法设置文件对话框标题。忽略 title 参数。

参数

相关 API 元素

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

显示“保存文件”对话框，用户可从中选择一个文件目标。

当用户选择该文件时，将调度 select 事件。select 事件的 target 属性是指向所选保存目标的 File 对象。

“保存文件”对话框并不始终显示在由另一个窗口（具有非空 owner 属性的窗口）拥有的窗口的前面。 要避免窗口顺序问题，请在调用此方法之前隐藏所拥有的窗口。

注意：在 Android 设备上，无法设置文件对话框标题。忽略 title 参数。

参数

相关 API 元素

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

取消任何未处理的异步操作。

规范化 File 路径。

如果 File 对象表示现有的文件或目录，规范化将调整该路径，使其与实际文件名或目录名的大小写相匹配。如果 File 对象是符号链接，规范化将调整该路径，使其与该链接所指向的文件或目录相匹配，不管所指向的文件或目录是否存在。在区分大小写的文件系统（如 Linux）上，当多个文件的名称只有大小写不同时，canonicalize() 方法将调整路径以匹配最先找到的文件（以文件系统确定的顺序）。

此外，在 Windows 中，规范化会将短文件名转换成长文件名。

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

返回此 File 对象的副本。未复制事件注册。

注意：此方法不 复制文件本身。它仅制作 ActionScript File 对象实例的副本。要复制文件，请使用 copyTo() 方法。

将由此 File 对象指定的位置的文件或目录复制到由 newLocation 参数指定的位置。复制过程将创建任何需要的父级目录（如有可能）。当使用 copyto() 来覆盖文件时，文件的属性也将会被覆盖。

参数

相关 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

开始将此 File 对象指定的位置中的文件或目录复制到 destination 参数指定的位置。

完成后，将调度 complete 事件（成功）或 ioError 事件（失败）。复制过程将创建任何需要的父级目录（如有可能）。

参数

相关 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

创建指定的目录和任何所需的父级目录。如果该目录已存在，则不执行任何操作。

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

返回对新临时目录的引用。这是一个位于系统临时目录路径中的新目录。

使用此方法来标识新的唯一目录，无需查询系统即可以确定该目录是新的唯一目录。

您可能需要在关闭应用程序前删除该临时目录，因为在某些设备上它不会自动删除。

相关 API 元素

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

返回对新临时文件的引用。这是一个位于系统临时目录路径中的新文件。

使用此方法来标识新的唯一文件，无需查询系统即可以确定该文件是新的唯一文件。

您可能需要在关闭应用程序前删除该临时文件，因为它不会自动删除。

相关 API 元素

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

删除目录。如果此 File 实际上是指向目录的符号链接，则删除的是链接，而非目录。

参数

相关 API 元素

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

异步删除目录。如果此 File 实际上是指向目录的符号链接，则删除的是链接，而非目录。

参数

相关 API 元素

删除文件。如果此 File 实际上是符号链接，则删除的是链接，而非目标文件。

相关 API 元素

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

异步删除文件。如果此 File 实际上是符号链接，则删除的是链接，而非目标文件。

相关 API 元素

返回与此 File 对象表示的目录中的文件和目录对应的 File 对象的数组。此方法不浏览子目录的内容。

相关 API 元素

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

异步检索与此 File 对象表示的目录内容对应的 File 对象的数组。

相关 API 元素

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

查找两个 File 路径之间的相对路径。

相对路径是可以追加到此引用（据此引用进行解析）以便定位第二个（参数）引用的组件的列表。使用“/”分隔符返回相对路径。

或者，相对路径可以包括“..”引用，但这样的路径将不能跨越明显的卷边界。

参数

返回 File 对象的数组，列出文件系统根目录。

例如在 Windows 中，这是一个卷列表，如 C: 驱动器和 D: 驱动器。此数组中不包括空的驱动器，如未插入光盘的 CD 或 DVD 驱动器。在 Mac OS 和 Linux 中，此方法始终返回计算机的唯一根目录（“/”目录）

在根不可读的文件系统上，例如 Android 文件系统，返回的 File 对象的属性并不总是反映真实值。例如，在 Android 上，spaceAvailable 属性报告 0。

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

将此 File 对象指定的位置中的文件或目录移动到 destination 参数指定的位置。

要重命名文件，请将 destination 参数设置为指向该文件目录中的路径，但使用不同的文件名。

移动过程将创建任何需要的父级目录（如有可能）。

参数

相关 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

开始将此 File 对象指定的位置中的文件或目录移动到 newLocation 参数指定的位置。

要重命名文件，请将 destination 参数设置为指向该文件目录中的路径，但使用不同的文件名。

移动过程将创建任何需要的父级目录（如有可能）。

参数

相关 API 元素

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

将文件或目录移动到垃圾桶。

注意：在不支持可恢复垃圾桶文件夹概念的操作系统上，会立即删除文件。

相关 API 元素

将文件或目录异步移动到垃圾桶。

注意：在不支持可恢复垃圾桶文件夹概念的操作系统上，会立即删除文件。

相关 API 元素

打开操作系统注册的应用程序中的文件来打开此类型的文件。

AIR 阻止您使用 File.openWithDefaultApplication() 方法打开特定文件。在 Windows 上，AIR 阻止您打开某些文件类型的文件（具有特定扩展名的文件，如下所示）。在 Mac OS 和 Linux 上，AIR 会阻止您打开在下面指定的特定应用程序中启动的文件。尝试使用 openWithDefaultApplication() 方法打开其中一个文件将导致异常。但是，使用本机安装程序（扩展的桌面配置文件应用程序）安装的 AIR 应用程序不受限于这些限制；它们可以打开任何类型的文件。

无法从应用程序目录中打开文档。

下列表列出了在 Windows 上禁止的文件扩展名，以及在 Mac OS 和 Linux 上阻止的应用程序：

相关 API 元素

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

申请文件系统访问权限

基于 path 参数（一个字符串）创建一个其路径相对于此 File 对象路径的新 File 对象。

path 参数可以使用相对路径或绝对路径。

如果指定相对路径，则将给定的 path“追加”到 File 对象的路径。但是，在 path 中使用“..”可以返回生成的路径（该路径不是 File 对象的子级）。生成的引用不必引用实际文件系统位置。

如果指定一个绝对文件引用，则该方法将返回指向该路径的 File 对象。绝对文件引用应使用对用户的操作系统有效的本机路径语法（例如 Windows 上的 "C:\\test"）。不要将 URL（例如 "file:///c:/test"）用作 path 参数。

所有生成的路径将按以下方式进行规范化：

• 任何“.”元素都会被忽略。
• 任何“..” 元素将参照其父级目录。
• 任何到达文件系统根目录或应用程序的永久存储区根目录的“..”参照将无法越过该节点；将忽略此类参照。

应始终使用正斜杠 (/) 字符作为路径分隔符。在 Windows 上，也可以使用反斜杠 (\) 字符，但最好不要使用它。使用反斜杠字符可导致应用程序在其他平台上无法运行。

在 Linux 上，文件名和目录名是区分大小写的。

参数

在取消未处理的异步操作时调度。

此事件具有以下属性：

在异步操作完成时调度。

此事件具有以下属性：

当由于调用 getDirectoryListingAsync() 方法而提供目录列表时调度。

此事件具有以下属性：

相关 API 元素

在执行异步文件操作期间发生错误时调度。

此事件具有以下属性：

当应用程序申请文件系统访问权限时调度。检查 status 属性的值，以确定是授予此权限还是拒绝此权限。

相关 API 元素

当操作违反安全限制时调度。

此事件具有以下属性：

当用户从文件浏览或目录浏览对话框中选择文件或目录时调度。

此事件具有以下属性：

当用户从通过调用 browseForOpenMultiple() 方法打开的对话框中选择文件时调度。

相关 API 元素