LoaderInfo  - AS3

Версия ActionScript загруженного SWF-файла. Версия языка задается с помощью перечислений в классе ActionScriptVersion, таких как ActionScriptVersion.ACTIONSCRIPT2 и ActionScriptVersion.ACTIONSCRIPT3.

Примечание. Это свойство всегда имеет значение ActionScriptVersion.ACTIONSCRIPT2 или ActionScriptVersion.ACTIONSCRIPT3. ActionScript 1.0 и 2.0 указываются как ActionScriptVersion.ACTIONSCRIPT2 (версия 2.0). Это свойство служит только для того, чтобы отличать ActionScript 1.0 и 2.0 от ActionScript 3.0.

Связанные элементы API

При загрузке внешнего SWF-файла все определения ActionScript 3.0 в загруженном классе сохраняются в свойстве applicationDomain.

Все программные коды в SWF-файле определены для существования в домене приложения. Текущим доменом приложения является домен, где выполняется основное приложение. Системный домен содержит все домены приложений, включая текущий домен и все классы проигрывателя Flash Player или Adobe AIR.

Все домены приложений, кроме системного, имеют связанный родительский домен. Родительским доменом свойства applicationDomain основного приложения является системный домен. Загруженные классы определяются только в том случае, если они уже не определены в своих родительских классах. Нельзя перезаписать определение загруженного класса новым определением.

Примеры использования доменов приложений см. в главе «Среда клиентской системы» Руководства разработчика по ActionScript 3.0.

Связанные элементы API

Байты, связанные с объектом LoaderInfo.

Число загруженных байт мультимедиа-содержимого. Когда это число равно значению bytesTotal, загружено все содержимое.

Число упакованных байт во всем мультимедийном файле.

До отправки первого события progress соответствующим объектом Loader данного объекта LoaderInfo, bytesTotal имеет значение 0. После отправки события progress объектом Loader bytesTotal отражает фактическое количество байт для загрузки.

Примечание (только для iOS). При выполнении приложения на iOS возвращаемое значение будет отличаться от значений на других платформах.

Связанные элементы API

Означает доверительные отношения со стороны содержимого (дочернего элемента) к загрузчику (родительскому элементу). Если дочерний элемент имеет право доступа к родительскому, значение — true; в противном случае значение — false. Это свойство имеет значение true, если дочерний объект вызвал метод allowDomain() для предоставления права доступа родительскому домену или если в дочернем домене загружена политика URL-адресов, предоставляющая доступ родительскому домену. Если дочерний объект и родительский объект находятся в том же домене, это свойство имеет значение true.

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

Объект, который может быть задан кодом загруженного содержимого, чтобы сделать свойства и методы доступными для кода в изолированной программной среде объекта Loader. Мост изолированной программной среды позволяет содержимому не из домена приложения получить управляемый доступ к сценариям в изолированной программной среде приложения, и наоборот. Этот мост служит своеобразным шлюзом между изолированными программными средами, обеспечивая открытое взаимодействие между изолированной программной средой приложения и другими изолированными средами.

Связанные элементы API

Загруженный объект, связанный с данным объектом LoaderInfo.

Тип MIME загруженного файла. Имеет значение null, если файл загружен недостаточно для определения его типа. В следующем списке перечислены возможные значения.

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

Номинальная частота кадров загруженного SWF-файла (в кадрах в секунду). Значение часто бывает целым числом, хотя это не обязательно.

Это значение может отличаться от фактически используемой частоты кадров. Проигрыватель Flash Player или Adobe AIR одновременно использует одну частоту кадров для всех загруженных SWF-файлов. Она определяется номинальной частотой кадров основного SWF-файла. Иногда невозможно достичь основной частоты кадров в зависимости от аппаратного обеспечения, звуковой синхронизации и других факторов.

Номинальная высота загруженного файла. Это значение может отличаться от фактической высоты области отображения содержимого, так как масштаб загруженного содержимого или его родительских экранных объектов может изменяться.

Указывает, усечено ли свойство LoaderInfo.url. Когда свойство isURLInaccessible имеет значение true, свойство LoaderInfo.url содержит только домен конечного URL-адреса, с которого загружается содержимое. Например, свойство усекается, если содержимое загружается со страницы http://www.adobe.com/assets/hello.swf и свойство LoaderInfo.url имеет значение http://www.adobe.com. Свойство isURLInaccessible имеет значение true, только когда верны все перечисленные ниже условия.

• Во время загрузки содержимого произошла переадресация HTTP.
• SWF-файл, вызывающий метод Loader.load(), находится не в том домене, к которому относится конечный URL-адрес содержимого.
• SWF-файл, вызывающий метод Loader.load(), не имеет разрешения на доступ к содержимому. Разрешение на доступ к содержимому предоставляется так же, как для метода BitmapData.draw(): вызовите метод Security.allowDomain(), чтобы получить доступ к SWF-файлу (или, если требуется доступ к другому типу содержимого, создайте файл политики и используйте свойство LoaderContext.checkPolicyFile).

Примечание. Свойство isURLInaccessible впервые добавлено в версии Flash Player 10.1 и AIR 2.0. Однако оно доступно для SWF-файлов, созданных во всех версиях, если его поддерживает среда выполнения Flash. Таким образом, использование «строгого режима» в некоторых инструментах разработки приводит к возникновению ошибки. Чтобы обойти эту ошибку, используйте косвенный синтаксис myLoaderInfo ["isURLInaccessible"] или выключите строгий режим. Если для разработки используется ПО Flash Professional CS5 или Flex SDK 4.1, этот API-интерфейс можно использовать и скомпилировать для сред выполнения, выпущенных до Flash Player 10.1 и AIR 2.

Для содержимого приложения в AIR это свойство всегда имеет значение false.

Связанные элементы API

Объект Loader, связанный с данным объектом LoaderInfo. Если этот объект LoaderInfo является свойством loaderInfo экземпляра основного класса SWF-файла, с ним не связывается объект Loader.

URL-адрес SWF-файла, который запустил загрузку мультимедийного содержимого описанного в данном объекте LoaderInfo. Для экземпляра основного класса SWF-файла этот URL-адрес совпадает с собственным URL-адресом этого файла.

Объект, содержащий пары имен и значений, представляющих параметры для загруженного SWF-файла.

Можно использовать цикл for-in для извлечения всех имен и значений из объекта parameters.

Существует два источника параметров: строка запроса в URL основного SWF-файла и значения HTML-параметра FlashVars (оно затрагивает только основной SWF-файл).

Свойство parameters заменяет технологию ActionScript 1.0 и 2.0, используемую для передачи параметров SWF-файлов в виде свойств основной временной шкалы.

Значение свойства parameters имеет значение null для объектов Loader, содержащих SWF-файлы, использующие ActionScript 1.0 или 2.0.. Это могут быть только SWF-файлы, использующие ActionScript 3.0, содержатся только в объектах Loader с ненулевым значением.

Означает доверительные отношения со стороны загрузчика (родительского элемента) к содержимому (дочернему элементу). Если предшественник имеет право доступа к дочернему элементу, то true; иначе false. Это свойство имеет значение true, если родительский объект вызвал метод allowDomain() для предоставления права доступа дочернему домену или если в родительском домене загружена политика URL-адресов, предоставляющая доступ дочернему домену. Если дочерний объект и родительский объект находятся в том же домене, это свойство имеет значение true.

Дополнительные сведения о безопасности см. в разделе центра разработчиков Flash Player Безопасность.

Объект, который может быть задан с помощью кода в изолированной программной среде объекта Loader, чтобы сделать свойства и методы доступными для кода загруженного содержимого. Мост изолированной программной среды позволяет содержимому не из домена приложения получить управляемый доступ к сценариям в изолированной программной среде приложения, и наоборот. Этот мост служит своеобразным шлюзом между изолированными программными средами, обеспечивая открытое взаимодействие между изолированной программной средой приложения и другими изолированными средами.

Связанные элементы API

Показывает доменную связь между загрузчиком и содержимым: true (если у них общий исходный домен) или false (в противном случае).

Экземпляр EventDispatcher, с помощью которого возможен обмен событиями через зоны с разным уровнем безопасности. Даже если объект Loader и загруженное содержимое находятся в доменах защиты, между которыми отсутствуют отношения доверия, они все равно могут получить свойство sharedEvents и использовать этот объект для отправки и получения событий.

Версия формата загруженного SWF-файла. Формат файла задается с помощью перечислений в классе SWFVersion, например SWFVersion.FLASH7 и SWFVersion.FLASH9.

