BitmapData  - AS3

Bitmap görüntüsünün piksel olarak yüksekliği.

Bitmap görüntüsünün boyut ve konumunu tanımlayan dikdörtgen. Dikdörtgenin üstü ve solu 0'dır; genişlik ve yükseklik, Bitmap nesnesinin piksel olarak genişlik ve yüksekliğine eşittir.

Bitmap görüntüsünün piksel başına saydamlığı destekleyip desteklemediğini tanımlar. Ancak yapıcının transparent parametresi için true değerini ileterek bir BitmapData nesnesi yaptığınızda bu değeri ayarlayabilirsiniz. Bir BitmapData nesnesi oluşturduktan sonra, transparent özelliği değerinin true olup olmadığını belirleyerek bu nesnenin piksel başına saydamlığı destekleyip desteklemediğini kontrol edebilirsiniz.

Bitmap görüntüsünün piksel olarak genişliği.

Belirtilen genişlik ve yükseklik ile bir BitmapData nesnesi oluşturur. fillColor parametresi için bir değer belirtirseniz, bitmap'teki her piksel o renge ayarlanır.

Varsayılan olarak, transparent parametresi için false değerini iletmediğiniz sürece, bitmap saydam olarak oluşturulur. Bir opak bitmap oluşturduktan sonra, bunu saydam bitmap olarak değiştiremezsiniz. Opak bitmap'teki her piksel yalnızca 24 bit renk kanalı bilgisi kullanır. Bitmap'i saydam olarak tanımlarsanız, her piksel alfa saydamlığı kanalı dahil, 32 bit renk kanalı bilgisi kullanır.

AIR 1.5 ve Flash Player 10'da, bir BitmapData nesnesi için maksimum boyut genişlikte ve yükseklikte 8.191 pikseldir ve toplam piksel sayısı 16.777.215'i geçemez. (Bu nedenle, bir BitmapData nesnesi 8.191 piksel genişliğindeyse en fazla 2.048 piksel yüksekliğinde olabilir.) Flash Player 9 ve önceki sürümleri ile AIR 1.1 ve önceki sürümlerinde, sınırlama yükseklikte 2880 piksel ve genişlikte 2880 pikseldir. 2880'den yüksek bir genişlik veya yükseklik değeri belirtirseniz, yeni bir örnek oluşturulmaz.

Bir kaynak görüntüyü ve filtre nesnesini alıp filtrelenen görüntüyü oluşturur.

Bu yöntem, bir girdi kaynağı dikdörtgeni tarafından etkilenen hedef dikdörtgeni belirleyen yerleşik filtre nesnelerinin davranışına dayanır.

Bir filtre uygulandıktan sonra, sonuç görüntü girdi görüntüsünden daha büyük olabilir. Örneğin alanın bir (50,50,100,100) kaynak dikdörtgenini ve (10,10) hedef noktasını bulanıklaştırmak için bir BlurFilter sınıfını kullanırsanız, hedef görüntüde değişen alan, bulanıklaştırmadan dolayı (10,10,60,60) değerinden daha büyüktür. Bu, applyFilter() çağrısı sırasında dahili olarak oluşur.

sourceBitmapData parametresinin sourceRect parametresi dahili bir bölgeyse (200 x 200 görüntüde (50,50,100,100) gibi), filtre hedef dikdörtgeni oluşturmak için sourceRect parametresinin dışındaki kaynak pikselleri kullanır.

BitmapData nesnesi ve sourceBitmapData parametresi olarak tanımlanan nesne aynı aynıysa, uygulama filtreyi uygulamak için nesnenin geçici bir kopyasını kullanır. En iyi performansı elde etmek için bu durumu önleyin.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();
bmd.applyFilter(bmd, rect, pt, filter);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

İçerilen bitmap'in tam kopyasıyla orijinal örneğin bir klonu olan yeni bir BitmapData nesnesi döndürür.

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(100, 80, false, 0x00000000);
var bmd2:BitmapData = bmd1.clone();

bmd1.setPixel32(1, 1, 0xFFFFFFFF);

trace(bmd1.getPixel32(1, 1).toString(16)); // ffffffff
trace(bmd2.getPixel32(1, 1).toString(16)); // ff000000

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);

var bm2:Bitmap = new Bitmap(bmd2);
bm2.x = 110;
this.addChild(bm2);

ColorTransform nesnesi kullanarak bitmap görüntüsünün belirtilen bir alanındaki renk değerlerini ayarlar. Dikdörtgen, bitmap görüntüsünün sınırlarıyla eşleşirse, bu yöntem görüntünün tamamının renk değerlerini dönüştürür.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.ColorTransform;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFF0000);

var cTransform:ColorTransform = new ColorTransform();
cTransform.alphaMultiplier = 0.5
var rect:Rectangle = new Rectangle(0, 0, 40, 30);
bmd.colorTransform(rect, cTransform);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

İki BitmapData nesnesini karşılaştırır. İki BitmapData nesnesinin boyutları (genişlik ve yükseklik) aynıysa, bu yöntem, iki kaynak nesnedeki pikseller arasında her pikselin “fark“ olduğu yeni bir BitmapData nesnesi döndürür:

• İki piksel eşitse, fark pikseli 0x00000000 olur.
• İki pikselin RGB değerleri farklıysa (alfa değeri yok sayılarak), fark pikseli 0xRRGGBB olur; burada RR/GG/BB, kırmızı, yeşil ve mavi kanalları arasındaki fark değerlerinin her biridir (kaynak nesnedeki piksel değeri eksi otherBitmapData nesnesindeki piksel değeri). Bu durumda alfa kanalı farkları yok sayılır.
• Yalnızca alfa kanalı değeri farklıysa, piksel değeri 0xZZFFFFFF olur; burada ZZ alfa değerlerindeki farktır (kaynak nesnedeki alfa değeri eksi otherBitmapData nesnesindeki alfa değeri).

Örneğin şu iki BitmapData nesnesini göz önünde bulundurun:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFF8800);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCCC6600);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel(0,0).toString(16); // 0x332200
     

Not: İki BitmapData nesnesini doldurmak için kullanılan renklerin RGB değerleri biraz farklıdır (0xFF0000 ve 0xFFAA00). compare() yönteminin sonucu, her pikseli iki bitmap arasındaki RGB değerlerinin farkını gösteren yeni bir BitmapData nesnesidir.

RGB renklerinin aynı, ancak alfa değerlerinin farklı olduğu şu iki BitmapData nesnesini göz önünde bulundurun:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel32(0,0).toString(16); // 0x33ffffff
     

compare() yönteminin sonucu, her pikseli iki bitmap arasındaki RGB değerlerinin farkını gösteren yeni bir BitmapData nesnesidir.

BitmapData nesneleri eşdeğerse (aynı genişlikte ve yükseklikte olup aynı piksel değerlerine sahipse), yöntem 0 sayısını döndürür.

BitmapData nesnelerinin genişlikleri eşit değilse, yöntem -3 sayısını döndürür.

BitmapData nesnelerinin yükseklikleri eşit olmadığı halde genişlikleri aynıysa, yöntem -4 sayısını döndürür.

Şu örnek, farklı genişliklerdeki (50 ve 60) iki Bitmap nesnesini karşılaştırır.

     var bmd1:BitmapData = new BitmapData(100, 50, false, 0xFFFF0000);
     var bmd2:BitmapData = new BitmapData(100, 60, false, 0xFFFFAA00);
     trace(bmd1.compare(bmd2)); // -4
     

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
var diffBmpData:BitmapData = BitmapData(bmd1.compare(bmd2));
var diffValue:String = diffBmpData.getPixel32(1, 1).toString(16);
trace (diffValue); // 33ffffff

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 60;

Başka bir BitmapData nesnesinin veya geçerli BitmapData nesnesinin bir kanalındaki verileri geçerli BitmapData nesnesinin bir kanalına aktarır. Hedef BitmapData nesnesindeki diğer kanallarda bulunan verilerin tümü korunur.

Kaynak kanal değeri ve hedef kanal değeri şu değerlerden biri olabilir:

• BitmapDataChannel.RED
• BitmapDataChannel.GREEN
• BitmapDataChannel.BLUE
• BitmapDataChannel.ALPHA

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd.copyChannel(bmd, rect, pt, BitmapDataChannel.RED, BitmapDataChannel.BLUE);

var bm:Bitmap = new Bitmap(bmd);
this.addChild(bm);    

Uzatma, döndürme veya renk efektleri içermeyen görüntüler arasında piksel işleme eylemi gerçekleştirmek için hızlı bir yordam sağlar. Bu yöntem, kaynak görüntünün dikdörtgen bir alanını hedef BitmapData nesnesinin hedef noktasındaki aynı boyutta bir dikdörtgen alana kopyalar.

alphaBitmap ve alphaPoint parametrelerini dahil ederseniz, kaynak görüntü için alfa kaynağı olarak ikincil bir görüntü kullanabilirsiniz. Kaynak görüntünün alfa verisi varsa, kaynak görüntüdeki pikselleri hedef görüntüyle birleştirmek için her iki alfa verisi kümesi kullanılır. alphaPoint parametresi, kaynak dikdörtgenin sol üst köşesine karşılık gelen alfa görüntüsündeki noktadır. Kaynak görüntü ile alfa görüntüsünün kesişme alanı dışındaki pikseller, hedef görüntüye kopyalanmaz.

mergeAlpha özelliği, saydam bir görüntü başka bir saydam görüntüye kopyalanırken alfa kanalının kullanılıp kullanılmamasını denetler. Alfa kanalı verileri içeren pikselleri kopyalamak için mergeAlpha özelliğini true değerine ayarlayın. Varsayılan olarak, mergeAlpha özelliği false değerindedir.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(40, 40, false, 0x000000FF);
var bmd2:BitmapData = new BitmapData(80, 40, false, 0x0000CC44);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd2.copyPixels(bmd1, rect, pt);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 50;

Piksel verisinin dikdörtgen bölgesinden bir bayt dizisini doldurur. Bu yöntem, ByteArray öğesinin position dizininden başlayarak, bayt dizisine her piksel için imzalanmamış bir tamsayı (32-bit çarpılmamış piksel değeri) yazar. Gerekirse, tüm piksel verilerini tutmak için bayt dizisinin boyutu gerekli bayt sayısına artırılır.

Parametreler

İlgili API Öğeleri

BitmapData nesnesini saklamak için kullanılan bellekte yer açar.

Bir görüntüde dispose() yöntemi çağrıldığında, görüntünün genişlik ve yüksekliği 0 değerine ayarlanır. Bu BitmapData örneğinin yöntemlerine veya özelliklerine yapılan sonraki çağrıların tümü başarısız olur ve bir istisna atılır.

BitmapData.dispose(), gerçek bitmap verilerinin kapladığı belleği hemen boşaltır (bir bitmap 64 MB'ye kadar bellek tüketebilir). BitmapData.dispose() öğesi kullanıldıktan sonra, BitmapData nesnesi artık kullanılamaz ve Flash çalışma zamanı BitmapData nesnesinde işlev çağırırsanız bir istisna atar. Ancak, BitmapData.dispose() öğesi, BitmapData nesnesinin (yaklaşık 128 bayt) çöpünü toplamaz ; BitmapData nesnesi çöp toplayıcı tarafından toplandığı anda gerçek BitmapData nesnesinin kapladığı alan boşalır.

İlgili API Öğeleri

import flash.display.BitmapData;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x000000FF);
trace(myBitmapData.getPixel(1, 1)); // 255 == 0xFF

myBitmapData.dispose();
try {
    trace(myBitmapData.getPixel(1, 1));
} catch (error:Error) {
    trace(error); // ArgumentError
}

Flash çalışma zamanı vektör oluşturucu kullanarak, source görüntüleme nesnesini bitmap görüntüsünün üzerine çizer. Oluşturmanın nasıl gerçekleştirileceğini denetlemek için matrix, colorTransform, blendMode ve bir hedef clipRect parametresi belirtebilirsiniz. İsteğe bağlı olarak, bitmap'in ölçeklenirken düzleştirilmesi gerekip gerekmediğini belirtebilirsiniz (bu yalnızca kaynak nesne bir BitmapData nesnesi olduğunda işe yarar).

Not: drawWithQuality() yöntemi tam olarak draw() yöntemine benzer şekilde çalışır, ancak vektör oluşturma kalitesini belirlemek için Stage.quality özelliğini kullanmak yerine, drawWithQuality() yöntemi için quality parametresini belirtirsiniz.

Bu yöntem, geliştirme aracı arabirimindeki nesneler için standart vektör oluşturucuyla nesnelerin çizilme şekline doğrudan karşılık gelir.

Kaynak görüntüleme nesnesi, bu çağrı için uygulanmış dönüştürmelerin herhangi birini kullanmaz. Bu, herhangi bir matris dönüştürmesi, renk dönüştürmesi ve karışım modu olmadan kütüphanede veya dosyada bulunduğu şekilde değerlendirilir. Bir görüntüleme nesnesini (örn. bir film klibi) kendi transform özelliklerini kullanarak çizmek için, görüntüleme nesnesinin transform özelliği nesnesini, BitmapData nesnesini kullanan Bitmap nesnesinin transform özelliğine kopyalayabilirsiniz.

Bu yöntem, Flash Player 9.0.115.0 ve sonraki sürümleri ile Adobe AIR'da RTMP üzerinden desteklenir. Sunucu tarafındaki bir komut dosyasında Flash Media Server'daki akışlara erişimi denetleyebilirsiniz. Daha fazla bilgi için Adobe Flash Media Server için Sunucu Tarafı ActionScript Dil Başvurusu içindeki Client.audioSampleAccess ve Client.videoSampleAccess özelliklerine bakın.

Kaynak nesne ve (bir Sprite veya MovieClip nesnesi olması durumunda) bunun tüm alt nesneleri, çağıranla aynı etki alanından gelmez veya çağıran tarafından Security.allowDomain() yönteminin çağrılmasıyla erişilebilir olan bir içerikte bulunmaz, draw() yönteminin çağrılması, bir SecurityError istisnası atar. Bu sınırlama, uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Yüklenen bitmap görüntüsünün source olarak kullanılmasına ilişkin sınırlamalar da mevcuttur. Yüklenen görüntü çağıranla aynı etki alanından geliyorsa, draw() yöntemine yapılan çağrı başarılı olur. Ayrıca, görüntünün sunucusunda bulunan etki alanları arası bir ilke dosyası, draw() yöntemini çağırarak SWF içeriğinin etki alanına izin verebilir. Bu durumda, bir LoaderContext nesnesinin checkPolicyFile özelliğini ayarlamalı ve bu nesneyi, görüntüyü yüklemek için kullanılan Loader nesnesinin load() yöntemini çağırırken context parametresi olarak kullanmalısınız. Bu sınırlamalar, uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Windows'da, draw() yöntemi Adobe AIR'de bulunan bir HTMLLoader nesnesindeki HTML sayfasında gömülü olan SWF içeriğini yakalayamaz.

draw() yöntemi Adobe AIR'de PDF içeriğini yakalayamaz. Adobe AIR'de wmode niteliğinin "window" olarak ayarlandığı HTML'de gömülü SWF içeriğini de yakalayamaz.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.draw(tf);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Flash çalışma zamanı vektör oluşturucu kullanarak, source görüntüleme nesnesini bitmap görüntüsünün üzerine çizer. Oluşturmanın nasıl gerçekleştirileceğini denetlemek için matrix, colorTransform, blendMode ve bir hedef clipRect parametresi belirtebilirsiniz. İsteğe bağlı olarak, bitmap'in ölçeklenirken düzleştirilmesi gerekip gerekmediğini belirtebilirsiniz (bu yalnızca kaynak nesne bir BitmapData nesnesi olduğunda işe yarar).

Not: drawWithQuality() yöntemi tam olarak draw() yöntemine benzer şekilde çalışır, ancak vektör oluşturma kalitesini belirlemek için Stage.quality özelliğini kullanmak yerine, drawWithQuality() yöntemi için quality parametresini belirtirsiniz.

Bu yöntem, geliştirme aracı arabirimindeki nesneler için standart vektör oluşturucuyla nesnelerin çizilme şekline doğrudan karşılık gelir.

Kaynak görüntüleme nesnesi, bu çağrı için uygulanmış dönüştürmelerin herhangi birini kullanmaz. Bu, herhangi bir matris dönüştürmesi, renk dönüştürmesi ve karışım modu olmadan kütüphanede veya dosyada bulunduğu şekilde değerlendirilir. Bir görüntüleme nesnesini (örn. bir film klibi) kendi transform özelliklerini kullanarak çizmek için, görüntüleme nesnesinin transform özelliği nesnesini, BitmapData nesnesini kullanan Bitmap nesnesinin transform özelliğine kopyalayabilirsiniz.

Bu yöntem, Flash Player 9.0.115.0 ve sonraki sürümleri ile Adobe AIR'da RTMP üzerinden desteklenir. Sunucu tarafındaki bir komut dosyasında Flash Media Server'daki akışlara erişimi denetleyebilirsiniz. Daha fazla bilgi için Adobe Flash Media Server için Sunucu Tarafı ActionScript Dil Başvurusu içindeki Client.audioSampleAccess ve Client.videoSampleAccess özelliklerine bakın.

