CameraRoll  - AS3

Consente di determinare se l’applicazione ha ottenuto l’autorizzazione di accesso al rullino fotografico.

Elementi API correlati

Indica se il metodo CameraRoll.addBitmapData() è supportato. Attualmente, questa funzione è supportata solo nelle applicazioni AIR eseguite sui dispositivi mobili.

Segnala se il metodo CameraRoll.browseForImage() è supportato. Attualmente, questa funzione è supportata solo nelle applicazioni AIR eseguite sui dispositivi mobili.

Crea un oggetto CameraRoll.

È presente un'unica libreria multimediale supportata da ActionScript. Tutti gli oggetti CameraRoll vengono salvati nello stesso archivio immagini.

Aggiunge un'immagine al rullino fotografico della fotocamera.

Per verificare in runtime se l'applicazione supporta il metodo CameraRoll.addBitmapData(), controllate la proprietà CameraRoll.supportsAddBitmapData.

Parametri

Apre una finestra di ricerca immagini per consentire all'utente di selezionare un'immagine esistente dal rullino fotografico del dispositivo.

Quando l'utente seleziona un'immagine, l'istanza CameraRoll invia un evento select contenente un oggetto MediaEvent. Utilizzate la proprietà data dell'oggetto MediaEvent per caricare l'immagine. La proprietà data è un oggetto MediaPromise che è possibile caricare utilizzando il metodo loadFilePromise() della classe Loader. Notate che l’oggetto MediaPromise contiene un oggetto file valido su alcune piattaforme (Blackberry Tablet OS) ma non su altre (iOS e Android). Se si utilizza il metodo loadFilePromise(), l'immagine viene caricata correttamente su tutte le piattaforme. Per accedere ai dati grezzi dell'oggetto multimediale, potete aprire l'origine dati fornita dalla promessa multimediale e leggere i dati utilizzando i metodi dell'interfaccia IDataInput.

Per verificare in runtime se l'applicazione supporta il metodo CameraRoll.browseForImage(), controllate la proprietà CameraRoll.supportsBrowseForImage.

In iOS (e solo sull'iPad) potete richiedere una dimensione specifica per la finestra di dialogo del browser di immagini. Potete anche specificare un'area dello schermo che non deve essere coperta dalla finestra del browser di immagini. Questa richiesta funziona solo sull'iPad perché su quel dispositivo il browser di immagini non occupa l'intero schermo.

Per richiedere opzioni di dimensione e posizionamento per il browser di immagini (per iPad), passate un oggetto CameraRollBrowseOptions a browseForImage(). Senza parametri, questo metodo posiziona la finestra di dialogo nell'angolo superiore sinistro del display, utilizzando le impostazioni predefinite del sistema per le dimensioni della finestra di dialogo.

Parametri

Altre informazioni

Elementi API correlati

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Richiede l’autorizzazione di accesso alla libreria multimediale del sistema (o “rullino fotografico”).

Inviato quando un utente annulla un'operazione di ricerca di un'immagine senza selezionare un'immagine.

Questo evento ha le seguenti proprietà:

Segnala che un'operazione addBitmapData() è stata completata correttamente.

Questo evento ha le seguenti proprietà:

L'evento error viene inviato quando si verifica un errore.

Gli errori possibili includono:

• Non è possibile aprire un browser di immagini.
• È già in uso un browser di immagini.
• L'applicazione AIR tenta di cercare un'immagine mentre è in background.
• Non è possibile aggiungere un'immagine alla libreria multimediale.
• Viene chiamato un metodo che non è supportato dal dispositivo.
• L'applicazione AIR tenta di caricare un'immagine remota senza la connessione Internet.

Questo evento ha le seguenti proprietà:

Inviato quando l’applicazione richiede l’autorizzazione di accesso al rullino fotografico. Controllando il valore della proprietà status, è possibile verificare se l’autorizzazione è stata concessa o negata.

Elementi API correlati

Inviato quando un utente seleziona un'immagine dalla libreria multimediale del dispositivo.

L'oggetto MediaEvent inviato per questo evento permette di accedere all'elemento multimediale selezionato.

Definisce il valore della proprietà type di un oggetto evento MediaEvent. Questo evento ha le seguenti proprietà: