NativeWindow  - AS3

Wskazuje, czy to okno jest oknem aktywnej aplikacji.

Należy użyć metody activate() w celu aktywacji okna.

Powiązane elementy interfejsu API

Określa, czy to okno zawsze będzie znajdować się na przedzie względem pozostałych okien (włączając okna innych aplikacji).

Istnieją dwie grupy okien w kolejności głębokości systemu. Okna znajdujące się w grupie alwaysInFront są zawsze wyświetlane z przodu pozostałych okien. Ustawianie kolejności głębokości okien wewnątrz tej samej grupy jest określone normalnie. Innymi słowy aktywacja okna przeniesie je na przód pozostałych okien w grupie.

Zmiana właściwości alwaysInFront z false na true spowoduje przeniesienie okna na wierzch wszystkich innych okien. Zmiana właściwości z true na false spowoduje wysłanie okna do tyłu okien o właściwości "alwaysInFront", ale wciąż z przodu pozostałych okien. Ustawienie właściwości na jej obecną wartość nie zmieni kolejności głębokości okna. Ustawienie właściwości alwaysInFront okna mającego właściciela nie ma żadnych skutków.

Wartość true dla właściwości alwaysInFront powinna być stosowana sporadycznie, ponieważ okna, dla których określono to ustawienie, będą widoczne przed oknami innych aplikacji, nawet jeśli aktywne są inne aplikacje.

Uwagi o zachowaniu systemu operacyjnego:

• Niektóre menedżery okien w systemie Linux nie wyświetlają okien z ustawioną właściwością alwaysInFront przed oknami w trybie pełnoekranowym.
• W systemie operacyjnym Mac^® OS X ustawienie alwaysInFront o wartości true nie odniesie skutku, gdy właściwość displayState stołu montażowego okna ma wartość fullScreen lub fullScreenInteractive.

windowObj.alwaysInFront = true;

displayObject.stage.nativeWindow.alwaysInFront=true;

window.nativeWindow.alwaysInFront = true;

Wielkość i położenie tego okna.

Przy określaniu wymiarów okna uwzględniana jest karnacja systemu. Wymiary stołu montażowego okna są równe rozmiarom okna, minus rozmiary karnacji systemu. Zmiana szerokości i wysokości okna zmieni parametry stageWidth i stageHeight stołu montażowego. Mechanizm działa również w kierunku przeciwnym: zmiana wymiarów stołu montażowego zmieni rozmiar okna.

W oknie głównym HTML właściwości outerWidth i outerHeigth są odpowiednikami właściwości height i width okna. Właściwości innerWidth i innerHeight są równe właściwościom stage.stageWidth i stage.stageHeight minus grubość wszelkich automatycznych pasków przewijania wyświetlonych przez okno.

Zdarzenie resize jest wywoływane za każdym razem, gdy szerokość i wysokość tego okna jest zmieniana. I podobnie — zdarzenie move jest wywoływane zawsze, gdy zmianie ulega położenie początku (x,y) okna. W systemach Mac OS i Windows bezpośrednie ustawienie właściwości bounds nie spowoduje wywołania zdarzenia moving ani resizing. Jednak w systemie Linux obiekt NativeWindow wywołuje zdarzenia moving i resizing po ustawieniu właściwości bounds.

Ustawienie właściwości bounds okna jest odpowiednikiem ustawienia właściwości x, y, width oraz height. I podobnie — ustawienie dowolnego wymiaru jest równoważne ustawieniu właściwości bounds. Jeśli wszystkie wymiary są ustawiane jednocześnie za pomocą właściwości bounds, wywoływana jest mniejsza liczba zdarzeń.

Kolejność ustawiania poszczególnych wymiarów nie jest gwarantowana. W menedżerach okien systemu Linux, które nie zezwalają na to, by część okna znajdowała się poza pulpitem, zmiana określonej właściwości może być zablokowana nawet wówczas, gdy łączny skutek wszystkich zmian właściwości doprowadziłby do uzyskania poprawnego okna.

Jeśli podana szerokość lub wysokość będzie mniejsza od minimalnej lub większa od maksymalnej dozwolonej wartości, wówczas szerokość lub wysokość okna zostanie ustawiona na najbliższą jej wartość dozwoloną. Czynniki, od których zależy minimalna i maksymalna szerokość i wysokość, to:

• Wartość właściwości minSize i maxSize obiektu NativeWindow.
• Ograniczenia systemu operacyjnego, czyli wartości właściwości NativeWindow.systemMinSize i NativeWindow.systemMaxSize.
• Maksymalna szerokość i wysokość okna w środowisku Adobe AIR, która wynosi 4095 pikseli. (W wersji AIR 1.5 i wersjach wcześniejszych maksymalna szerokość i wysokość okna wynosi 2880 pikseli).
• Minimalna szerokość i wysokość wymagana przez aktualną karnację systemową.

W przypadku zmiany położenia lub wymiarów okna wartości pikseli są zaokrąglane do najbliższej liczby całkowitej.

Powiązane elementy interfejsu API

windowObj.bounds = new Rectangle(200, 200, 1000, 800);

displayObject.stage.nativeWindow.bounds = new Rectangle(20, 20, 800, 600);

window.nativeWindow.bounds = new air.Rectangle(20, 20, 800, 600);

Wskazuje, czy okno zostało zamknięte.

Uzyskanie dostępu do następujących właściwości w przypadku zamknięcia okna spowoduje zgłoszenie błędu niepoprawnej operacji:

• title
• bounds
• x, y, width, height
• displayState
• visible

I podobnie — wywołanie następujących metod w zamkniętym oknie również spowoduje wywołanie błędu niepoprawnej operacji:

• minimize()
• maximize()
• restore()
• startResize()
• startMove()

var isWindowClosed:Boolean = windowObj.closed;

var isWindowClosed:Boolean = displayObject.stage.nativeWindow.closed;

var isWindowClosed = window.nativeWindow.closed;

Stan wyświetlania okna.

Stałe możliwych wartości są zdefiniowane w klasie NativeWindowDisplayState:

• NativeWindowDisplayState.NORMAL
• NativeWindowDisplayState.MINIMIZED
• NativeWindowDisplayState.MAXIMIZED

Powiązane elementy interfejsu API

var state:String = windowObj.displayState;

Wysokość tego okna w pikselach.

Przy określaniu wymiarów okna uwzględniana jest wyświetlana karnacja okna systemu. Wysokość obszaru wyświetlania możliwego do użycia jest dostępna we właściwości Stage.stageHeight.

