LoaderInfo  - AS3

ロード済みの SWF ファイルの ActionScript バージョンです。言語バージョンは、ActionScriptVersion クラスに列挙されているものを使用して指定されます。例えば、ActionScriptVersion.ACTIONSCRIPT2 や ActionScriptVersion.ACTIONSCRIPT3 などです。

注意：このプロパティの値は、必ず、ActionScriptVersion.ACTIONSCRIPT2 または ActionScriptVersion.ACTIONSCRIPT3 のいずれかになります。ActionScript 1.0 と 2.0 はどちらも ActionScriptVersion.ACTIONSCRIPT2（バージョン 2.0）と見なされます。このプロパティは、ActionScript 1.0/2.0 と ActionScript 3.0 だけを区別します。

関連する API エレメント

外部 SWF ファイルが読み込まれると、読み込まれたクラスに含まれているすべての ActionScript 3.0 定義は applicationDomain プロパティに格納されます。

SWF ファイル内のすべてのコードは、アプリケーションドメイン内に存在するように定義されます。現在のアプリケーションドメインは、メインアプリケーションが実行されている場所です。システムドメインには、現在のドメインおよび Flash Player または Adobe AIR によって使用されるすべてのクラスを含む、すべてのアプリケーションドメインが含まれます。

システムドメインを除くすべてのアプリケーションドメインには、親ドメインが関連付けられています。メインアプリケーションの applicationDomain の親ドメインは、システムドメインです。ロードされるクラスは、その親によってまだ定義されていない場合にのみ定義されます。ロードされるクラスの定義を新しい定義でオーバーライドすることはできません。

アプリケーションドメインの使用例については、『ActionScript 3.0 開発ガイド』の「クライアントのシステム環境」の章を参照してください。

関連する API エレメント

LoaderInfo オブジェクトに関連付けられているバイト数です。

そのメディアのロード済みのバイト数です。この数値が bytesTotal の値と同じである場合、すべてのバイト数がロードされます。

メディアファイル全体の圧縮後のバイト数です。

最初の progress イベントが、この LoaderInfo オブジェクトの対応する Loader オブジェクトによって送出される前、bytesTotal は 0 です。Loader オブジェクトの最初の progress イベントの後、bytesTotal は、ダウンロードされる実際のバイト数を反映します。

注意（iOS のみ）：iOS でアプリケーションを実行する場合、返される値は他のプラットフォームとは異なります。

関連する API エレメント

コンテンツ（子）からロードする側（親）への信頼関係を表します。子が親へのアクセスを許可されている場合は true、そうでない場合は false です。このプロパティが true に設定されるのは、子オブジェクトが allowDomain() メソッドを呼び出して親ドメインへの許可を受けている場合、または子ドメインに URL ポリシーがロードされていて親ドメインへの許可を受けている場合です。子と親が同じドメインに置かれている場合、このプロパティは true に設定されます。

セキュリティについて詳しくは、Flash Player デベロッパーセンターのトピック：セキュリティを参照してください。

Loader オブジェクトのサンドボックスにあるコードによってアクセスできるプロパティとメソッドを公開するために、ロードされたコンテンツのコードで設定できるオブジェクトです。このサンドボックスブリッジによって、アプリケーション以外のドメインからのコンテンツがアプリケーションサンドボックスのスクリプトへのアクセスを制御しており、また、その逆もおこなっています。サンドボックスブリッジは、サンドボックス間のゲートウェイとして機能し、アプリケーションとアプリケーション以外のセキュリティサンドボックスの間での明示的なやり取りを提供します。

関連する API エレメント

この LoaderInfo オブジェクトに関係したロードされたオブジェクトです。

ロードされたファイルの MIME タイプです。ファイルのロードが正しく行われておらず、タイプを判別できない場合、この値は null です。 次のリストは、想定される値を示しています。

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

読み込み済みの SWF ファイルに関する 1 秒ごとのフレーム数を表す公称のフレームレートです。この数値はほとんどの場合整数ですが、整数でなくても構いません。

この値は、実際のフレームレートとは異なる場合があります。Flash Player または Adobe AIR は、すべてのロード済み SWF ファイルについて一度に 1 つのフレームレートしか使用せず、このフレームレートはメイン SWF ファイルの公称のフレームレートによって決まります。 また、メインのフレームレートは、ハードウェア、サウンド同期、およびその他の要素によっては達成できない場合があります。

読み込まれたファイルの規格高さです。読み込まれたコンテンツやその親表示オブジェクトは拡大 / 縮小されている場合があるため、この値は表示されているコンテンツの実際の高さとは異なる場合があります。

LoaderInfo.url プロパティが切り詰められているかどうかを示します。isURLInaccessible 値が true の場合、LoaderInfo.url の値は、コンテンツのロード元となる最終的な URL のドメイン部分のみになります。例えば、コンテンツが http://www.adobe.com/assets/hello.swf から読み込まれ、LoaderInfo.url プロパティの値が http://www.adobe.com の場合、このプロパティは切り詰められています。isURLInaccessible の値は、以下の値もすべて true の場合のみ true になります。

