HTMLHost

Pacchetto	flash.html
Classe	public class HTMLHost
Ereditarietà	HTMLHost Object

Versioni runtime:

AIR 1.0

Un oggetto HTMLHost definisce il comportamento dell'oggetto HTMLLoader per gli elementi dell'interfaccia utente che possono essere controllati impostando varie proprietà o chiamando vari metodi dell'oggetto window della pagina HTML. Tali metodi e proprietà sono:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

I metodi della classe HTMLHost forniscono modalità di gestione delle modifiche di queste impostazioni di window. Per utilizzare questa classe, create una nuova classe che estenda la classe HTMLHost (una sottoclasse) e che ignori i metodi per i quali desiderate definire i comportamenti. I metodi della classe HTMLHost gestiscono le proprietà e i metodi JavaScript come segue:

Proprietà o metodo JavaScript	Metodo HTMLHost
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

Per rispondere alle modifiche nei metodi window.moveBy(), window.moveTo(), window.resizeBy() e window.resizeTo(), sostituite il metodo set windowRect() nella sottoclasse di HTMLHost.

Ogni oggetto HTMLHost può essere associato ad almeno un oggetto HTMLLoader. Per stabilire tale relazione, è necessario assegnare un'istanza HTMLHost alla proprietà htmlHost dell'oggetto HTMLLoader. Se assegnate il valore null alla proprietà htmlHost dell'oggetto HTMLLoader o impostate l'oggetto HTMLHost come la proprietà htmlHost di un altro oggetto HTMLLoader, l'oggetto HTMLHost viene rimosso dal primo oggetto HTMLLoader.

Vedere gli esempi

Altri esempi

Definizione di interfacce simili a browser per il contenuto HTML

Elementi API correlati

HTMLLoader
HTMLWindowCreateOptions

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		constructor : Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		htmlLoader : flash.html:HTMLLoader [sola lettura] L'oggetto HTMLLoader a cui si applica questo oggetto HostControl.	HTMLHost
		windowRect : Rectangle La proprietà modificata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.moveBy(), window.moveTo(), window.resizeBy() o window.resizeTo().	HTMLHost

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		HTMLHost(defaultBehaviors:Boolean = true) Crea un oggetto HTMLHost.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.open().	HTMLHost
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toLocaleString():String Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		updateLocation(locationURL:String):void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.location.	HTMLHost
		updateStatus(status:String):void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.status.	HTMLHost
		updateTitle(title:String):void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.document.title oppure quando l'elemento title cambia in base al DOM oppure in seguito al caricamento di una nuova pagina.	HTMLHost
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object
		windowBlur():void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.blur().	HTMLHost
		windowClose():void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.close().	HTMLHost
		windowFocus():void La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.focus().	HTMLHost

Descrizione delle proprietà

htmlLoader

proprietà

htmlLoader:flash.html:HTMLLoader [sola lettura]

Versioni runtime:

AIR 1.0

L'oggetto HTMLLoader a cui si applica questo oggetto HostControl. La proprietà htmlHost di tale oggetto HTMLLoader è impostata su questo oggetto HostControl.

Implementazione
public function get htmlLoader():flash.html:HTMLLoader

Elementi API correlati

HTMLLoader.htmlHost

windowRect

proprietà

windowRect:Rectangle

Versioni runtime:

AIR 1.0

La proprietà modificata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.moveBy(), window.moveTo(), window.resizeBy() o window.resizeTo().

Nella sottoclasse di HTMLHost, sostituite il metodo set windowRect() per gestire i nuovi limiti della finestra come desiderato.

Implementazione
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Descrizione della funzione di costruzione

()

Funzione di costruzione

public function HTMLHost(defaultBehaviors:Boolean = true)

Versioni runtime:

AIR 1.0

Crea un oggetto HTMLHost.

Parametri

defaultBehaviors:Boolean (default = true) — Indica se i comportamenti del contenuto principale devono essere forniti per impostazione predefinita.

Descrizione dei metodi

createWindow

()

metodo

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.open().

Per impostazione predefinita, una chiamata JavaScript al metodo window.open() nella pagina HTML di un oggetto HTMLLoader non apre un nuovo oggetto NativeWindow nel runtime. Potete aprire un nuovo oggetto NativeWindow nel runtime creando un nuovo oggetto NativeWindow nell'override del metodo createWindow nella sottoclasse della classe HTMLHost.

Parametri

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Un oggetto contenente proprietà nella stringa passata come il parametro features della chiamata al metodo window.open().

Restituisce

flash.html:HTMLLoader — Un oggetto HTMLLoader che contiene la nuova pagina HTML. Generalmente, potete creare un nuovo oggetto HTMLLoader in questo metodo, aggiungerlo allo stage di un nuovo oggetto NativeWindow, quindi restituirlo.

updateLocation

()

metodo

public function updateLocation(locationURL:String):void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.location.

Parametri

locationURL:String — Valore su cui è impostata la proprietà location della proprietà window dell'oggetto HTMLLoader.

updateStatus

()

metodo

public function updateStatus(status:String):void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.status.

Parametri

status:String — Valore su cui è impostata la proprietà status della proprietà window dell'oggetto HTMLLoader.

updateTitle

()

metodo

public function updateTitle(title:String):void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader imposta la proprietà window.document.title oppure quando l'elemento title cambia in base al DOM oppure in seguito al caricamento di una nuova pagina.

Parametri

title:String — Valore su cui è impostata la proprietà window.document.title dell'oggetto HTMLLoader.

windowBlur

()

metodo

public function windowBlur():void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.blur().

windowClose

()

metodo

public function windowClose():void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.close().

Per impostazione predefinita, una chiamata JavaScript al metodo window.close() nella pagina HTML di un oggetto HTMLLoader chiude le finestre contenenti l'oggetto HTMLLoader.

windowFocus

()

metodo

public function windowFocus():void

Versioni runtime:

AIR 1.0

La funzione chiamata quando il codice JavaScript dell'oggetto HTMLLoader chiama il metodo window.focus().

Esempi Come utilizzare questo esempio

HTMLHost.1.as

Il codice seguente definisce CustomHot, una sottoclasse di HTMLHost. I metodi della classe CustomHost sostituiscono i metodi ereditati nella classe HTMLHost per definire le azioni intraprese quando il codice JavaScript nella pagina HTMLLoader imposta varie proprietà o chiama vari metodi dell'oggetto window:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Create la classe seguente, che aggiunge un oggetto HTMLLoader allo stage, così come un oggetto TextField denominato statusBar. L'oggetto HTMLLoader definisce un oggetto CustomHost come sua proprietà htmlHost:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Costruite un'applicazione AIR che aggiunge un oggetto definito da questa classe allo stage della finestra principale.

Create una pagina HTML denominata Test.html nella directory delle risorse dell'applicazione (directory contenente il file descrittore dell'applicazione) e aggiungetevi il seguente contenuto:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

Quando testate l'applicazione, la classe CustomHost gestisce le impostazioni JavaScript relative all'interfaccia utente nella pagina HTML.

Note legali | Informativa sulla privacy online

HTMLHost - AS3

Pacchettix

Elementi del linguaggio

Appendici

Pacchetto flash.html

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus