PrintJobOptions  - AS3

Określa rozdzielczość, jaka ma być używana dla bitmap, w pikselach na cal. Wartość domyślna Number.NaN oznacza, że jest używana rodzima rozdzielczość drukarki.

Ustawienie rozdzielczości dotyczy drukowania bitmapy i drukowania wektorowego. W przypadku drukowania bitmap rozdzielczość wpływa na sposób rasteryzacji całej strony. W przypadku drukowania obrazów wektorowych rozdzielczość wpływa na sposób rasteryzacji konkretnych elementów treści, takich jak bitmapy i gradienty.

Określa, czy treść zadania wydruku ma być drukowana jako bitmapa, czy jako obiekt wektorowy. Wartością domyślną jest false dla drukowania w postaci wektorowej.

Jeśli drukowana zawartość obejmuje bitmapę, dla printAsBitmap należy ustawić true w celu uwzględnienia dowolnej przezroczystości alpha i efektów kolorów. Jeśli zawartość nie obejmuje obrazów bitmap, należy wydrukować zawartość w formacie wektorowym o wyższej jakości (opcja domyślna).

Na przykład: w celu wydrukowania zawartości w postaci bitmapy należy zastosować składnię:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Uwaga: środowisko Adobe AIR nie obsługuje drukowania wektorowego w systemie Mac OS.

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Określa, że środowisko wykonawcze Flash wybiera najbardziej odpowiednią metodę drukowania lub że autor chce jawnie wybrać drukowanie wektorowe lub drukowanie bitmapy.

Ustaw właściwość na jedną z następujących wartości zdefiniowanych w klasie PrintMethod:

• PrintMethod.AUTO: Określa, że drukowanie wektorowe lub drukowanie bitmapy jest wybierane automatycznie na podstawie treści przeznaczonej do drukowania. Drukowanie wektorowe będzie używane za każdym razem, gdy treść może zostać wiernie odtworzona przez tę metodę. Jeśli dostępny jest efekt przezroczystości lub inne efekty, będzie stosowana metoda drukowania bitmapy.
• PrintMethod.VECTOR: Określa drukowanie wektorowe. Tak samo, jak ustawienie false dla printAsBitmap.
• PrintMethod.BITMAP: Określa drukowanie bitmapy. Tak samo, jak ustawienie true dla printAsBitmap.

Jeśli metoda printMethod jest ustawiona na jedną z obsługiwanych wartości, wówczas printAsBitmap jest ignorowane.

Wartością domyślną jest null; używana jest właściwość printAsBitmap.

Powiązane elementy interfejsu API

Tworzy nowy obiekt PrintJobOptions. Ten obiekt należy przekazać do parametru options metody PrintJob.addPage().

Powiązane elementy interfejsu API