File  - AS3

Папка с установленными файлами приложения.

Свойство url для этого объекта использует схему URL-адресов app (не схему file). Это означает, что строка url открывается записьюapp: (а не file:). Кроме того, если создается объект File, связанный с каталогом File.applicationDirectory (с помощью метода resolvePath()), то url объекта File также использует схему URL-адреса app (как в примере).

Примечание. В файлы или каталоги, в путях которых используется схема URL-адреса app:, невозможно производить запись. Также невозможно удалять или создать файлы и папки с путями, в которых используется схема URL-адреса app:. Изменение содержимого в каталоге программы не является оптимальным методом по причинам, связанным с безопасностью, и блокируется операционной системой на некоторых платформах. Если требуется сохранить какие-то данные приложения, лучше использовать каталог хранения данных приложения (File.applicationStorageDirectory). Если необходимо предоставить какому-либо содержимому в каталоге хранения программы доступ к отдельным функциям программы (API-интерфейсы AIR), можно поместить эти функции в изолированную программную среду безопасности.

Свойство applicationDirectory позволяет создать ссылку на каталог приложения, который будет действительным для всех платформ. Если задать объект File для ссылки на каталог приложения с помощью свойства nativePath или url, эта ссылка будет работать только на той платформе, для которой этот путь является действительным.

На платформе Android свойство nativePath объекта File, указывающее на каталог программы, является пустой строкой. Используйте свойство url для доступа к файлам программы.

Связанные элементы API

Каталог для хранения данных приложения.

Каждое приложение AIR имеет свой постоянный каталог для хранения данных, который создается при первом вызове File.applicationStorageDirectory. Этот каталог уникален для каждого приложения и каждого пользователя. Этот каталог очень удобен для хранения данных приложения или пользователей.

При удалении программы AIR удаление каталога хранения программы и ее файлов программой удаления зависит от платформы.

Свойство url для этого объекта использует схему URL-адреса app-storage (не схему file). Это означает, что строка url открывается записьюapp-storage: (а не file:). Кроме того, если создается объект File, связанный с каталогом File.applicationStoreDirectory (с помощью метода resolvePath()), то url объекта File также использует схему URL-адреса app-storage (как в примере).

Свойство applicationStorageDirectory позволяет создать ссылку на каталог хранилища приложения, который будет действительным для всех платформ. Если задать объект File для ссылки на каталог хранилища приложения с помощью свойства nativePath или url, эта ссылка будет работать только на той платформе, для которой этот путь является действительным.

Примечание (только для Mac OS). Для соответствия требованиям Mac App Store физическое расположение этого каталога в AIR 3.3 изменилось по сравнению с AIR 3.2:

• Пространство имен 3.2 и более ранних версий: ~/Library/Preferences/appid/Local Store/
• Пространство имен 3.3 и более поздних версий: path/Library/Application Support/appid/Local Store/, где path соответствует ~/Library/Containers/bundle-id/Data (изолированная среда) или ~ (при выполнении за пределами изолированной среды)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Каталог кэша приложения.

Свойство cacheDirectory служит для обращения к каталогу кэша. Приложению рекомендуется хранить в каталоге кэша файлы, которые можно заново загрузить с сервера или восстановить иным образом. В каталог кэша помещаются, например, следующие файлы: файлы кэша базы данных и загружаемый контент, используемый электронными журналами, газетами и картографическими приложениями.

Если задать объект File для ссылки на каталог кэша с помощью свойства nativePath или url, эта ссылка будет работать только на тех платформах, на которых этот путь является действительным.

Если операционная система не поддерживает каталог кэша, cacheDirectory получает значение null.

Каталог рабочего стола пользователя.

Свойство desktopDirectory позволяет создать ссылку на каталог рабочего стола, который будет действительным для всех платформ. Если задать объект File для ссылки на каталог рабочего стола с помощью свойства nativePath или url, эта ссылка будет работать только на той платформе, для которой этот путь является действительным.

Если операционная система не поддерживает каталог рабочего стола, вместо него используется соответствующий каталог файловой системы.

На устройствах AIR for TV отсутствует понятие каталога рабочего стола пользователя. Поэтому свойство desktopDirectory ссылается на тот же каталог, что и свойство File.userDirectory. Каталог пользователя уникален для программы.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Каталог с документами пользователя.