Kaynak nesne ve (bir Sprite veya MovieClip nesnesi olması durumunda) bunun tüm alt nesneleri, çağıranla aynı etki alanından gelmezse ya da çağıran tarafından Security.allowDomain() yönteminin çağrılmasıyla erişilebilir olan bir içerikte bulunmazsa, drawWithQuality() yönteminin çağrılması, bir SecurityError istisnası atar. Bu sınırlama, uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Yüklenen bitmap görüntüsünün source olarak kullanılmasına ilişkin sınırlamalar da mevcuttur. Yüklenen görüntü çağıranla aynı etki alanından geliyorsa, drawWithQuality() yöntemine yapılan çağrı başarılı olur. Ayrıca, görüntünün sunucusunda bulunan etki alanları arası bir ilke dosyası, drawWithQuality() yöntemini çağırarak SWF içeriğinin etki alanına izin verebilir. Bu durumda, bir LoaderContext nesnesinin checkPolicyFile özelliğini ayarlamalı ve bu nesneyi, görüntüyü yüklemek için kullanılan Loader nesnesinin load() yöntemini çağırırken context parametresi olarak kullanmalısınız. Bu sınırlamalar, uygulama sanal alanındaki AIR içeriğine uygulanmaz.

Windows'ta, drawWithQuality() yöntemi Adobe AIR'de bulunan bir HTMLLoader nesnesindeki HTML sayfasına gömülü olan SWF içeriğini yakalayamaz.

drawWithQuality() yöntemi Adobe AIR'de PDF içeriğini yakalayamaz. Adobe AIR'de wmode niteliğinin "window" olarak ayarlandığı HTML'de gömülü SWF içeriğini de yakalayamaz.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.drawWithQuality(tf, , , , , , StageQuality.LOW);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Bu BitmapData nesnesini seçili sıkıştırıcı algoritmasını kullanarak sıkıştırır ve yeni bir ByteArray nesnesini döndürür. İsteğe bağlı olarak, belirtilen ByteArray'e sonuç verilerini yazar. Compressor argümanı kodlanan algoritmayı belirtir ve PNGEncoderOptions, JPEGEncoderOptions veya JPEGXREncoderOptions olabilir.

Aşağıdaki örnek bir BitmapData nesnesini JPEGEncoderOptions kullanarak sıkıştırır:

     // Compress a BitmapData object as a JPEG file.
     var bitmapData:BitmapData = new BitmapData(640,480,false,0x00FF00);
     var byteArray:ByteArray = new ByteArray();
     bitmapData.encode(new Rectangle(0,0,640,480), new flash.display.JPEGEncoderOptions(), byteArray); 

Parametreler

İlgili API Öğeleri

Dikdörtgen bir piksel alanını belirtilen bir ARGB rengi ile doldurur.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x0000FF);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Bir koordinattan (x, y) başlayarak görüntü üzerinde blok dolgu işlemi gerçekleştirir ve görüntüyü belirli bir renkle doldurur. floodFill() yöntemi, çeşitli paint programlarındaki renkle doldurma aracına benzer. Bu renk, alfa bilgilerini ve renk bilgilerini içeren bir ARGB rengidir.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x000000FF);
rect = new Rectangle(15, 15, 25, 25);
myBitmapData.fillRect(rect, 0x000000FF);

myBitmapData.floodFill(10, 10, 0x00FF0000);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Bir Bitmap nesnesi, kaynak dikdörtgen ve filtre nesnesi ile, applyFilter() yöntemi çağrısının etkilediği hedef dikdörtgeni belirler.

Örneğin bir bulanıklaştırma filtresi normalde orijinal görüntünün boyutundan daha büyük bir alanı etkiler. Varsayılan bir BlurFilter örneğiyle filtrelenmekte olan 100 x 200 piksel bir görüntü; burada blurX = blurY = 4 bir hedef dikdörtgen (-2,-2,104,204) oluşturur. generateFilterRect() yöntemi, bir filtre işlemi gerçekleştirmeden önce hedef görüntüyü uygun şekilde boyutlandırmanız için bu hedef dikdörtgenin boyutunu önceden bulmanızı sağlar.

Bazı filtreler, kaynak görüntü boyutunu esas alarak hedef dikdörtgenlerini kırpar. Örneğin bir iç DropShadow, kaynak görüntüsünden daha büyük bir sonuç oluşturmaz. Bu API'de, BitmapData nesnesi kaynak rect parametresi olarak değil, kaynak sınırları olarak kullanılır.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();

trace(bmd.generateFilterRect(rect, filter));
// (x=8, y=8, w=44, h=14)

bmd.applyFilter(bmd, rect, pt, filter);
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Bitmap görüntüsü içinde, belirtilen bir rengin tüm piksellerini tamamen kapsayan (findColor parametresi true değerine ayarlandıysa) veya belirtilen rengi içermeyen tüm pikselleri tamamen kapsayan (findColor parametresi false değerine ayarlandıysa) dikdörtgen bir bölgeyi belirler.

Örneğin bir kaynak görüntünüz varsa ve sıfır olmayan bir alfa kanalını içeren görüntü dikdörtgenini belirlemek isterseniz, parametre olarak {mask: 0xFF000000, color: 0x00000000} iletin. findColor parametresi true değerine ayarlanırsa, görüntünün tamamında (value & mask) == color (burada value, pikselin renk değeridir) olan piksellerin sınırları aranır. findColor parametresi false değerine ayarlanırsa, görüntünün tamamında (value & mask) != color (burada value, pikselin renk değeridir) olan piksellerin sınırları aranır. Bir görüntünün etrafındaki beyaz boşluğu belirlemek için, beyaz olmayan piksellerin sınırlarını bulmak üzere {mask: 0xFFFFFFFF, color: 0xFFFFFFFF} iletin.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFFFFFF);
var rect:Rectangle = new Rectangle(0, 0, 80, 20);
bmd.fillRect(rect, 0xFF0000);

var maskColor:uint = 0xFFFFFF; 
var color:uint = 0xFF0000;  
var redBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, true);
trace(redBounds); // (x=0, y=0, w=80, h=20)

var notRedBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, false);
trace(notRedBounds); // (x=0, y=20, w=80, h=20)

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Belirli bir noktadaki (x, y) BitmapData nesnesinden bir RGB piksel değerini temsil eden bir tam sayıyı döndürür. getPixel() yöntemi, çarpılmamış bir piksel değeri döndürür. Alfa bilgisi döndürülmez.

Bir BitmapData nesnesindeki tüm pikseller, önceden çarpılmış renk değerleri olarak saklanır. Önceden çarpılmış görüntü pikseli, zaten alfa verileriyle çarpılmış kırmızı, yeşil ve mavi renk kanalı değerlerine sahiptir. Örneğin alfa değeri 0 ise, çarpılmamış değerlerinden bağımsız olarak RGB kanallarının değerleri de 0 olur. Bu veri kaybı, işlemleri gerçekleştirirken bazı sorunlar yaşamanıza neden olabilir. Tüm BitmapData yöntemleri, çarpılmamış değerleri alır ve döndürür. Dahili piksel temsili, bir değer olarak döndürülmeden önce, önceden çarpılmış durumdan çarpılmamış duruma dönüştürülür. Ayarlama işlemi sırasında, ham görüntü pikseli ayarlanmadan önce piksel değeri önceden çarpılır.

Parametreler

İlgili API Öğeleri

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFF0000);

var pixelValue:uint = bmd.getPixel(0, 0);
trace(pixelValue.toString(16)); // ff0000;

Alfa kanalı verilerini ve RGB verilerini içeren ARGB renk değeri döndürür. Bu yöntem, alfa kanalı verileri olmadan bir RGB rengi döndürengetPixel() yöntemine benzer.

Bir BitmapData nesnesindeki tüm pikseller, önceden çarpılmış renk değerleri olarak saklanır. Önceden çarpılmış görüntü pikseli, zaten alfa verileriyle çarpılmış kırmızı, yeşil ve mavi renk kanalı değerlerine sahiptir. Örneğin alfa değeri 0 ise, çarpılmamış değerlerinden bağımsız olarak RGB kanallarının değerleri de 0 olur. Bu veri kaybı, işlemleri gerçekleştirirken bazı sorunlar yaşamanıza neden olabilir. Tüm BitmapData yöntemleri, çarpılmamış değerleri alır ve döndürür. Dahili piksel temsili, bir değer olarak döndürülmeden önce, önceden çarpılmış durumdan çarpılmamış duruma dönüştürülür. Ayarlama işlemi sırasında, ham görüntü pikseli ayarlanmadan önce piksel değeri önceden çarpılır.

Parametreler

İlgili API Öğeleri

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, true, 0xFF44AACC);

var pixelValue:uint = bmd.getPixel32(0, 0);
var alphaValue:uint = pixelValue >> 24 & 0xFF;
var red:uint = pixelValue >> 16 & 0xFF;
var green:uint = pixelValue >> 8 & 0xFF;
var blue:uint = pixelValue & 0xFF;

trace(alphaValue.toString(16)); // ff
trace(red.toString(16)); // 44
trace(green.toString(16)); // aa
trace(blue.toString(16)); // cc

Dikdörtgen bir piksel verisi bölgesinden bir bayt dizisi oluşturur. Bayt dizisine her piksel için işaretsiz bir tam sayı (32 bit çarpılmamış bir piksel değeri) yazar.

Parametreler

İlgili API Öğeleri

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

var bmd:BitmapData = new BitmapData(80, 40, true);
var seed:int = int(Math.random() * int.MAX_VALUE);
bmd.noise(seed);

var bounds:Rectangle = new Rectangle(0, 0, bmd.width, bmd.height);
var pixels:ByteArray = bmd.getPixels(bounds);

Dikdörtgen bir piksel verisi bölgesinden bir vektör dizisi oluşturur. Belirtilen dikdörtgen için, işaretsiz tam sayıların (32-bit çarpılmamış piksel değeri) bir Vector nesnesini döndürür.

Parametreler

BitmapData nesnesinin ikilik düzende 256 değerli bir histogramını hesaplar. Bu yöntem, dört Vector içeren bir Vector nesnesi döndürür.<Number> örnekleri (Number nesneleri içeren dört Vector nesnesi). Sırayla kırmızı, yeşil, mavi ve alfa bileşenlerini temsil eden dört Vector örneği. Her Vector, 0 ile 255 arasında tek bir bileşen değerinin popülasyon sayısını temsil eden 256 değer içerir.

Parametreler

Bir bitmap görüntüsü ile nokta, dikdörtgen veya başka bir bitmap görüntüsü arasında piksel düzeyinde vuruş algılaması gerçekleştirir. Vuruş, bir noktanın örtüşmesi veya opak bir piksel üzerindeki bir dikdörtgen veya iki tane örtüşen opak piksel olarak tanımlanır. Vuruş testi gerçekleştirildiğinde iki nesnenin de uzatma, döndürme veya başka bir dönüştürmesi göz önünde bulundurulmaz.

Bir görüntü opak ise, bu yöntem için tamamen opak bir dikdörtgen olarak değerlendirilir. Her iki görüntünün, saydamlığı göz önünde bulunduran piksel düzeyinde vuruş testi gerçekleştirmesi için saydam görüntüler olması gerekir. İki saydam görüntü test edilirken, alpha threshold parametreleri 0 - 255 arasında hangi alfa kanalı değerlerinin opak olarak değerlendirileceğini denetler.

Parametreler

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(80, 80, true, 0x00000000);
var rect:Rectangle = new Rectangle(20, 20, 40, 40);
bmd1.fillRect(rect, 0xFF0000FF);

var pt1:Point = new Point(1, 1);
trace(bmd1.hitTest(pt1, 0xFF, pt1)); // false
var pt2:Point = new Point(40, 40);
trace(bmd1.hitTest(pt1, 0xFF, pt2)); // true

