| Pacchetto | flash.filesystem |
| Classe | public class StorageVolume |
| Ereditarietà | StorageVolume  Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
- La proprietà
storageVolumedi un oggetto StorageVolumeChangeEvent è un oggetto StorageVolume. Questo oggetto rappresenta il volume di archiviazione che è stato montato o smontato. - Il metodo
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes()restituisce un vettore di oggetti StorageVolume. Ognuno di questi oggetti StorageVolume rappresenta un volume di archiviazione montato.
Altri esempi
Elementi API correlati
flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume
flash.events.StorageVolumeChangeEvent.storageVolume
Proprietà pubbliche
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
 | constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| drive : String [sola lettura]
La lettera di unità del volume in Windows. | StorageVolume | ||
| fileSystemType : String [sola lettura]
Il tipo di file system sul volume di archiviazione (ad esempio "FAT", "NTFS", "HFS" o "UFS"). | StorageVolume | ||
| isRemovable : Boolean [sola lettura]
Indica se il sistema operativo considera il volume di archiviazione rimovibile (true) o non rimovibile (false). | StorageVolume | ||
| isWritable : Boolean [sola lettura]
Se un volume è scrivibile (true) o meno (false). | StorageVolume | ||
| name : String [sola lettura]
Il nome del volume. | StorageVolume | ||
| rootDirectory : File [sola lettura]
Un oggetto File corrispondente alla directory principale del volume. | StorageVolume | ||
Metodi pubblici
| Metodo | Definito da | ||
|---|---|---|---|
StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)
La funzione di costruzione. | StorageVolume | ||
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
Descrizione delle proprietà
drive | proprietà |
fileSystemType | proprietà |
fileSystemType:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
Il tipo di file system sul volume di archiviazione (ad esempio "FAT", "NTFS", "HFS" o "UFS").
Implementazione
public function get fileSystemType():StringEsempio ( Come utilizzare questo esempio )
Il codice seguente elenca il percorso nativo della directory principale e il tipo di file system di ogni volume di archiviazione montato:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}
isRemovable | proprietà |
isRemovable:Boolean [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
Indica se il sistema operativo considera il volume di archiviazione rimovibile (true) o non rimovibile (false).
Nella seguente tabella sono elencati i valori StorageVolume.isRemovable per vari tipi di dispositivi:
| Tipo di dispositivo | Mac OS | Windows | Linux |
|---|---|---|---|
| CD/DVD (fisso) | true | true | true |
| Unità flash USB | true | true | true |
| Disco rigido USB | false | false | true |
| Disco rigido Firewire | false | false | true |
| Volume condiviso | true | false | - 1 |
| Unità di rete | false | false | false |
| Lettore di schede di memoria (vuoto) | - 2 | false | - 2 |
| Lettore di schede di memoria (con scheda SD/CF) | true | true | true |
1 Linux non prevede la presenza di volumi condivisi.
2 In Windows, un lettore di schede vuoto viene indicato come dispositivo non rimovibile. In Mac OS e Linux, i lettori di schede vuoti non vengono indicati come volumi di archiviazione.
Implementazione
public function get isRemovable():BooleanEsempio ( Come utilizzare questo esempio )
Il codice seguente genera un elenco di volumi di archiviazione non rimovibili, seguito da un elenco di volumi di archiviazione rimovibili:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
if (!volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
if (volumes[i].isRemovable)
{
trace(volumes[i].rootDirectory.nativePath);
}
}
isWritable | proprietà |
isWritable:Boolean [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
Se un volume è scrivibile (true) o meno (false).
Nota: potete determinare la quantità di spazio disponibile su un volume chiamando la proprietà rootDirectory.spaceAvailble dell'oggetto StorageVolume.
Implementazione
public function get isWritable():BooleanElementi API correlati
flash.fileSystem.File.spaceAvailable
Esempio ( Come utilizzare questo esempio )
Il codice seguente genera un elenco di volumi di archiviazione scrivibili e lo spazio disponibile per ognuno di essi:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
if(volumes[i].isWritable)
{
trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
}
}
name | proprietà |
name:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
Il nome del volume. Se non è presente un nome, questa proprietà è impostata su null.
Implementazione
public function get name():StringEsempio ( Come utilizzare questo esempio )
Il codice seguente elenca il percorso nativo della directory principale e il nome del file system (se presente) di ogni volume di archiviazione montato:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var name:String = new String();
if (volumes[i].name)
{
name = "(" + volumes[i].name + ")";
}
trace(volumes[i].rootDirectory.nativePath, name);
}
rootDirectory | proprietà |
rootDirectory:File [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
Un oggetto File corrispondente alla directory principale del volume.
Implementazione
public function get rootDirectory():FileEsempio ( Come utilizzare questo esempio )
Il codice seguente elenca il percorso nativo della directory principale di ogni volume di archiviazione montato:
var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
trace(volumes[i].rootDirectory.nativePath);
}
Descrizione della funzione di costruzione
StorageVolume | () | Funzione di costruzione |
public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 2 |
La funzione di costruzione. In genere, per creare nuovi oggetti StorageVolume, non chiamate questa funzione di costruzione direttamente. Al contrario, fate riferimento agli oggetti StorageVolume accedendo alla proprietà storageVolume di un oggetto StorageVolumeChangeEvent o chiamando StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().
rootDirPath:File | |
name:String | |
writable:Boolean | |
removable:Boolean | |
fileSysType:String | |
drive:String |
StorageVolumeExample.as
Il codice seguente elenca le proprietà di ogni volume di archiviazione mondato:
package
{
import flash.display.Sprite;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeExample extends Sprite
{
public function StorageVolumeExample()
{
var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
var volume:StorageVolume = volumes[i];
trace("nativePath:", volume.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace("________________________________________________________");
}
}
}
}
StorageVolumeChangeEventExample.as
Il codice seguente elenca le proprietà di ogni volume di archiviazione che viene montato o smontato: Tenete presente che la proprietà
storageVolume di StorageVolumeChangeEvent viene impostata solo per l'evento storageVolumeMount; è null per l'evento storageVolumeUnmount:
package
{
import flash.display.Sprite;
import flash.events.StorageVolumeChangeEvent;
import flash.filesystem.StorageVolume;
import flash.filesystem.StorageVolumeInfo;
public class StorageVolumeChangeEventExample extends Sprite
{
public function StorageVolumeChangeEventExample()
{
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
}
public function mountEventHandler(event:StorageVolumeChangeEvent):void
{
var volume:StorageVolume = event.storageVolume;
trace("VOLUME MOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace("fileSystemType:", volume.fileSystemType);
trace("isRemovable:", volume.isRemovable);
trace("isWritable:", volume.isWritable);
trace("drive:", volume.drive);
trace("name:", volume.name);
trace();
}
public function unmountEventHandler(event:StorageVolumeChangeEvent):void
{
trace("VOLUME UNMOUNTED:");
trace("nativePath:", event.rootDirectory.nativePath);
trace();
}
}
}
Tue Jun 12 2018, 02:44 PM Z