Zmiana właściwości height okna jest odpowiednikiem zmiany wysokości przez właściwość bounds.

Jeśli podana wysokość będzie mniejsza od minimalnej lub większa od maksymalnej dozwolonej wartości, wówczas wysokość okna zostanie ustawiona na najbliższą jej wartość dozwoloną. Czynniki, od których zależy minimalna i maksymalna wysokość, to:

• Wartości właściwości minSize.x i maxSize.x obiektu NativeWindow.
• Ograniczenia systemu operacyjnego, czyli wartości właściwości NativeWindow.systemMinSize.x i NativeWindow.systemMaxSize.x.
• Maksymalna wysokość okna w środowisku Adobe AIR wynosi 4095 pikseli (2880 pikseli w wersji AIR 1.5 i wersjach wcześniejszych).

W systemie Linux ustawianie właściwości height jest operacją asynchroniczną.

Aby wykryć zakończenie zmiany wysokości, należy wykrywać zdarzenie resize, które jest wywoływane na wszystkich platformach.

W przypadku zmiany wysokości okna wartości pikseli są zaokrąglane do najbliższej liczby całkowitej.

Powiązane elementy interfejsu API

Wskazuje, czy natywne okna są obsługiwane na systemie klienckim.

Informuje o ustawieniu możliwości maksymalizacji użytym podczas tworzenia tego okna.

Ustawienie maximizable nie może zostać zmienione po utworzeniu okna.

Uwaga: Niektóre menedżery okien w systemie Linux zezwalają na maksymalizowanie okien przez użytkownika, nawet jeśli wartością właściwości maximizable jest false.

Powiązane elementy interfejsu API

Rozmiar maksymalny dla tego okna.

Limit rozmiaru jest określony jako współrzędne obiektu Point. Właściwość x punktu odpowiada szerokości okna, natomiast właściwość y jego wysokości.

Ograniczenie maxSize jest narzucone dla operacji zmiany wielkości okien wywoływanych za pośrednictwem kodu ActionScript oraz systemu operacyjnego.

Ustawienie właściwości maxSize spowoduje zmianę granic okna, jeżeli obecne granice są większe niż nowy rozmiar maksymalny.

Jeśli podana szerokość lub wysokość będzie większa od maksymalnej dozwolonej wartości, wówczas szerokość lub wysokość okna zostanie ustawiona na najbliższą jej wartość dozwoloną. Czynniki, od których zależy minimalna i maksymalna szerokość i wysokość:

• Ograniczenie systemu operacyjnego, czyli wartość właściwości NativeWindow.systemMaxSize.
• Maksymalna szerokość i wysokość okna w środowisku Adobe AIR, która wynosi 4095 pikseli. (W wersji AIR 1.5 i wersjach wcześniejszych maksymalna szerokość i wysokość okna wynosi 2880 pikseli).

Uwaga: W niektórych systemach operacyjnych, takich jak Mac OS X, maksymalizacja okna spowoduje powiększenie go tylko do wartości maxSize, nawet jeśli tak powiększone okno będzie mniejsze od ekranu systemu operacyjnego. Okno wciąż będzie w stanie zmaksymalizowanego wyświetlania.

Powiązane elementy interfejsu API

windowObj.maxSize = new Point(1040,920);

displayObject.stage.nativeWindow.maxSize = new Point(800,600);

window.nativeWindow.maxSize = new air.Point(960,960);

Natywne menu dla tego okna.

Kiedy obiekt NativeMenu jest przypisany do właściwości okna menu, wówczas macierzyste menu zostanie wyświetlone dla okna, jeżeli właściwość NativeWindow.supportsMenu ma wartość true, chyba że właściwość systemChrome ma wartość NativeWindowSystemChrome.NONE.

Uwaga: Przypisanie menu do okna, gdy właściwość NativeWindow.supportsMenu ma wartość false, lub gdy właściwość okna systemChrome ma wartość NativeWindowSystemChrome.NONE jest dozwolone, lecz nie funkcjonuje. W celu ustalenia, czy system operacyjny obsługuje menu okien, należy koniecznie skorzystać z właściwości NativeWindow.supportsMenu. Użycie innych sposobów (na przykład właściwości Capabilities.os) do określenia możliwości obsługi może prowadzić do błędów programowania (jeśli niektóre docelowe systemy operacyjne nie zostaną uwzględnione).

Powiązane elementy interfejsu API

Raportuje ustawienie możliwości minimalizacji, wykorzystane przy utworzeniu tego okna.

Ustawienie minimizable nie może zostać zmienione po utworzeniu tego okna.

Uwaga: Niektóre menedżery okien w systemie Linux zezwalają na maksymalizowanie okien przez użytkownika, nawet jeśli wartością właściwości minimizable jest false.

Powiązane elementy interfejsu API

Rozmiar minimalny dla tego okna.

Limit rozmiaru jest określony jako współrzędne obiektu Point. Właściwość x punktu odpowiada szerokości okna, natomiast właściwość y jego wysokości.

Ustawienie właściwości minSize spowoduje zmianę granic okna, jeżeli obecne granice są mniejsze niż nowy rozmiar minimalny.

Ograniczenie minSize jest narzucone dla operacji zmiany wielkości okien wywoływanych za pośrednictwem kodu ActionScript oraz systemu operacyjnego.

Uwaga: Szerokość i wysokość dowolnej wyświetlonej karnacji systemu może uniemożliwić ustawienie okna na rozmiar tak mały, jak określony przez rozmiar minimalny.

Powiązane elementy interfejsu API

windowObj.minSize = new Point(200,80);

displayObject.stage.nativeWindow.minSize = new Point(120,60);

window.nativeWindow.minSize = new air.Point(80,60);

Obiekt NativeWindow posiadający to okno.

Prawo własności do okna jest ustalane podczas tworzenia okna i nie można go zmieniać. Aby utworzyć okno mające właściciela, należy ustawić będący właścicielem obiekt NativeWindow jako właściwość owner obiektu NativeWindowInitOptions użytego do utworzenia posiadanego okna.

Uwaga: W systemie Linux niektóre menedżery okien nie wyświetlają posiadanych okien z przodu okna będącego właścicielem, gdy okno będące właścicielem działa w trybie pełnoekranowym.

Powiązane elementy interfejsu API

Zwraca ustawienie renderMode okna użyte przy tworzeniu tego okna.