Связанные элементы API

Объект, который отправляет событие uncaughtError при возникновении необработанной ошибки в коде SWF-файла данного объекта LoaderInfo. Неперехваченные ошибки возникают, когда ошибка выдается за пределами блока try..catch или когда отправляется объект ErrorEvent, для которого не зарегистрирован прослушиватель.

Например, если в блоке try имеется диспетчер событий, который вызывает обработчик событий, блок catch не перехватывает ошибку, если ее выдает обработчик событий. Любую ошибку, выданную после этого момента, можно перехватить, прослушивая LoaderInfo.uncaughtErrorEvents

Это свойство создается после завершения загрузки SWF-файла, связанного с данным объектом LoaderInfo. До тех пор свойство uncaughtErrorEvents имеет значение null. В проекте, созданном с использованием только ActionScript, это свойство можно получить во время или после выполнения функции-конструктора основного класса файла SWF. Для проектов Flex свойство uncaughtErrorEvents становится доступным только после отправки события applicationComplete.

Связанные элементы API

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

URL-адрес загружаемого мультимедийного содержимого.

Перед отправкой первого события progress соответствующим объектом Loader данного объекта LoaderInfo значение свойства url может отображать только исходный URL-адрес, заданный в вызове метода load() объекта Loader. После первого события progress свойство url отображает окончательный URL-адрес мультимедийного содержимого после того, как выполнено разрешение всех перенаправлений и относительных URL.

В некоторых случаях значение свойства url усекается; дополнительные сведения см. в описании свойства isURLInaccessible.

Связанные элементы API

Номинальная ширина загруженного содержимого. Это значение может отличаться от фактической ширины области отображения содержимого, так как масштаб загруженного содержимого или его родительских экранных объектов может изменяться.

Возвращает объект LoaderInfo, связанный с SWF-файлом, определенным в качестве объекта.

Параметры

Отправляется после успешной загрузки данных. Другими словами, это событие отправляется при завершении загрузки всего содержимого. Событие complete всегда отправляется после события init. Событие init отправляется, когда объект становится доступным, хотя загрузка содержимого может продолжаться.

Это событие имеет следующие свойства:

Связанные элементы API

Передается, когда сетевой запрос отправляется через HTTP и возможно определить код состояния HTTP.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется, когда свойства и методы загруженного SWF-файла становятся доступны и готовы к использованию. Содержимое, однако, может продолжать загружаться. Объект LoaderInfo отправляет событие init, когда выполняются два следующих условия:

• Доступны все свойства и методы, связанные с загруженным объектом и с объектом LoaderInfo.
• Завершена работа конструкторов для всех дочерних объектов.
• Код ActionScript в первом кадре основной временной шкалы загруженного SWF-файла был полностью выполнен.

Например, событие Event.INIT отправляется после загрузки первого кадра ролика или анимации. Тогда ролик становится доступным и может быть добавлен в список отображения. Загрузка ролика полностью, однако, может занять больше времени. Событие Event.COMPLETE отправляется только при полной загрузке ролика.

Событие init всегда предшествует событию complete.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется, когда происходит ошибка ввода-вывода, приводящая к сбою операции загрузки.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется при запуске операции загрузки.

Это событие имеет следующие свойства:

Связанные элементы API

Отправляется в случае получения данных в ходе операции загрузки.

Это событие имеет следующие свойства:

Связанные элементы API

Передается объектом LoaderInfo каждый раз, когда загруженный объект удаляется с помощью метода unload() объекта Loader, а также когда выполняется повторная загрузка тем же объектом Loader, и перед началом загрузки удаляется исходное содержимое.

Это событие имеет следующие свойства:

Связанные элементы API

1. Создается свойство url, описывающее местоположение и имя изображения.
2. Конструктор класса создает объект Loader с именем loader.
3. Объект loader создает экземпляр прослушивателя событий, чтобы обеспечить правильную загрузку изображения.
4. Конструктор создает новый экземпляр объекта URLRequest, request, и передает url, чтобы сообщить имя и местоположение файла.
5. Затем объект request передается методу load() объекта loader, который загружает изображение в список отображения.

Важно! В этом примере требуется добавить файл с именем Image.gif в тот же каталог, что и компилированный SWF-файл. Используйте изображение, область которого соответствует размерам основного SWF-файла.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}