BitmapData nesnesine başvuran Bitmap gibi nesnelerin, bu BitmapData nesnesi değiştiğinde güncellenmemesi için bir görüntüyü kilitler. Performansı artırmak için, setPixel() veya setPixel32() yöntemine birçok çağrı yapmadan önce veya yaptıktan sonra unlock() yöntemiyle birlikte bu yöntemi kullanın.

İlgili API Öğeleri

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

Kaynak görüntüden hedef görüntüye kanal öncesi karışım yapma işlemini gerçekleştirir. Kaynak ve hedef piksellerin kanal değerleri esas alınarak her kanal ve her piksel için yeni bir değer hesaplanır. Örneğin, kırmızı kanalda yeni bir değer şu şekilde hesaplanır (burada redSrc, kaynak görüntüdeki bir pikselin kırmızı kanal değeri ve redDest ise hedef görüntüde karşılık gelen pikseldeki kırmızı kanal değeridir):

new redDest = [(redSrc * redMultiplier) + (redDest * (256 - redMultiplier))] / 256;

redMultiplier, greenMultiplier, blueMultiplier ve alphaMultiplier değerleri, renk kanalının her biri için kullanılan çarpanlardır. 0 ile 0x100 (256) arasında bir onaltılık değer kullanın; burada 0, hedefteki tam değerin sonuçta kullanıldığını belirtir, 0x100 kaynaktaki tam değerin kullanıldığını belirtir ve aradaki sayılar da bir karışımın (örn. % 50 için 0x80) kullanıldığını belirtir.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(100, 80, true, 0xFF00FF00);
var bmd2:BitmapData = new BitmapData(100, 80, true, 0xFFFF0000);
var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(20, 20);
var mult:uint = 0x80; // 50% 
bmd1.merge(bmd2, rect, pt, mult, mult, mult, mult);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Görüntüyü, rastgele paraziti temsil eden piksellerle doldurur.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;

var bmd1:BitmapData = new BitmapData(80, 80);
var bmd2:BitmapData = new BitmapData(80, 80);

var seed:int = int(Math.random() * int.MAX_VALUE);
bmd1.noise(seed, 0, 0xFF, BitmapDataChannel.RED, false);
bmd2.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 90;

Her kanal için bir tane olmak üzere dört taneye kadar renk paleti verisi dizisi olan renk kanalı değerlerini yeniden eşler.

Flash çalışma zamanları, sonuç görüntüsünü oluşturmak için şu adımları kullanır:

1. Kırmızı, yeşil, mavi ve alfa değerleri hesaplandıktan sonra, standart 32 bit tam sayı aritmetiği kullanılarak bunlar birbirine eklenir.
2. Her pikselin kırmızı, yeşil, mavi ve alfa kanalı değerleri ayrı 0 - 255 değerlerine çıkarılır. Uygun dizideki yeni renk değerlerini aramak için bu değerler kullanılır: redArray, greenArray, blueArray ve alphaArray. Bu dört dizinin her biri 256 değer içermelidir.
3. Yeni kanal değerlerinin dördü de alındıktan sonra, piksele uygulanan standart bir ARGB değerine birleştirilir.

Kanallar arası efektler bu yöntemle desteklenebilir. Her girdi dizisi tam 32 bit değer içerebilir ve değerler birbirine eklendiğinde değişme oluşmaz. Bu yordam kanal başına kelepçelemeyi desteklemez.

Bir kanal için herhangi bir dizi belirtilmezse, kaynak görüntüdeki renk kanalı hedef görüntüye kopyalanır.

Genel palet eşleme (bir kanalı alıp yanlış bir renk görüntüsüne dönüştürme) gibi çeşitli efektler için bu yöntemi kullanabilirsiniz. Gama, eğriler, düzeyler ve nicelendirme gibi çeşitli gelişmiş renk işleme algoritmaları için de bu yöntemi kullanabilirsiniz.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var myBitmapData:BitmapData = new BitmapData(80, 80, false, 0x00FF0000);
myBitmapData.fillRect(new Rectangle(20, 20, 40, 40), 0x0000FF00);

var redArray:Array = new Array(256);
var greenArray:Array = new Array(256);

for(var i:uint = 0; i < 255; i++) {
    redArray[i] = 0x00000000;
    greenArray[i] = 0x00000000;
}

redArray[0xFF] = 0x0000FF00;
greenArray[0xFF] = 0x00FF0000;

var bottomHalf:Rectangle = new Rectangle(0, 0, 100, 40);
var pt:Point = new Point(0, 0);
myBitmapData.paletteMap(myBitmapData, bottomHalf, pt, redArray, greenArray);

var bm1:Bitmap = new Bitmap(myBitmapData);
addChild(bm1);

Perlin parazit görüntüsü oluşturur.

Perlin parazit oluşturma algoritması, tek tek rastgele parazit işlevlerini (oktav adı verilir), daha doğal görünümlü rastgele parazit oluşturan tek bir işleve ekleyip birleştirir. Müzik oktavları gibi her oktav işlevi, bir öncekinin frekansının iki katıdır. Perlin paraziti, farklı ayrıntı düzeyine sahip birden çok parazit kümesini birleştirdiğinden, “kırılmış parazit toplamı“ olarak açıklanır.

Ağaç damarları, bulutlar ve dağ silsileleri gibi doğal olayların ve manzaraların benzetimini yapmak için Perlin parazit işlevlerini kullanabilirsiniz. Çoğu durumda bir Perlin paraziti işlevinin çıktısı doğrudan görüntülenmez, ancak diğer görüntüleri güçlendirmek ve bunlara yapay olarak rastgele çeşitlemeler vermek için kullanılır.

Basit dijital rastgele parazit işlevleri genellikle sert, kontrastlı noktalar içeren görüntüler üretir. Bu tür sert kontrastlar genellikle doğada bulunmaz. Perlin parazit algoritması farklı ayrıntı düzeylerinde çalışan birden çok parazit işlevini harmanlar. Bu algoritma, komşu piksel değerleri arasında daha küçük çeşitlemeler verir.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(200, 200, false, 0x00CCCCCC);