Wartość zwrócona przez właściwość NativeWindow.renderMode będzie jedną ze stałych zdefiniowanych w klasie NativeWindowRenderMode.

Ustawienia renderMode nie można zmienić po utworzeniu okna.

Powiązane elementy interfejsu API

Informuje o ustawieniu możliwości zmiany rozmiaru użytym podczas tworzenia tego okna.

Ustawienie resizable nie może zostać zmienione po utworzeniu tego okna.

Powiązane elementy interfejsu API

Obiekt Stage dla tego okna. Obiekt Stage jest głównym obiektem architektury listy wyświetlanej używanym w zawartości SWF bazującej na języku ActionScript 3.0.

Stół montażowy jest początkowym obiektem listy wyświetlania dla okna. Można dodać obiekty wyświetlane wizualnego do okna poprzez dodanie ich do stołu montażowego lub innego obiektu, który jest już na liście wyświetlania tego stołu. Wymiary stołu montażowego są takie same, jak obszaru klienta okna, gdy okno wykorzystuje karnację systemu. Wymiary stołu montażowego są równe wymiarom okna, jeżeli karnacja systemu nie jest stosowana.

Powiązane elementy interfejsu API

import flash.display.StageAlign;

windowObj.stage.align = StageAlign.TOP_LEFT;

Wskazuje, czy aplikacja AIR obsługuje natywne menu okien w obecnym systemie.

Jeśli właściwość NativeWindow.supportsMenu ma wartość true, wówczas menu natywne zostanie wyświetlone dla okna w momencie przypisania właściwości menu dla obiektu Nativemenu (chyba że właściwość systemChrome okna ma wartość NativeWindowSystemChrome.NONE). W celu ustalenia, czy system operacyjny obsługuje natywne menu okien, należy koniecznie skorzystać z właściwości NativeWindow.supportsMenu. Użycie innych sposobów (np. właściwości Capabilities.os) do określenia możliwości obsługi może prowadzić do błędów programowania (jeśli niektóre docelowe systemy operacyjne nie zostaną uwzględnione).

Uwaga: Przypisanie menu do okna, gdy właściwość NativeWindow.supportsMenu ma wartość false, lub gdy właściwość okna systemChrome ma wartość NativeWindowSystemChrome.NONE jest dozwolone, lecz nie funkcjonuje.

Powiązane elementy interfejsu API

Wskazuje, czy aplikacja AIR obsługuje sygnalizację powiadomień okna w obecnym systemie.

Kiedy właściwość NativeWindow.supportsNotification ma wartość true, wywoływanie metody notifyUser() okna będzie skutkować sygnalizacją wizualną dla użytkownika z informacją o tym, że wystąpiło ważne zdarzenie. Sygnalizacja wizualna będzie dostosowana do konwencji natywnego systemu operacyjnego. Na przykład: w systemie Windows^® będzie migać ikona na pasku zadań.

Uwaga: wywoływanie metody notifyUser(), gdy właściwość NativeWindow.supportsNotification ma wartość false, jest dozwolone, ale nie przynosi żadnych widocznych skutków.

Powiązane elementy interfejsu API

Wskazuje, czy środowisko AIR obsługuje okna natywne z pikselami przezroczystymi.

Jeśli parametr NativeWindow.supportsTransparency ma wartość true, będzie uwzględniana przezroczystość okna natywnego w pikselach, pod warunkiem że właściwość transparent ma wartość true. Przezroczystość wszystkich pikseli będzie ustawiona na 1, jeśli właściwość NativeWindow.supportsTransparency ma wartość false, bez względu na wartość właściwości transparent okna. Piksele całkowicie przezroczyste będą renderowane jako czarne, gdy właściwość NativeWindow.supportsTransparency ma wartość false. W celu ustalenia, czy system operacyjny obsługuje przezroczystość, należy koniecznie skorzystać z właściwości NativeWindow.supportsTransparency. Użycie innych sposobów (na przykład właściwości Capabilities.os) do określenia możliwości obsługi może prowadzić do błędów programowania (jeśli niektóre docelowe systemy operacyjne nie zostaną uwzględnione).

Uwaga: Wartość tej właściwości może ulec zmianie podczas działania aplikacji. Jest to uzależnione od preferencji użytkownika ustawionych w systemie operacyjnym.

Powiązane elementy interfejsu API

Raportuje ustawienie karnacji systemu, wykorzystane przy utworzeniu tego okna.

Wartości zwrócone przez właściwość NativeWindow.systemChrome będą jednymi ze stałych zdefiniowanych w klasie NativeWindowSystemChrome.

Ustawienie karnacji systemu nie może zostać zmienione po utworzeniu okna.

Powiązane elementy interfejsu API

var sysChromeType:String = windowObj.systemChrome;

var sysChromeType:String = displayObject.stage.nativeWindow.systemChrome;

var sysChromeType = window.nativeWindow.systemChrome;

import flash.display.NativeWindow;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowInitOptions;

public function deChromeWindow(oldWindow:NativeWindow):NativeWindow{
    if(oldWindow.systemChrome != NativeWindowSystemChrome.NONE){
        var newOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
        newOptions.systemChrome = NativeWindowSystemChrome.NONE;
        newOptions.transparent = true;
        
        var newWindow:NativeWindow = new NativeWindow(newOptions);
        newWindow.stage.stageWidth = oldWindow.stage.stageWidth;
        newWindow.stage.stageHeight = oldWindow.stage.stageHeight;
        newWindow.stage.align = oldWindow.stage.align;
        newWindow.stage.scaleMode = oldWindow.stage.scaleMode;
        
        for(var i:int = 0; i < oldWindow.stage.numChildren; i++){
            newWindow.stage.addChild(oldWindow.stage.getChildAt(i));
        }
        newWindow.activate();
        oldWindow.close();
        
        return newWindow;
    }
    return oldWindow;
}

Największy rozmiar okna dozwolony przez system operacyjny.

Limit rozmiaru jest określony jako współrzędne obiektu Point. Właściwość x punktu odpowiada szerokości okna, natomiast właściwość y jego wysokości.

Oprócz limitu rozmiaru, jaki definiuje system operacyjny, środowisko AIR określa limit maksymalnego rozmiaru okna wynoszący 4095 na 4095 pikseli (2880 na 2880 pikseli w wersji AIR 1.5 i wersjach wcześniejszych). Ponadto aplikacja może narzucić limit przy użyciu właściwości maxSize obiektu NativeWindow.