• コンテンツの読み込み中に HTTP リダイレクトが発生しました。
• Loader.load() の呼び出し元の SWF ファイルが、コンテンツの最終的な URL とは別のドメインからのファイルです。
• Loader.load() の呼び出し元の SWF ファイルに、コンテンツにアクセスする許可がありません。コンテンツにアクセスする許可は BitmapData.draw() に許可が与えられる場合と同じ方法で与えられます。つまり、Security.allowDomain() を呼び出して、SWF ファイルにアクセスします（または、SWF ファイルコンテンツ以外の場合、ポリシーファイルを作成して、LoaderContext.checkPolicyFile プロパティを使用します）。

注意：isURLInaccessible プロパティは Flash Player 10.1 および AIR 2.0 用に追加されました。ただし、Flash ランタイムでサポートされている場合、このプロパティはすべてのバージョンの SWF ファイルで使用できます。このため、オーサリングツールを「strict モード」で使用するとコンパイルエラーが発生します。このエラーを回避するには、間接構文 myLoaderInfo["isURLInaccessible"] を使用するか、strict モードを無効にします。Flash Professional CS5 または Flex SDK 4.1 を使用している場合、Flash Player 10.1 および AIR 2 以前にリリースされたランタイム向けに、この API を使用してコンパイルすることができます。

AIR のアプリケーションコンテンツの場合、このプロパティの値は常に false です。

関連する API エレメント

この LoaderInfo オブジェクトに関係した Loader オブジェクトです。この LoaderInfo オブジェクトが、SWF ファイルのメインクラスのインスタンスの loaderInfo プロパティである場合、関係する Loader オブジェクトはありません。

この LoaderInfo オブジェクトによって記述されるメディアの読み込みを開始した SWF ファイルの URL です。SWF ファイルのメインクラスのインスタンスの場合、この URL は、SWF ファイル自体の URL と同じものです。

ロード済みの SWF ファイルに提供されるパラメーターを表す、名前と値の組を含んだオブジェクトです。

for-in ループを使用すると、parameters オブジェクトからすべての名前と値を抽出できます。

パラメーターは、メイン SWF ファイルの URL のクエリ文字列と、FlashVars HTML パラメーターの値の 2 つから提供されます。この HTML パラメーターはメイン SWF ファイルにのみ影響します。

parameters プロパティは、メインタイムラインのプロパティとして SWF ファイルパラメーターを提供する ActionScript 1.0 および 2.0 の方法を置き換えます。

parameters プロパティの値は、ActionScript 1.0 または 2.0 を使用する SWF ファイルを含んだ Loader オブジェクトについては null です。ActionScript 3.0 を使用する SWF ファイルを含んだ Loader オブジェクトについてのみ、null 以外の値になります。

ロードする側（親）からコンテンツ（子）への信頼関係を表します。親が子のアクセスを許可している場合は true、そうでない場合は false です。このプロパティが true に設定されるのは、親オブジェクトが allowDomain() メソッドを呼び出して子ドメインへの許可を受けている場合、または親ドメインに URL ポリシーファイルがロードされていて子ドメインへの許可を受けている場合です。子と親が同じドメインに置かれている場合、このプロパティは true に設定されます。

セキュリティについて詳しくは、Flash Player デベロッパーセンターのトピック：セキュリティを参照してください。

ロードされたコンテンツのコードによってアクセスできるプロパティとメソッドを公開するために、Loader オブジェクトのサンドボックス内にあるコードで設定できるオブジェクトです。このサンドボックスブリッジによって、アプリケーション以外のドメインからのコンテンツがアプリケーションサンドボックスのスクリプトへのアクセスを制御しており、また、その逆もおこなっています。サンドボックスブリッジは、サンドボックス間のゲートウェイとして機能し、アプリケーションとアプリケーション以外のセキュリティサンドボックスの間での明示的なやり取りを提供します。

関連する API エレメント

読み込む側とそのコンテンツの間のドメインの関係を次のように表します。ドメインが同じ場合は true、異なる場合は false です。

セキュリティ境界を越えてイベントを交換するために使用される EventDispatcher インスタンスです。Loader オブジェクトとロードされたコンテンツが、互いに信頼関係を確立していないセキュリティドメインに置かれている場合でも、どちらも sharedEvents にアクセスし、このオブジェクトを経由してイベントを送受信することができます。

ロード済みの SWF ファイルのファイル形式のバージョンです。ファイル形式は、SWFVersion クラスに列挙されているものを使用して指定されます。例えば、SWFVersion.FLASH7 や SWFVersion.FLASH9 などです。

関連する API エレメント