var seed:Number = Math.floor(Math.random() * 10);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd.perlinNoise(100, 80, 6, seed, false, true, channels, false, null);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Kaynak görüntüsünden hedef görüntüsüne veya aynı görüntüyü kullanarak piksel erimesi gerçekleştirir. Flash çalışma zamanları, rastgele piksel erimesi oluşturmak için bir randomSeed değeri kullanır. Piksel erimesini bitinceye kadar sürdürmek için işlevin dönüş değerinin sonraki çağrılarda iletilmesi gerekir.

Kaynak görüntü hedef görüntüye dek değilse, tüm özellikler kullanılarak pikseller kaynaktan hedefe kopyalanır. Bu işlem, boş bir görüntüden tamamen doldurulmuş bir görüntüye erime gerçekleştirilmesini sağlar.

Kaynak ve hedef görüntüler eşitse, pikseller color parametresiyle doldurulur. Bu işlem, tamamen doldurulmuş bir görüntüden erime gerçekleştirilmesini sağlar. Bu modda, hedef point parametresi yok sayılır.

Parametreler

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.utils.Timer;
import flash.events.TimerEvent;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);
var bitmap:Bitmap = new Bitmap(bmd);
addChild(bitmap);

var tim:Timer = new Timer(20);
tim.start();
tim.addEventListener(TimerEvent.TIMER, timerHandler);
 
function timerHandler(event:TimerEvent):void {
    var randomNum:Number = Math.floor(Math.random() * int.MAX_VALUE);
    dissolve(randomNum);
}

function dissolve(randomNum:Number):void {
    var rect:Rectangle = bmd.rect;
    var pt:Point = new Point(0, 0);
    var numberOfPixels:uint = 100;
    var red:uint = 0x00FF0000;
    bmd.pixelDissolve(bmd, rect, pt, randomNum, numberOfPixels, red);
    var grayRegion:Rectangle = bmd.getColorBoundsRect(0xFFFFFFFF, 0x00CCCCCC, true);
    if(grayRegion.width == 0 && grayRegion.height == 0 ) {
        tim.stop();
    }
}

Görüntüyü belirli bir (x, y) piksel miktarı kaydırır. Kaydırma alanı dışındaki kenar bölgeleri değişmeden kalır.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);
var rect:Rectangle = new Rectangle(0, 0, 40, 40);
bmd.fillRect(rect, 0xFFFF0000);
            
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

trace (bmd.getPixel32(50, 20).toString(16)); // ffcccccccc

bmd.scroll(30, 0); 

trace (bmd.getPixel32(50, 20).toString(16)); // ffff0000

Bir BitmapData nesnesinin tek bir pikselini ayarlar. Görüntü pikselinin geçerli alfa kanalı değeri bu işlem sırasında korunur. RGB color parametresinin değeri, çarpılmamış bir renk değeri olarak değerlendirilir.

Not: Performansı artırmak için, setPixel() veya setPixel32() yöntemini art arda kullandığınızda, setPixel() ya da setPixel32() yöntemini çağırmadan önce lock() yöntemini çağırın ve sonra da tüm piksel değişikliklerini yaptığınızda unlock() yöntemini çağırın. Bu işlem, bu BitmapData örneğine başvuran nesnelerin siz piksel değişikliklerini tamamlayıncaya kadar güncellenmesini önler.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, false, 0xCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0xFF0000;
    bmd.setPixel(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

BitmapData nesnesinin tek bir pikselinin renk ve alfa saydamlığı değerlerini ayarlar. Bu yöntem, setPixel() yöntemine benzer; ana fark, setPixel32() yönteminin, alfa kanalı bilgilerini içeren bir ARGB renk değerini almasıdır.

Bir BitmapData nesnesindeki tüm pikseller, önceden çarpılmış renk değerleri olarak saklanır. Önceden çarpılmış görüntü pikseli, zaten alfa verileriyle çarpılmış kırmızı, yeşil ve mavi renk kanalı değerlerine sahiptir. Örneğin alfa değeri 0 ise, çarpılmamış değerlerinden bağımsız olarak RGB kanallarının değerleri de 0 olur. Bu veri kaybı, işlemleri gerçekleştirirken bazı sorunlar yaşamanıza neden olabilir. Tüm BitmapData yöntemleri, çarpılmamış değerleri alır ve döndürür. Dahili piksel temsili, bir değer olarak döndürülmeden önce, önceden çarpılmış durumdan çarpılmamış duruma dönüştürülür. Ayarlama işlemi sırasında, ham görüntü pikseli ayarlanmadan önce piksel değeri önceden çarpılır.

Not: Performansı artırmak için, setPixel() veya setPixel32() yöntemini art arda kullandığınızda, setPixel() ya da setPixel32() yöntemini çağırmadan önce lock() yöntemini çağırın ve sonra da tüm piksel değişikliklerini yaptığınızda unlock() yöntemini çağırın. Bu işlem, bu BitmapData örneğine başvuran nesnelerin siz piksel değişikliklerini tamamlayıncaya kadar güncellenmesini önler.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0x60FF0000;
    bmd.setPixel32(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Bir bayt dizisini dikdörtgen bir piksel verisi bölgesine dönüştürür. Her piksel için ByteArray.readUnsignedInt() yöntemi çağrılır ve dönüş değeri piksele yazılır. Tam dikdörtgen çizilmeden önce bayt dizisi sonlandırılırsa işlev döndürülür. Bayt dizisindeki verilerin 32 bit piksel değerinde olması beklenir. Pikseller okunduktan önce veya sonra bayt dizisi üzerinde arama işlemi gerçekleştirilmez.

Parametreler

İlgili API Öğeleri

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.utils.ByteArray;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(100, 100, true, 0xFFCCCCCC);
var bmd2:BitmapData = new BitmapData(100, 100, true, 0xFFFF0000);

var rect:Rectangle = new Rectangle(0, 0, 100, 100);
var bytes:ByteArray = bmd1.getPixels(rect);

bytes.position = 0;
bmd2.setPixels(rect, bytes);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Bir Vector öğesini dikdörtgen bir piksel verisi bölgesine dönüştürür. Her piksel için bir Vector öğesi okunur ve BitmapData pikseline yazılır. Vector öğesindeki verilerin 32 bit ARGB piksel değerinde olması beklenir.

Parametreler

Bir görüntüdeki piksel değerlerini belirtilen eşiğe karşı test eder ve testi geçen pikselleri yeni renk değerlerine ayarlar. threshold() yöntemini kullanarak bir görüntüdeki renk aralıklarını yalıtabilir ve değiştirebilir ve görüntü pikselleri üzerinde diğer mantıksal işlemleri gerçekleştirebilirsiniz.

threshold() yönteminin test mantığı şu şekildedir:

1. ((pixelValue & mask) operation (threshold & mask)) olursa, piksel color olarak ayarlanır;
2. Aksi takdirde, copySource == true olursa, piksel sourceBitmap içindeki karşılık gelen piksel değerine ayarlanır.

operation parametresi, eşik testi için kullanılacak karşılaştırma operatörünü belirtir. Örneğin operation parametresi olarak "==" öğesini kullanarak bir görüntüdeki belirli bir renk değerini yalıtabilirsiniz. Veya {operation: "<", mask: 0xFF000000, threshold: 0x7F000000, color: 0x00000000} öğesini kullanarak kaynak görüntü pikselinin alfası 0x7F değerinden düşük olduğunda tüm hedef pikselleri tamamen saydam olacak şekilde ayarlayabilirsiniz. Animasyonlu geçişler ve diğer efektler için bu tekniği kullanabilirsiniz.

Parametreler

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.geom.Point;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);

var seed:int = int(Math.random() * int.MAX_VALUE);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd1.perlinNoise(100, 80, 12, seed, false, true, channels, false, null);

var bitmap1:Bitmap = new Bitmap(bmd1);
addChild(bitmap1);

var bmd2:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);
var pt:Point = new Point(0, 0);
var rect:Rectangle = new Rectangle(0, 0, 200, 200);
var threshold:uint =  0x00800000; 
var color:uint = 0x20FF0000;
var maskColor:uint = 0x00FF0000;
bmd2.threshold(bmd1, rect, pt, ">", threshold, color, maskColor, true);

var bitmap2:Bitmap = new Bitmap(bmd2);
bitmap2.x = bitmap1.x + bitmap1.width + 10;
addChild(bitmap2);

BitmapData nesnesine başvuran Bitmap gibi nesnelerin, bu BitmapData nesnesi değiştiğinde güncellenmesi için bir görüntünün kilidini kaldırır. Performansı artırmak için, setPixel() veya setPixel32() yöntemine birçok çağrı yapmadan önce veya yaptıktan sonra lock() yöntemiyle birlikte bu yöntemi kullanın.

Parametreler

İlgili API Öğeleri

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

1. Bir url özelliği oluşturulur; bu, görüntü dosyasının konumu ve adıdır.
2. Sınıf yapıcısı bir Loader nesnesi oluşturur; bu nesne de, completeHandler() yöntemi görüntü işlemeyi tamamladığında gönderilen bir olay dinleyicisini başlatır.
3. Daha sonra, request URLRequest nesnesi loader.load() öğesine iletilir, böylece görüntüleme nesnesi kullanılarak görüntü belleğe yüklenir.
4. Ardından görüntü, ekranda x = 0, y = 0 koordinatlarında görüntüyü gösteren görüntüleme listesine yerleştirilir.
5. completeHandler() yöntemi daha sonra şunları yapar:
   • Loader nesnesiyle başlatılan bir Bitmap nesnesiyle birlikte ikinci bir Loader öğesi oluşturur.
   • Orijinal görüntünün kopyasını oluşturan duplicateImage() yöntemini çağıran ikinci bir Bitmap nesnesi (duplicate) oluşturur.
   • duplicate nesnesinin BitmapData nesnesine atanan bir BitmapData nesnesi oluşturur.
   • Orijinal görüntüyle aynı koordinatlar, genişlik ve yükseklikle başlatılan yeni bir Rectangle nesnesi oluşturur.
   • x = 0, y = 0 varsayılan ayarlı yeni bir Point nesnesi oluşturur.
   • Şu değişkenleri oluşturur:
     • operation — Eşik değeri, orijinalden daha yüksek veya orijinale eşitse yeni rengi uygular.
     • threshold — Her pikselin karşılaştırıldığı değer (bu örnekte, 0xCC alfasıyla açık gri).
     • color — Piksellerin eşik testini geçmek için ayarlandığı renk, bu durumda düz sarıdır.
     • mask — Rengin tam karşıtı (saydam mavi).
     • copySource — false değerine ayarlanır ve eşik değerinin geçmemesi durumunda piksel değerlerinin kopyalanmadığını belirtir. Görüntü çoğaltıldığı ve yalnızca eşik testini geçen pikseller değiştirildiği için bu değerin bir anlamı yoktur.
   • Önceki değişkenleri kullanarak threshold() yöntemini çağırır. Sonuçta elde edilen eşik denklemi şu şekildedir: (geçerli piksel Değeri & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) olursa, piksel 0xFFFFFF00 olarak ayarlanır.

Notlar:

• SWF dosyasını Yerel Oynatma Güvenliği, Yalnızca Yerel Dosyalara Erişim şeklinde ayarlanmış biçimde derlemeniz gerekir.
• Bu örnek, Image.gif adlı bir dosyanın SWF dosyanızla aynı dizine yerleştirilmesini gerektirir.
• En fazla yaklaşık 80 piksel genişlikte bir görüntü kullanmanız önerilir.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapDataExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapDataExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}