Najmniejszy rozmiar okna dozwolony przez system operacyjny.

Limit rozmiaru jest określony jako współrzędne obiektu Point. Właściwość x punktu odpowiada szerokości okna, natomiast właściwość y jego wysokości.

Tytuł okna.

Jeżeli zajdzie konieczność wyświetlenia, wówczas tytuł pojawi się w karnacji systemu dla tego okna oraz innych lokalizacjach zależnych od systemu (na przykład pasek zadań).

windowObj.title = "Window Title";

Raportuje ustawienie przezroczystości, wykorzystane przy utworzeniu tego okna.

Właściwość transparent nie może zostać zmieniona po utworzeniu okna. Przezroczystość wpływa zarówno na wygląd wizualny okna oraz zachowanie myszy. W systemach Windows i Mac OS X okno nie będzie przechwytywać zdarzeń myszy, gdy wartość alpha piksela pod wskaźnikiem jest niższa od określonego progu, przedziale między 0,01 i 0,06, w zależności od systemu operacyjnego. W systemie Linux okno będzie przechwytywać zdarzenia myszy nawet nad obszarami całkowicie przezroczystymi, a tym samym użytkownicy nie będą mieli dostępu do innych okien ani elementów na pulpicie.

Uwaga: Przezroczystość okien nie zawsze jest obsługiwana. Jeśli konfiguracja systemu operacyjnego użytkownika uniemożliwia stosowanie przezroczystości, okno zostanie utworzone bez tego efektu. Obszary, które byłyby przezroczyste, będą w kompozycji traktowane jako czarne. Właściwość NativeWindow.supportsTransparency umożliwia określenie, czy przezroczystość okien jest obsługiwana.

Powiązane elementy interfejsu API

Raportuje ustawienie type okna wykorzystane podczas tworzenia tego okna.

Wartości zwrócone przez właściwość NativeWindow.type będą jednymi ze stałych zdefiniowanych w klasie NativeWindowType.

Ustawienie type nie może zostać zmienione po utworzeniu okna.

Powiązane elementy interfejsu API

Określa, czy okno jest widoczne.

Okno niewidoczne nie jest wyświetlane na pulpicie, ale wszelkie właściwości i metody okna są poprawne.

Domyślnie właściwość visible jest ustawiona na false. W celu wyświetlenia okna należy ustawić właściwość visible na wartość true lub wywołać metodę NativeWindow.activate().

Jeśli dane okno ma właściciela, to stan widoczności okna będącego właścicielem określa, czy dane okno jest wyświetlane. Jeśli dane okno nie jest wyświetlane, to nie są wyświetlane żadne okna, których jest ono właścicielem — nawet jeśli mają dla właściwości visible ustawioną wartość true.

Uwaga: W systemie operacyjnym Mac X, ustawienie właściwości visible=false przy zminimalizowanym oknie nie usunie ikony okna z doku. Jeżeli użytkownik ponownie kliknie ikonę doku, wówczas okno powróci do stanu widocznego i zostanie wyświetlone na pulpicie.

Powiązane elementy interfejsu API

windowObj.visible = true;

displayObj.stage.nativeWindow.visible = true;

window.nativeWindow.visible = true;

Szerokość tego okna w pikselach.

Wymiary zgłaszane dla okna rodzimego zawierają dowolne karnacje okna systemu, jakie są wyświetlane. Szerokość obszaru wyświetlania możliwego do użycia jest dostępna we właściwości Stage.stageWidth.

Zmiana właściwości width okna jest odpowiednikiem zmiany szerokości przez właściwość bounds.

Jeśli podana szerokość będzie mniejsza od minimalnej lub większa od maksymalnej dozwolonej wartości, wówczas szerokość okna zostanie ustawiona na najbliższą jej wartość dozwoloną. Czynniki, od których zależy minimalna i maksymalna szerokość, to:

• Wartości właściwości minSize.y i maxSize.y obiektu NativeWindow.
• Ograniczenia systemu operacyjnego, czyli wartości właściwości NativeWindow.systemMinSize.y i NativeWindow.systemMaxSize.y.
• Maksymalna szerokość okna w środowisku Adobe AIR wynosi 4095 pikseli (2880 pikseli w wersji AIR 1.5 i wersjach wcześniejszych).

W systemie Linux ustawianie właściwości width jest operacją asynchroniczną.

Aby wykryć zakończenie zmiany szerokości, należy wykrywać zdarzenie resize, które jest wywoływane na wszystkich platformach.

W przypadku zmiany szerokości okna wartości pikseli są zaokrąglane do najbliższej liczby całkowitej.

Powiązane elementy interfejsu API

Współrzędna osi poziomej górnego lewego rogu tego okna względem początku układu współrzędnych pulpitu systemu operacyjnego.

W systemach, w których stosowana jest większa liczba monitorów, wartość x może być ujemna. Jeśli wartość zostanie zapisana — np. w celu przywrócenia okna do poprzedniego położenia, należy się zawsze upewnić, że okno zostało ustawione w użytecznym miejscu, gdy położenie zostanie przywrócone. Zmiany rozdzielczości ekranu lub ustawień monitora mogą spowodować przesunięcie okna poza ekran. W celu uzyskania informacji o geometrii pulpitu należy użyć klasy Screen.

Zmiana właściwości x okna jest odpowiednikiem zmiany położenia przez właściwość bounds.

W systemie Linux ustawianie właściwości x jest operacją asynchroniczną.

Aby wykryć zakończenie zmiany pozycji, należy wykrywać zdarzenie move, które jest wywoływane na wszystkich platformach.

W przypadku zmiany współrzędnej x okna wartości pikseli są zaokrąglane do najbliższej liczby całkowitej.

Powiązane elementy interfejsu API

Współrzędna osi pionowej górnego lewego rogu tego okna względem górnego lewego rogu pulpitu systemu operacyjnego.

W systemach, w których stosowana jest większa liczba monitorów, wartość y może być ujemna. Jeśli wartość zostanie zapisana — np. w celu przywrócenia okna do poprzedniego położenia, należy się zawsze upewnić, że okno zostało ustawione w użytecznym miejscu, gdy położenie zostanie przywrócone. Zmiany rozdzielczości ekranu lub ustawień monitora mogą spowodować przesunięcie okna poza ekran. W celu uzyskania informacji o geometrii pulpitu należy użyć klasy Screen.