この LoaderInfo オブジェクトの SWF ファイルのコードで不明なエラーが発生したときに、uncaughtError イベントを送出するオブジェクトです。不明なエラーが発生するのは、いずれかの try..catch ブロックの外側でエラーがスローされたり、登録されたリスナーを持たない ErrorEvent オブジェクトが送出される場合です。

例えば、try ブロックにイベントハンドラーを呼び出すイベントディスパッチャーがある場合、catch ブロックはイベントハンドラーで発生したエラーをキャッチしません。その後に発生したエラーは、LoaderInfo.uncaughtErrorEvents をリッスンすることによってキャッチできます。

このプロパティが作成されるのは、この LoarderInfoに関連付けられた SWF がロードを完了したときです。それまでは、uncaughtErrorEvents プロパティの値は null です。 ActionScript 専用のプロジェクトでは、SWF ファイルのメインクラスのコンストラクター関数の実行中または実行後にこのプロパティにアクセスできます。Flex プロジェクトでは、uncaughtErrorEvents プロパティは、applicationComplete イベントが送出された後に使用できるようなります。

関連する API エレメント

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

読み込まれるメディアの URL です。

この LoaderInfo オブジェクトの対応する Loader オブジェクトによって最初の progress イベントが送出されるまでは、url プロパティの値に、Loader オブジェクトの load() メソッドの呼び出しで指定した初期 URL しか反映されていない可能性があります。最初の progress イベントの後は、url プロパティはリダイレクトや相対 URL が解決された後のメディアの最終的な URL を反映します。

場合によっては、url プロパティの値が切り詰められていることがあります。詳しくは、isURLInaccessible プロパティを参照してください。

関連する API エレメント

読み込まれたコンテンツの規格幅です。読み込まれたコンテンツやその親表示オブジェクトは拡大 / 縮小されている場合があるため、この値は表示されているコンテンツの実際の幅とは異なる場合があります。

オブジェクトとして定義され、SWF ファイルに関連付けられている LoaderInfo オブジェクトを返します。

パラメーター

データが正常にロードされたときに送出されます。つまり、すべてのコンテンツのダウンロードが完了し、ロードが完了したときに送出されます。complete イベントは、常に、init イベントの後に送出されます。 init イベントはオブジェクトにアクセス可能になったときに送出されますが、コンテンツはまだダウンロード中である可能性があります。

このイベントには、次のプロパティがあります。

関連する API エレメント

ネットワーク要求が HTTP を介して行われ、HTTP ステータスコードを検出できる場合に送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

ロードされた SWF ファイルのプロパティおよびメソッドがアクセス可能で使用できる状態の場合に送出されます。ただし、コンテンツはダウンロード中の可能性があります。次に示す条件に適合するときに LoaderInfo オブジェクトは init イベントを送出します。

• 読み込まれたオブジェクトに関係したすべてのプロパティとメソッド、および LoaderInfo オブジェクトに関係したすべてのプロパティとメソッドにアクセスできます。
• すべての子オブジェクトのコンストラクターが完了済みです。
• ロードされた SWF のメインタイムラインの最初のフレームに含まれるすべての ActionScript コードが実行済みです。

例えば、ムービーまたはアニメーションの最初のフレームがロードされたとき、Event.INIT が送出されます。その時点で、ムービーはアクセス可能になり、表示リストに追加できます。ただし、ムービー全体のダウンロードには、さらに時間がかかる可能性があります。Event.COMPLETE は、ムービー全体がダウンロードされた時点で初めて送出されます。

init イベントは、常に、complete イベントの前に送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

入出力エラーが発生して読み込み処理が失敗したときに送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

ロード操作が開始したときに送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

ダウンロード処理を実行中にデータを受信したときに送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

読み込まれたオブジェクトが Loader オブジェクトの unload() メソッドを使用して削除されるたびに、LoaderInfo オブジェクトによって送出されます。または 2 番目の読み込みが同じ Loader オブジェクトによって実行され、読み込み開始前に元のコンテンツが削除された場合に、LoaderInfo オブジェクトによって送出されます。

このイベントには、次のプロパティがあります。

関連する API エレメント

1. プロパティ url を作成します。これはイメージの場所と名前です。
2. クラスコンストラクターは loader という名前の Loader オブジェクトを作成します。
3. loader オブジェクトはイベントリスナーをインスタンス化して、イメージが正しくロードされるようにします。
4. コンストラクターは、request という URLRequest オブジェクトの新しいインスタンスを作成しますが、その前に、ファイル名と場所が分かるように url を渡します。
5. 次に request オブジェクトが load() メソッド（loader オブジェクトのメソッド）に渡されます。このメソッドでは、イメージが表示リストにロードされます。

重要：この例では、Image.gif という名前のファイルがコンパイル済み SWF ファイルと同じディレクトリに追加されている必要があります。メイン SWF ファイルのサイズ内に収まる領域を持つイメージを使用します。

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}