В Windows это каталог «Мои документы» (например, C:\Documents and Settings\имя_пользователя\Мои документы). В Mac OS это по умолчанию каталог /Users/имя_пользователя/Documents. В Linux это по умолчанию каталог /home/имя_пользователя/Documents (в англоязычной системе), и это свойство учитывает настройку xdg-user-dirs.

Свойство documentsDirectory позволяет создать ссылку на каталог документов, который будет действительным для всех платформ. Если задать объект File для ссылки на каталог документов с помощью свойства nativePath или url, эта ссылка будет работать только на той платформе, для которой этот путь является действительным.

Если операционная система не поддерживает каталог документов, вместо него используется соответствующий каталог файловой системы.

На устройствах AIR for TV отсутствует понятие каталога документов пользователя. Поэтому свойство documentsDirectory ссылается на тот же каталог, что и свойство File.userDirectory. Каталог пользователя уникален для программы.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Указывает, был ли файл или каталог, указанный в ссылке, загружен из Интернета.

Это свойство имеет значение только для операционных систем, в которых файлы могут помечаться во время загрузки:

• ОС Windows XP с пакетом обновления SP2 или более поздним и ОС Windows Vista
• ОС Mac OS 10.5 и более поздних версий

В системах, которые не помечают загруженные файлы, такие как Linux, это свойство неприменимо (и имеет значение false).

Связанные элементы API

Определяет, существует ли файл или каталог, на который дается ссылка. Значение true присваивается, если объект File указывает на существующий файл или каталог, в противном случае присваивается значение false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Объект Icon, содержащий значки, заданные для этого файла. Объект Icon является массивом объектов BitmapData, связанных с различными состояниями значков. В Linux объект Icon не содержит значков. На платформе Android свойство icon имеет значение null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Указывает, ведет ли ссылка на каталог. Значение true присваивается, если объект File указывает на каталог, в противном случае присваивается значение false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Указывает, являются ли файл или каталог, на которые ведет ссылка, скрытыми. Значение true присваивается, если файл или каталог, на которые указывает ссылка, являются скрытыми, в противном случае присваивается значение false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Указывает, является ли каталог, на который ссылаются, пакетом.

Значение true присваивается, если каталог, на который ссылаются, является пакетом, в противном случае присваивается значение false. Обратите внимание, что в классе File не предусмотрено прямое создание пакетов.

• В Mac OS каталог может быть назначен пакетом и в этом случае будет отображаться в диспетчере файлов Finder как единый файл, а не как каталог. Этому свойству присваивается значение true, если каталог, на который ссылается объект, является пакетом; или значение false, если файл не является каталогом или пакетом или его не существует.
• В других операционных системах это свойство всегда имеет значение false.

Указывает, является ли ссылка символьной.

Значение true присваивается, если объект File указывает на каталог, в противном случае присваивается значение false. Обратите внимание, что в классе File не предусмотрено прямое создание символьных ссылок.

С помощью символьных ссылок один файл может ссылаться на другой файл или каталог на диске. Не путайте символьные ссылки с псевдонимами в Mac OS и ярлыками в Windows, это не одно и то же. Псевдонимы и ярлыки всегда считаются файлами (не каталогами), а чтение или запись псевдонимов и ярлыков не изменяет файлы, на которые они указывают. Символьная ссылка, в свою очередь, повторяет поведение файла или каталога, на который она указывает. Она может считаться файлом или каталогом, а при чтении и записи символьной ссылки изменения будут производиться над самим файлом, на который она указывает, а не только над ссылкой. Удаление символьной ссылки приводит к удалению самой ссылки, а не целевого объекта.

Операционные системы Mac^® OS^®, Linux и Windows^® Vista^® поддерживают символьные ссылки. Кроме этого, в Windows свойство isSymbolicLink для объекта File, ссылающегося на точку соединения (используется в файловой системе NTFS) имеет значение true.

Последовательность символов закрытия строки, используемая домашней операционной системой.

В Mac OS и Linux это знак перевода строки (шестнадцатеричный код символа 0x0A). В ОС Windows это знак возврата каретки (шестнадцатеричный код символа 0x0D) в сочетании со знаком перевода строки (шестнадцатеричный код символа 0x0A).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Полный путь в представлении домашней операционной системы. В Mac OS и Linux в качестве разделителя в записи пути используется левая косая черта (/). Однако в Windows можно задать свойство nativePath, используя в качестве разделителя в записи пути прямую (/) или обратную (\) косую черту, а AIR автоматически заменит все прямые косые черты обратными.

Прежде чем написать код для прямого задания свойства nativePath, подумайте, не приведет ли это к созданию кода, который будет работать только на одной конкретной платформе. Например, такой собственный путь, как C:\\Documents and Settings\\bob\\Desktop, действителен только для Windows. Рекомендуется использовать следующие статические свойства, представляющие часто используемые каталоги и действительные для всех платформ:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Можно вызвать метод resolvePath(), чтобы получить относительный путь к этим каталогам.

Некоторые интерфейсы Flex API, например, свойство source класса SWFLoader, используют URL-адрес (свойство url объекта File), а не собственный путь (свойство nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Каталог, содержащий файл или каталог, на который ссылается данный объект File.

Если файла или каталога не существует, свойство parent все равно будет возвращать объект File, указывающий на каталог, содержащий файл или каталог, даже если его не существует.

Это свойство идентично возвращаемому значению для функции resolvePath(".."), но при этом родительскому элементу корневого каталога присваивается значение null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Определяет, предоставлено или нет приложению разрешение на доступ к файловой системе.

Связанные элементы API

Указывает, предотвращает ли среда выполнение резервного копирования этого объекта File в облаке.

Если это свойство имеет значение true, файл не будет подвергаться автоматическому резервному копированию в облако на платформах, имеющих такую функцию. Значением по умолчанию этого свойства является false.

Разделительный символ, используемый в домашней операционной системе.

В Mac OS и Linux таким разделителем является левая косая черта (/). В ОС Windows это обратная косая черта (\).

Примечание. При использовании обратной косой черты в строковом литерале необходимо вводить ее дважды (например, directory\\file.ext). Две обратных косых черты в строковом литерале идентичны одной обратной косой черте в строке.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Доступное для использования пространство в данном местоположении File, в байтах.

Если объект File ссылается на каталог, spaceAvailable указывает на объем пространства в каталоге, доступный для использования файлами. Если объект File ссылается на файл, spaceAvailable указывает доступный объем увеличения файла. Если местоположение файла не существует, spaceAvailable имеет значение 0. Если объект File указывает на символическую ссылку, spaceAvailable указывает на доступное пространство в указанном символической ссылкой местоположении.

Как правило, доступное для файла или каталога пространство равно такому пространству в томе, содержащем этот файл или каталог. Однако при выделении доступного пространства могут учитываться квоты и ограничения, установленные для каталогов.

При добавлении файла или каталога в том, как правило, требуется больше места, чем фактический размер файла или содержимого каталога. Например, операционной системе может потребоваться дополнительное место для хранения информации указателей. Или секторам диска может потребоваться дополнительное пространство. К тому же, доступное пространство динамически изменяется. Поэтому выделение всего требуемого пространства для хранения файлов может быть невозможно.

Кодировка по умолчанию, используемая домашней операционной системой.

Возможные значения включают "windows-1252" "shift-jis", "cn-gb", "iso-8859-1" и другие. Полный список см. в разделе Поддерживаемые наборы символов.

Это значение можно использовать с методами readMultiByte() и writeMultiByte() класса FileStream.

Связанные элементы API

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

URL-адрес данного пути к файлу.

Если это ссылка на путь в каталог хранения данных приложения, схема URL будет app-storage. Если это ссылка на путь в каталог приложения, схема URL будет app. Во всех остальных случаях схема будет file.

Для присвоения значения свойству url рекомендуется использовать знаки пробела (вместо "%20"). AIR автоматически кодирует строки (например, переводит пробелы в "%20").

Связанные элементы API

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Каталог пользователя.

В ОС Windows это родительский элемент каталога «Мои документы» (например, C:\Мои документы\имя_пользователя). В Mac OS это /Users/имя_пользователя. В Linux это /home/имя_пользователя.

Свойство userDirectory позволяет создать ссылку на каталог пользователя, который будет действительным для всех платформ. Если задать свойство nativePath или url объекта File напрямую, ссылка будет работать только на той платформе, для которой она является действительной.

Если операционная система не поддерживает каталог пользователя, вместо него используется соответствующий каталог файловой системы.

На устройствах AIR for TV свойство userDirectory ссылается на каталог пользователя, который уникален для программы.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Функция конструктора для класса File.

При передаче аргумента path объект File указывает на конкретный путь, а свойства nativePath и url отражают этот путь.

Хотя можно передать аргумент path, чтобы указать путь к файлу, в результате может получиться код, предназначенный для конкретной платформы. Например, такой собственный путь, как "C:\\Documents and Settings\\bob\\Desktop", или такой URL-адрес, как "file:///C:/Documents%20and%20Settings/bob/Desktop", действителен только для Windows. Рекомендуется использовать следующие статические свойства, представляющие часто используемые каталоги и действительные для всех платформ:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Затем можно вызвать метод resolvePath(), чтобы получить относительный путь к этим каталогам. Например, следующий код задает объект File для указания на файл settings.xml в каталоге хранилища приложения:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Важно! Если передать строку URL в параметре path, URL декодируется и преобразуется в путь к файлу. Например, оператор new File("file:///c:/test/demo%20file%201%2e0.txt") создает объект File с собственным путем «c:\test\demo file 1.0.txt». (URL-адрес использует префиксы схемы file:, app: или app-storage:.) Однако, если допустимые префиксы URL-адреса пропускаются, строка пути рассматривается как собственный путь и не подвергается декодированию. Необходимо учитывать это поведение при проверке путей, полученных из потенциально ненадежных источников. Если просто проверяется строка ввода, расшифровка URL-адреса может позволить злоумышленнику обойти проверки. Всегда проверяйте окончательный путь создаваемого объекта File.

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Связанные элементы API

Отображает для пользователя диалоговое окно выбора каталога. При выборе каталога вызывается событие select. Свойство target события select является объектом File, указывающим на выбранный каталог.

Диалоговое окно выбора каталога не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Примечание. На устройствах Android browseForDirectory() не поддерживается. Объект File незамедлительно отправляет событие cancel.

Параметры

Связанные элементы API

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Отображает диалоговое окно «Открыть файл», где можно выбрать файл для открытия.

При выборе файла вызывается событие select. Свойство target события select — это объект File, указывающий на выбранный файл.

Диалоговое окно «Открыть файл» не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Примечание. На устройствах Android установка заголовка диалогового окна файла невозможна. Параметр title игнорируется.

Параметры

Связанные элементы API

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Отображает диалоговое окно «Открыть файл», в котором можно выбрать один или несколько файлов для открытия.

При выборе файлов вызывается событие selectMultiple. Свойство target события select является этим объектом File. В отличие от browseForOpen(), применение метода browseForOpenMultiple() не делает объект File ссылкой на выбранные файлы. Вместо этого конечное событие selectMultiple содержит массив выбранных файлов.

Диалоговое окно «Открыть файл» не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Примечание. На устройствах Android установка заголовка диалогового окна файла невозможна. Параметр title игнорируется.

Параметры

Связанные элементы API

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Отображает диалоговое окно «Сохранить файл», в котором можно выбрать место назначения файла.

При выборе файла вызывается событие select. Свойство target события select является объектом File, который указывает на выбранное место для сохранения файла.

Диалоговое окно «Сохранить файл» не всегда отображается на переднем плане относительно окон, которые принадлежат другому окну (окна, свойство owner которых имеет непустое значение). Для предотвращения проблем, связанных с порядком окон, перед вызовом этого метода скройте подчиненные окна.

Примечание. На устройствах Android установка заголовка диалогового окна файла невозможна. Параметр title игнорируется.

Параметры

Связанные элементы API

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Отменяет все операции, ожидающие выполнения.

Устанавливает путь к файлу в качестве канонического.

Если объект File представляет собой существующий файл или каталог, при установлении пути как канонического он корректируется в соответствии с регистром в имени реального файла или каталога. Если объект File — символьная ссылка, при установлении пути как канонического он корректируется для соответствия файлу или каталогу, на который указывает ссылка, независимо от того, существует ли такой файл или каталог. В файловых системах, учитывающих регистр (например, Linux), когда существует несколько файлов, имена которых отличаются только регистром, метод canonicalize() корректирует путь в соответствии с первым найденным файлом (в порядке, определенном файловой системой).

Кроме того, при установлении канонического пути в ОС Windows короткие имена файлов переводятся в длинные.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Возвращает копию данного объекта File. Регистрации событий не копируются.

Примечание. Данный метод не копирует сам файл. Он просто создает копию экземпляра объекта File ActionScript. Для копирования файла пользуйтесь методом copyTo().

Перемещает файл или каталог из места, заданного объектом File, в место, заданное параметром newLocation. Процесс копирования создает все необходимые родительские каталоги (если возможно). Перезаписывая файлы с помощью copyTo (), атрибуты file также перезаписаны.

Параметры

Связанные элементы API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Начинает копирование файла или каталога из места, указанного данным объектом File, в место, заданное параметром destination.

После завершения вызывается событие complete (в случае успешного выполнения) или ioError (в случае невозможности завершения). Процесс копирования создает все необходимые родительские каталоги (если возможно).

Параметры

Связанные элементы API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Создает указанный каталог и все необходимые родительские каталоги. Если каталог уже существует, никаких действий не предпринимается.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Возвращает ссылку на новый временный каталог. Это новый каталог в пути временного системного каталога.

Этот метод позволяет определить новый уникальный каталог, не отправляя запрос системе.

Перед закрытием приложения рекомендуется удалять временные каталоги, так как не некоторых устройствах они не удаляются автоматически.

Связанные элементы API

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Возвращает ссылку на новый временный файл. Это новый файл в пути временного системного каталога.

Этот метод позволяет определить новый уникальный файл, не запрашивая об этом систему.

Перед закрытием приложения рекомендуется удалять временные файлы, так как они не удаляются автоматически.

Связанные элементы API

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Удаляет каталог. Если этот объект File является символьной ссылкой на каталог, то удаляется эта ссылка, а не сам каталог.

Параметры

Связанные элементы API

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Удаляет каталог в асинхронном режиме. Если этот объект File является символьной ссылкой на каталог, то удаляется эта ссылка, а не сам каталог.

Параметры

Связанные элементы API

Удаляет файл. Если этот объект File является символьной ссылкой, то удаляется эта ссылка, а не целевой файл.

Связанные элементы API

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Удаляет файл в асинхронном режиме. Если этот объект File является символьной ссылкой, то удаляется эта ссылка, а не целевой файл.

Связанные элементы API

Возвращает массив объектов File, связанных с файлами и каталогами, размещенными в каталоге, представленном данным объектом File. При использовании этого метода не рассматривается содержимое подкаталогов.

Связанные элементы API

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

В асинхронном режиме формирует массив объектов File, связанных с содержимым каталога, который представляется данным объектом File.

Связанные элементы API

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Находит среди двух путей к файлу относительный путь.

Относительный путь — это список компонентов, которые могут быть добавлены (разрешены по отношению) к этой ссылке для обнаружения второй (параметрической) ссылки. Для записи возвращенного относительного пути используется разделитель «/».

В других случаях относительные пути могут содержать ссылки «..», но такие пути не могут превышать предельного объема.

Параметры

Возвращается массив объектов File, в котором перечислены корневые каталоги файловой системы.

Например, в ОС Windows это список томов, таких как C: и D:. Пустой том, например CD- или DVD-привод, в который не установлен диск, не учитывается в массиве. В Mac OS и Linux этот метод всегда возвращает уникальный корневой каталог компьютера (каталог «/»)

В файловых системах, в которых чтение корневого каталога невозможно, например в файловой системе Android, свойства возвращенного объекта File не всегда отражают истинное значение. Например, на платформе Android свойство spaceAvailable возвращает значение 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Перемещает файл или каталог из места, заданного объектом File, в место, заданное параметром destination.

Для переименования файла задайте параметр destination, чтобы он указывал на путь в каталог, содержащий файл, но с другим именем файла.

Процесс перемещения создает все необходимые родительские каталоги (если возможно).

Параметры

Связанные элементы API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Перемещает файл или каталог из места, заданного объектом File, в место, заданное параметром newLocation.

Для переименования файла задайте параметр destination, чтобы он указывал на путь в каталог, содержащий файл, но с другим именем файла.

Процесс перемещения создает все необходимые родительские каталоги (если возможно).

Параметры

Связанные элементы API

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Перемещает файл или каталог в корзину.

Примечание. В операционных системах, которые не поддерживают концепцию восстанавливаемой папки корзины, файлы сразу же удаляются.

Связанные элементы API

Перемещает файл или каталог в корзину в асинхронном режиме.

Примечание. В операционных системах, которые не поддерживают концепцию восстанавливаемой папки корзины, файлы сразу же удаляются.

Связанные элементы API

Открывает файл в программе, назначенной в операционной системе для открытия данного типа файлов.

AIR препятствует использованию метода File.openWithDefaultApplication() для открытия определенных файлов. В ОС Windows AIR препятствует открытию файлов определенного типа (с расширениями, перечисленными ниже). В системах Mac OS и Linux среда выполнения AIR не позволяет открывать файлы, которые запускаются в специальных приложениях, перечисленных ниже. При попытке открыть такие файлы с помощью метода openWithDefaultApplication() выдается исключение. Однако эти ограничения не распространяются на программы AIR, устанавливаемые с помощью собственной программы установки (то есть расширенные программы профиля рабочего стола). Они могут открывать файлы любого типа.

Нельзя открывать документы из каталога программы.

В приведенной ниже таблице перечислены расширения файлов, запрещенные в ОС Windows, а также программы, которые нельзя запускать в ОС Mac OS и ОС Linux.

Связанные элементы API

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Запрашивает разрешение на доступ к файловой системе.

Создает новый объект File с относительным для данного объекта File путем, на основе параметра path (строки).

В качестве параметра path можно использовать относительный или абсолютный путь.

При указании относительного пути заданный path добавляется в конец пути объекта File. Однако использование «..» в записи path может вернуть путь, не являющийся дочерним путем объекта File. Полученная ссылка не обязательно должна ссылаться на действительное место расположения файловой системы.

При указании абсолютной ссылки на файл метод возвращает объект File, указывающий на этот путь. В абсолютной ссылке на файл должен использоваться допустимый синтаксис пути, присущий операционной системе пользователя (например, "C:\\test" в Windows). Не используйте URL-адрес (например, file:///c:/test) в качестве параметра path.

Все полученные пути нормализуются следующим образом:

• Все элементы «.» игнорируются.
• Все элементы «..» замещают родительские записи.
• Ни одна ссылка «..», достигающая корневого каталога файловой системы или корневого каталога хранения данных приложения, не проходит этот узел; такие ссылки игнорируются.

В качестве разделителя в записи пути всегда следует использовать левую косую черту (/). В ОС Windows также можно использовать обратную косую черту (\), но этого делать не следует. Использование обратной наклонной черты может привести к тому, что программы не смогут работать на других платформах.

Имена файлов и каталогов в Linux чувствительны к регистру.

Параметры

Вызывается при отмене асинхронной операции, ожидающей выполнения.

Это событие имеет следующие свойства:

Вызывается при завершении асинхронной операции.

Это событие имеет следующие свойства:

Вызывается, когда в результате запроса метода getDirectoryListingAsync() становится доступен список каталогов.

Это событие имеет следующие свойства:

Связанные элементы API

Вызывается, когда при выполнении асинхронной операции над файлом происходит ошибка.

Это событие имеет следующие свойства:

Отправляется, когда приложение запрашивает разрешение на доступ к файловой системе. Проверяет значение свойства status, чтобы определить, предоставлено разрешение или нет

Связанные элементы API

Вызывается, когда операция нарушает ограничения безопасности.

Это событие имеет следующие свойства:

Вызывается, когда пользователь выбирает файл или каталог из окна просмотра файлов или каталогов.

Это событие имеет следующие свойства:

Вызывается, когда пользователь выбирает файлы из диалогового окна, открывшегося по вызову метода browseForOpenMultiple().

Связанные элементы API