Zmiana właściwości y okna jest odpowiednikiem zmiany położenia przez właściwość bounds.

W systemie Linux ustawianie właściwości y jest operacją asynchroniczną.

Aby wykryć zakończenie zmiany pozycji, należy wykrywać zdarzenie move, które jest wywoływane na wszystkich platformach.

W przypadku zmiany współrzędnej y okna wartości pikseli są zaokrąglane do najbliższej liczby całkowitej.

Powiązane elementy interfejsu API

Tworzy nowe wystąpienie klasy NativeWindow oraz odpowiadające mu okno systemu operacyjnego.

Ustawienia zdefiniowane w parametrze initOptions nie mogą zostać zmienione po utworzeniu okna. Niepoprawne ustawienia initOptions spowodują zgłoszenie błędu dotyczącego niepoprawnej operacji. Ustawienia, które są prawidłowe ale nie są dostępne w bieżącym systemie, nie zgłoszą wyjątku. Opcje okna konkretne dla bieżącego systemu operacyjnego mogą zostać wykryte w razie potrzeby przy użyciu statycznych członków NativeWindow, jak na przykład systemMaxSize.

Domyślny rozmiar okna jest określany przez system operacyjny, a tworzone okna są niewidoczne. Aby nie dopuścić do tego, aby zmiany w oknie były widoczne, nie należy zmieniać właściwości visible okna na true ani wywoływać metody activate() do czasu zakończenia zmian okna.

Powiązane elementy interfejsu API

import flash.display.NativeWindowInitOptions;
import flash.display.NativeWindowSystemChrome;
import flash.display.NativeWindowType;
import flash.display.NativeWindow;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.geom.Rectangle;

var windowOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
windowOptions.systemChrome = NativeWindowSystemChrome.STANDARD;
windowOptions.type = NativeWindowType.NORMAL;

var newWindow:NativeWindow = new NativeWindow(windowOptions);
newWindow.stage.scaleMode = StageScaleMode.NO_SCALE;
newWindow.stage.align = StageAlign.TOP_LEFT;
newWindow.bounds = new Rectangle(100, 100, 800, 800);

newWindow.activate();

Aktywuje to okno.

Aktywacja okna spowoduje:

• Okno stanie się widoczne
• Okno zostanie przesunięte na przód
• Okno stanie się aktywne dla klawiatury i myszy

W systemie Linux metoda activate() jest wykonywana jako operacja asynchroniczna.

Obiekt NativeWindow wywołuje zdarzenie activate na wszystkich platformach.

Powiązane elementy interfejsu API

displayObject.stage.nativeWindow.activate();

windowObj.activate();

window.nativeWindow.activate();

Zamyka to okno.

Zdarzenie close jest wywoływane tuż po zakończeniu operacji zamykania. Zdarzenie closing nie będzie wywoływane. W sytuacji gdy dozwolone jest anulowanie operacji zamykania, należy wywołać zdarzenie closing oraz sprawdzić, czy zarejestrowane detektory anulują domyślne zachowanie przed wywołaniem metody close().

W momencie zamknięcia okna zostają zamknięte wszystkie okna posiadane przez to okno. Posiadane okna nie wywołują zdarzeń closing.

Jeżeli do instancji obiektów wyświetlanych widocznych obecnie w oknie nie istnieją odwołania nigdzie indziej, zostaną one zebrane jako elementy niepotrzebne i zniszczone — z wyjątkiem wstępnego okna aplikacji utworzonego przez AIR. Aby umożliwić gromadzenie (niepotrzebnych) obiektów wyświetlanych w oknie początkowym, należy usunąć je ze stołu montażowego okna.

Po zamknięciu obiekt NativeWindow jest wciąż prawidłowym odwołaniem, ale próby uzyskania dostępu do większości właściwości i metod spowodują zgłoszenie błędu niepoprawnej operacji.

Okna zamknięte nie mogą być ponownie otworzone. Jeżeli okno jest już zamknięte, wówczas nie jest podejmowana żadna akcji ani nie są wywoływane zdarzenia.

Uwaga: aby ukryć okno, nie zamykając go, należy ustawić właściwość okna visible na wartość false.

Powiązane elementy interfejsu API

windowObj.close();

displayObj.stage.nativeWindow.close();

window.close(); //overriddable in HTMLHost

window.nativeWindow.close(); //not overriddable

public function closeCommand():Boolean{
    var closeEvent:Event = new Event(Event.CLOSING,true,true);
    windowObj.dispatchEvent(closeEvent);
    if(!closeEvent.isDefaultPrevented()){
        windowObj.close();
        return true;
    } else {
      return false;
    }
}

<script src="AIRAliases.js" type="text/javascript"></script>
<script type="text/javascript">
    var dirtyData = false;
    function closeWindow(){
            var closingEvent = new air.Event(air.Event.CLOSING,true,true);
            window.nativeWindow.dispatchEvent(closingEvent);
               if(!closingEvent.isDefaultPrevented()){
                   window.nativeWindow.close();
                //or use: window.close(); 
               return true;
           } else {
               return false;
        }
    }
        
    function onClosing(event){
        if(dirtyData){
            event.preventDefault();
            //Save data...
        }
    }    

    window.nativeWindow.addEventListener(air.Event.CLOSING,onClosing);        
</script>

Konwertuje punkt we współrzędnych pikseli względem źródła stołu montażowego okna (punkt globalny w pojęciu listy wyświetlania), do punktu na pulpicie wirtualnym.

Współrzędne pulpitu wirtualnego są względne wobec górnego, lewego rogu głównego monitora.

Parametry

Powiązane elementy interfejsu API

Zwraca listę obiektów NativeWindow posiadanych przez to okno.

Nie można zmieniać praw własności do obiektów NativeWindow przez dodawanie lub usuwanie obiektów ze zwróconego wektora. Po utworzeniu danego okna nie można zmieniać prawa własności do okna.

Powiązane elementy interfejsu API

Maksymalizuje okno.

Wywołanie metody maximize()powoduje wywołanie zdarzenia displayStateChange oraz, jeśli to możliwe, zdarzenia move i resize. Karnacja systemu wywoła zdarzenie displayStateChanging, które może zostać anulowane gdy polecenie maksymalizacji jest wydane przez użytkownika, jednakże w takim przypadku logika maksymalizacji ustawiona przez użytkownika musi implementować takie zachowanie.

Metoda maximize() jest wykonywana asynchronicznie. Aby wykryć zakończenie zmiany stanu, należy wykrywać zdarzenie displayStateChange. Jeżeli okno jest już zmaksymalizowane, wówczas nie jest podejmowane żadne działanie ani nie są wywoływane zdarzenia.

Uwagi o zachowaniu systemu operacyjnego:

• W systemach operacyjnych, jak np. Mac OS X, w którym maksymalizacja okna nie zapobiega zmianie jego rozmiarów, wywołanie metody maximize() spowoduje powiększenie okna w celu wypełnienia ekranu, ale nie uniemożliwi kolejnych zmian rozmiaru okna. Zmiana rozmiaru powiększonego okna przywróci również stan wyświetlania.
• W niektórych systemach operacyjnych, takich jak Mac OS X, a także w niektórych menedżerach okien systemu Linux, maksymalizacja okna nie spowoduje powiększenia go ponad szerokość i wysokość określoną we właściwości maxSize. W innych systemach okno zostanie powiększone na cały ekran, nawet jeśli ekran jest większy niż maxSize.
• Niektóre menedżery okien w systemie Linux nie zezwalają na maksymalizowanie okien narzędziowych.

Powiązane elementy interfejsu API

public function maximizeWindow(nativeWin:NativeWindow):Boolean{
  if(nativeWin.displayState != NativeWindowDisplayState.MAXIMIZED){
    var beforeState:String = nativeWin.displayState;
    var afterState:String = NativeWindowDisplayState.MAXIMIZED;
    var displayStateEvent:NativeWindowDisplayStateEvent = 
        new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
    nativeWin.dispatchEvent(displayStateEvent);
    if(!displayStateEvent.isDefaultPrevented()){
        nativeWin.maximize();
        return true;
    } else {
      return false;
    }
  }
  return false;
}

function maximizeWindow(nativeWin){
    if(nativeWin.displayState != air.NativeWindowDisplayState.MAXIMIZED){
        var beforeState = nativeWin.displayState;
        var afterState = air.NativeWindowDisplayState.MAXIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.maximize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Minimalizuje okno.

Wywołanie metody minimize()powoduje wywołanie zdarzenia displayStateChange oraz, jeśli to możliwe, zdarzenia move i resize. Karnacja systemu wywoła zdarzenie displayStateChanging, które może zostać anulowane, gdy użytkownik wyda polecenie minimalizacji. Jednak bezpośrednie wywoływanie metody minimize() tego nie spowoduje. Logika minimalizacji ustawiona przez użytkownika może zaimplementować takie zachowanie w razie potrzeby.

Metoda minimize() jest wykonywana asynchronicznie. Aby wykryć zakończenie zmiany stanu, należy wykrywać zdarzenie displayStateChange, które jest wywoływane na wszystkich platformach. Jeżeli okno jest już zminimalizowane, wówczas nie jest podejmowane żadne działanie ani nie są wywoływane zdarzenia.

Wszystkie okna posiadane przez to okno są ukrywane podczas jego minimalizowania. Posiadane okna nie wywołują zdarzeń displayStateChanging ani displayStateChange.

Uwagi:

• W systemie Windows zminimalizowanie niewidocznego oka a(visible == false) spowoduje uwidocznienie okna.
• Niektóre menedżery okien w systemie Linux nie zezwalają na minimalizowanie okien narzędziowych.

Powiązane elementy interfejsu API

public function minimizeWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.MINIMIZED){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            nativeWin.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

 
function minimizeWindow(){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.MINIMIZED){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.MINIMIZED;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.minimize();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Wywołuje sygnalizację wizualną w systemie operacyjnym, która informuje o tym, że wystąpiło ważne zdarzenie.

Gdy właściwość NativeWindow.supportsNotification ma wartość true, wówczas sygnalizacja wizualna będzie dostosowana do konwencji rodzimego systemu operacyjnego. Przykładowo w systemie Windows pasek zadań zacznie migać.

Parametr type określa intensywność sygnalizacji. Stałe dla dozwolonych wartości są zdefiniowane w klasie NotificationType i mogą to być:

• NotificationType.INFORMATIONAL
• NotificationType.CRITICAL

Sygnalizacje związane z powiadomieniami informacyjnymi trwają krótko; sygnalizacje związane z powiadomieniami krytycznymi będą trwały do momentu aktywacji okna przez użytkownika. Nie wszystkie menedżery okien systemu Linux obsługują dwa poziomy powiadomień. W przypadku takich menedżerów okien wywołanie metody notifyUser() odniesie zawsze taki sam skutek, niezależnie od wybranej opcji.

Uwaga: Wywoływanie metody notifyUser(), gdy właściwość NativeWindow.supportsNotification ma wartość false jest dozwolone, ale nie przynosi żadnych widocznych skutków.

Parametry

Wysyła to okno bezpośrednio za określone okno.

Nie aktywuje ani nie otrzymuje fokusu dla okna lub aplikacji. Okna zminimalizowane lub ukryte (wartość visible to false) nie mogą mieć zmienionej kolejności.

Posiadane okno nie może nigdy zostać umieszczone za swoim właścicielem. Jeśli to okno ma właściciela, wówczas następuje ustawienie właściciela i innych posiadanych przez niego okien również za oknem docelowym. Jeśli okno docelowe ma właściciela, wówczas to okno zostaje ustawione za właścicielem okna docelowego.

Niektóre menedżery okien systemu Linux nie zezwalają na umieszczanie okien narzędziowych za oknami zwykłymi.

Parametry

windowBehind.orderInBackOf(windowFront);

displayObjBehind.stage.nativeWindow.orderInBackOf(displayObjectFront.stage.nativeWindow);

jsWindowObjBehind.nativeWindow.orderInBackOf(jsWindowObjFront.nativeWindow);

Przesuwa to okno bezpośrednio na przód wybranego okna.

Nie aktywuje ani nie otrzymuje fokusu dla okna lub aplikacji. Okna zminimalizowane lub ukryte (wartość visible to false) nie mogą mieć zmienionej kolejności.

Nigdy nie można ustawić okna przed oknem posiadanym przez dane okno. Jeśli to okno ma właściciela, wówczas następuje ustawienie właściciela i innych posiadanych przez niego okien również przed oknem docelowym. Jeśli okno docelowe ma właściciela, wówczas to okno zostaje również umieszczone przed innymi oknami mającymi tego samego właściciela co okno docelowe.

Niektóre menedżery okien w systemie Linux nie zezwalają na umieszczanie zwykłych okien nad oknami narzędziowymi.

Parametry

windowFront.orderInFrontOf(windowBehind);

displayObjFront.stage.nativeWindow.orderInFrontOf(displayObjectBehind.stage.nativeWindow);

jsWindowObjFront.nativeWindow.orderInFrontOf(jsWindowObjBehind.nativeWindow);

Wysyła to okno pod inne widoczne okna.

Nie aktywuje ani nie otrzymuje fokusu dla tego okna lub aplikacji. Okna zminimalizowane lub ukryte (wartość visible to false) nie mogą mieć zmienionej kolejności.

Jeżeli dla wartości alwaysInFront ustawiono true, wówczas wywoływanie tej metody nie wyśle tego okna na tył innych okien, posiadających wartość alwaysInFront, dla której ustawiono false.

Posiadane okno nie może nigdy zostać umieszczone za swoim właścicielem. Jeśli to okno ma właściciela, wówczas następuje ustawienie właściciela i innych posiadanych przez niego okien również na spodzie listy wyświetlania okien. To okno zostanie przesunięte za wszystkie inne okna posiadane przez to samo okno. Jeśli to okno posiada inne okna, wówczas te okna zostaną przesunięte do tyłu z zachowaniem ich kolejności względem siebie.

Niektóre menedżery okien systemu Linux nie zezwalają na umieszczanie okien narzędziowych za oknami zwykłymi.

windowObj.orderToBack();

displayObj.stage.nativeWindow.orderToBack();

window.nativeWindow.orderToBack();

Przesuwa to okno na przód względem pozostałych widocznych okien.

Nie aktywuje ani nie otrzymuje fokusu dla tego okna lub aplikacji. Okna zminimalizowane lub ukryte (wartość visible to false) nie mogą mieć zmienionej kolejności.

Jeśli dla alwaysInFront ustawiono wartość false, wówczas wywołanie tej metody nie spowoduje wysłania tego okna na przód innych okien, dla których dla parametru alwaysInFront ustawiono wartość true.

Nigdy nie można ustawić okna przed oknem posiadanym przez dane okno. Jeśli to okno posiada inne okna, wówczas te okna zostaną przesunięte do przodu z zachowaniem ich kolejności względem siebie. Jeśli to okno ma właściciela, wówczas następuje ustawienie właściciela i wszystkich posiadanych przez niego okien również z przodu w kolejności wyświetlania okien. To okno zostaje przesunięte przed inne okna mające tego samego właściciela.

Niektóre menedżery okien w systemie Linux nie zezwalają na umieszczanie zwykłych okien nad oknami narzędziowymi.

windowObj.orderToFront();

displayObj.stage.nativeWindow.orderToFront();

window.nativeWindow.orderToFront();

Przywraca to okno ze stanu zminimalizowanego lub zmaksymalizowanego.

Wywołanie metody restore()powoduje wywołanie zdarzenia displayStateChange oraz, jeśli to możliwe, zdarzenia move i resize. Karnacja systemu wywoła zdarzenie displayStateChanging, które może zostać anulowane gdy polecenie przywracania jest wydane przez użytkownika, jednakże w takim przypadku logika przywracania ustawiona przez użytkownika musi implementować takie zachowanie.

Jeżeli okno jest już w stanie NativeWindowDisplayState.NORMAL,wówczas nie jest podejmowana żadna akcja ani nie są wywoływane zdarzenia.

Aby wykryć zakończenie zmiany stanu, należy wykrywać zdarzenie displayStateChange, które jest wywoływane na wszystkich platformach.

Powiązane elementy interfejsu API

public function restoreWindow(nativeWin:NativeWindow):Boolean{
    if(nativeWin.displayState != NativeWindowDisplayState.NORMAL){
        var beforeState:String = nativeWin.displayState;
        var afterState:String = NativeWindowDisplayState.NORMAL;
        var displayStateChangingEvent:NativeWindowDisplayStateEvent = 
            new NativeWindowDisplayStateEvent(NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        nativeWin.dispatchEvent(displayStateChangingEvent);
        if(!displayStateChangingEvent.isDefaultPrevented()){
            nativeWin.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

function restoreWindow(nativeWin){
    if(window.nativeWindow.displayState != air.NativeWindowDisplayState.NORMAL){
        var beforeState = window.nativeWindow.displayState;
        var afterState = air.NativeWindowDisplayState.NORMAL;
        var displayStateEvent = 
            new air.NativeWindowDisplayStateEvent(air.NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING,
                                              true,true,beforeState,afterState);
        window.nativeWindow.dispatchEvent(displayStateEvent);
        if(!displayStateEvent.isDefaultPrevented()){
            window.nativeWindow.restore();
            return true;
        } else {
          return false;
        }
     }
     return false;
}

Rozpoczyna przesunięcie okna kontrolowane przez system.

W przypadku wywołania ze zdarzenia mouseDown, ta metoda rozpoczyna się sekwencją przesuwania sterowaną myszą, która jest kontynuowana do momentu wystąpienia zdarzenia mouseUp.

W przypadku wywołania z innego kodu, ta metoda rozpoczyna się sekwencją przesuwania sterowaną klawiaturą lub myszą zgodną z domyślną sekwencją systemu operacyjnego.

W trakcie sekwencji przesuwania zostaną wywołane serie zdarzeń zgodnie z ruchem okna źródłowego. Dla każdego ruchu przyrostowego najpierw wywoływane jest zdarzenie moving, a następnie (jeżeli zdarzenie moving nie zostało anulowane) aktualizowane jest położenie okna oraz wywoływane jest zdarzenie typu move. Jeśli zdarzenie moving zostało anulowane, sekwencja przesuwania zostaje natychmiast zakończona.

var initOpts:NativeWindowInitOptions = new NativeWindowInitOptions();
var win:NativeWindow = new NativeWindow(initOpts);
win.activate();
win.stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

function mouseDownHandler(event:MouseEvent):void
{
    win.startMove();
}

Rozpoczyna operację zmiany rozmiarów okna, kontrolowaną przez system.

W przypadku wywołania z modułu obsługi zdarzeń mouseDown, ta metoda rozpoczyna się sekwencją zmiany rozmiarów sterowaną myszą, która jest kontynuowana do momentu wystąpienia zdarzenia mouseUp.

W przypadku wywołania z innego kodu, ta metoda rozpoczyna się sekwencją zmiany rozmiarów sterowaną klawiaturą lub myszą, zgodną z domyślną sekwencją systemu operacyjnego.

W trakcie sekwencji zmiany rozmiarów zostaną wywołane serie zdarzeń zgodnie ze zmianą rozmiarów okna. Dla każdego ruchu przyrostowego najpierw wywoływane jest zdarzenie resizing, a następnie (jeżeli zdarzenie resizing nie zostało anulowane) aktualizowane jest położenie okna oraz wywoływane jest zdarzenie typu resize. Jeżeli zdarzenie resizing zostało anulowane, wówczas sekwencja zmiany rozmiarów zostaje natychmiast zakończona.

Parametry

Powiązane elementy interfejsu API

stage.addEventListener(MouseEvent.MOUSE_DOWN, onResizeCommand);

function onResizeCommand(event:MouseEvent):void
{
    var win:NativeWindow = event.target.nativeWindow;
    var resizeFrom:String = "";
    if (event.stageY < win.height * .33)
    {
        resizeFrom = NativeWindowResize.TOP;
    }
    else if (event.stageY > win.height * .66)
    {
        resizeFrom = NativeWindowResize.BOTTOM;
    }
    if (event.stageX < win.width * .33)
    {
        resizeFrom += NativeWindowResize.LEFT;
    }
    else if (event.stageX > win.width * .66)
    {
        resizeFrom += NativeWindowResize.RIGHT;
    }
    win.startResize(resizeFrom);    
}

Wywołane przez ten obiekt NativeWindow po aktywacji okna.

Uwaga: to zdarzenie nie zawiera fazy „przechwytywania” ani „propagacji”, co oznacza, że detektory zdarzeń muszą być dodawane bezpośrednio do każdego potencjalnego obiektu docelowego — niezależnie od tego, czy obiekt znajduje się na liście wyświetlania.

To zdarzenie nie jest nigdy automatycznie wywoływane na urządzeniach telewizyjnych ze środowiskiem AIR. Można wywołać je ręcznie.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow po zamknięciu okna.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow tuż przed zamknięciem okna. To zdarzenie może zostać anulowane, aby zapobiec zamknięciu okna.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow po dezaktywacji okna.

Uwaga: to zdarzenie nie zawiera fazy „przechwytywania” ani „propagacji”, co oznacza, że detektory zdarzeń muszą być dodawane bezpośrednio do każdego potencjalnego obiektu docelowego — niezależnie od tego, czy obiekt znajduje się na liście wyświetlania.

To zdarzenie nie jest nigdy automatycznie wywoływane na urządzeniach telewizyjnych ze środowiskiem AIR. Można wywołać je ręcznie.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow po zmianie właściwości displayState okna.

Nie należy zmieniać rozmiaru okna ani jego stanu wyświetlania w funkcji obsługi zdarzenia displayStateChange.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow tuż przed zmianą stanu wyświetlania okna. Zdarzenie można anulować, aby zapobiec zmianie.

To zdarzenie ma następujące właściwości:

function displayStateChanging_handler(displayStateEvent:NativeWindowDisplayStateEvent):void
{
  //shouldStopStateChange is an application-defined Boolean indicating 
  //that display state changes should be canceled
  if (displayStateEvent.type == NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGING 
                                  &&    shouldStopStateChange)
  {
    displayStateEvent.preventDefault();
  }
}

Wywołane przez ten obiekt NativeWindow po przesunięciu okna na pulpit.

Zdarzenie move jest wywoływane, gdy źródło (właściwości x lub y) okna ulegnie zmianie, co może się zdarzyć z powodu przesunięcia okna kontrolowanego przez system; minimalizacji, maksymalizacji, przywracania okna lub zmiany pozycji okna poprzez ustawienie właściwości x, y lub bounds.

Uwaga: Należy unikać akcji, które mogą otwierać jednocześnie okna dialogowe systemu operacyjnego w funkcjach modułu obsługi dla zdarzeń moving i move obiektu NativeWindow. Może się tak zdarzyć, gdy np. oba moduły obsługi zgłoszą błąd. Jeżeli do tego dojdzie, drugie otworzone okno dialogowe nie będzie rejestrowało kliknięć myszy i konieczne będzie jego zamknięcie za pomocą klawiatury.

To zdarzenie ma następujące właściwości:

Wywołane przez ten obiekt NativeWindow tuż przed przesunięciem okna na pulpit. Zdarzenie może zostać anulowane, aby zapobiec lub zmodyfikować przesunięcie.

Uwaga: Należy unikać akcji, które mogą otwierać jednocześnie okna dialogowe systemu operacyjnego w funkcjach modułu obsługi dla zdarzeń moving i move obiektu NativeWindow. Może się tak zdarzyć, gdy np. oba moduły obsługi zgłoszą błąd. Jeżeli do tego dojdzie, drugie otworzone okno dialogowe nie będzie rejestrowało kliknięć myszy i konieczne będzie jego zamknięcie za pomocą klawiatury.

To zdarzenie ma następujące właściwości:

Uwaga: W systemie Linux metoda preventDefault() nie jest obsługiwana dla tego zdarzenia.

Wywołane przez ten obiekt NativeWindow po zmianie rozmiaru okna. Zdarzenie resize jest wywoływane zawsze, gdy dojdzie do zmiany wielkości (właściwości width i height) okna, do której może dojść na skutek zmiany wielkości okna kontrolowanej przez system; minimalizowania, maksymalizowania lub przywracania okna; a także na skutek zmiany wielkości okna po ustawieniu właściwości width, height lub bounds. Zdarzenia NativeWindow resize są wywoływane podczas pętli zmiany wielkości kontrolowanych przez system. Natomiast zdarzenia resize obiektu Stage są wywoływane w momencie, gdy obiekt Stage jest gotowy do rysowania.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywołane przez ten obiekt NativeWindow tuż przed zmianą rozmiarów okna na pulpicie. Zdarzenie może zostać anulowane, aby zapobiec lub zmodyfikować zmianę rozmiarów.

To zdarzenie ma następujące właściwości:

Uwaga: W systemie Linux metoda preventDefault() nie jest obsługiwana dla tego zdarzenia.

function boundsChanging_handler(boundsEvent:NativeWindowBoundsEvent):void
{
  //shouldStopResize is an application-defined Boolean indicating 
  //that resize operations should be canceled
  if (boundsEvent.type == NativeWindowBoundsEvent.RESIZING && shouldStopResize)
  {
    boundsEvent.preventDefault();
  }
}