| Pacchetto | flash.external |
| Classe | public final class ExternalInterface |
| Ereditarietà | ExternalInterface  Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Tramite la classe ExternalInterface, potete chiamare una funzione ActionScript nel runtime Flash, utilizzando JavaScript nella pagina HTML. La funzione ActionScript può restituire un valore che JavaScript riceve immediatamente come valore restituito dalla chiamata.
Questa funzionalità sostituisce il metodo fscommand().
Utilizzate la classe ExternalInterface nelle seguenti combinazioni di browser e sistema operativo:
| Browser | Sistema operativo | Sistema operativo |
|---|---|---|
| Internet Explorer 5.0 e versioni successive | Windows | |
| Netscape 8.0 e versioni successive | Windows | MacOS |
| Mozilla 1.7.5 e versioni successive | Windows | MacOS |
| Firefox 1.0 e versioni successive | Windows | MacOS |
| Safari 1.3 e versioni successive | MacOS |
Flash Player per Linux versione 9.0.31.0 e successive supporta la classe ExternalInterface nei browser seguenti:
| Browser |
|---|
| Mozilla 1.7.x e successivi |
| Firefox 1.5.0.7 e versioni successive |
| SeaMonkey 1.0.5 e successivi |
La classe ExternalInterface richiede il supporto per ActiveX ® o per l'API NPRuntime (esposta da alcuni browser per lo script di plug-in) nel browser dell'utente. Anche se una combinazione di browser e sistema operativo non è elencata sopra, se è supportata l'API NPRuntime è supportata anche la classe ExternalInterface. Vedete http://www.mozilla.org/projects/plugins/npruntime.html.
Nota: quando incorporate file SWF all'interno di una pagina HTML, verificate che l'attributo id sia impostato e che gli attributi id e name dei tag object e embed non comprendano i seguenti caratteri:
. - + * / \
Nota per le applicazioni Flash Player: Flash Player versione 9.0.115.0 e successive consentono l'uso del carattere . (punto) all'interno degli attributi id e name.
Nota per le applicazioni Flash Player: in Flash Player 10 e versioni successive in esecuzione in un browser, potrebbe non essere possibile utilizzare questa classe a livello di programmazione per aprire una finestra a comparsa. Browser (e configurazioni del browser) differenti potrebbero bloccare le finestre a comparsa in qualsiasi momento; non è possibile garantire la visualizzazione delle finestre. Tuttavia, per avere più possibilità di successo, utilizzate questa classe per aprire una finestra a comparsa solo in codice che viene eseguita come risultato diretto di un'azione utente (ad esempio, in un gestore di eventi per un clic del mouse o la pressione di un tasto)
Da ActionScript è possibile eseguire le seguenti operazioni sulla pagina HTML:
- chiamare qualsiasi funzione JavaScript
- passare un numero qualsiasi di argomenti, con qualsiasi nome
- passare vari tipi di dati (booleani, numeri, stringhe e così via)
- ricevere un valore restituito dalla funzione JavaScript
Da JavaScript è possibile eseguire le seguenti operazioni sulla pagina HTML:
- chiamare una funzione ActionScript
- passare argomenti mediante una notazione di chiamata a una funzione standard
- restituire un valore alla funzione JavaScript
Nota per le applicazioni Flash Player: attualmente Flash Player non supporta i file SWF incorporati nei moduli HTML.
Nota per le applicazioni AIR: in Adobe AIR, potete utilizzare la classe ExternalInterface per comunicare tra JavaScript in una pagina HTML caricata nel controllo HTMLLoader e ActionScript nel contenuto SWF incorporato in tale pagina HTML.
Altri esempi
Accessing Flex from JavaScript
About ExternalInterface API security in Flex
Uso della classe ExternalInterface
Esempio di API esterna: comunicazione tra ActionScript e JavaScript in un browser Web
Controllo dell’accesso agli URL in uscita
Altre informazioni
Nozioni fondamentali sull'uso dell'API esterna
Requisiti e vantaggi dell'API esterna
Il formato XML dell'API esterna
Elementi API correlati
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
| available : Boolean [statico] [sola lettura]
Indica se Flash Player si trova in un contenitore dotato di interfaccia esterna. | ExternalInterface | ||
 | constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| marshallExceptions : Boolean = false [statico]
Indica se l'interfaccia esterna deve tentare di trasferire le eccezioni ActionScript al browser corrente e le eccezioni JavaScript al lettore. | ExternalInterface | ||
| objectID : String [statico] [sola lettura]
Restituisce l'attributo id del tag object in Internet Explorer o l'attributo name del tag embed in Netscape. | ExternalInterface | ||
| Metodo | Definito da | ||
|---|---|---|---|
[statico]
Registra un metodo ActionScript come metodo chiamabile dal contenitore. | ExternalInterface | ||
[statico]
Chiama una funzione esposta dal contenitore SWF, che passa zero o più argomenti. | ExternalInterface | ||
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
available | proprietà |
available:Boolean [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Indica se Flash Player si trova in un contenitore dotato di interfaccia esterna. Se l'interfaccia esterna è disponibile, questa proprietà è true; in caso contrario, è false.
Nota: quando utilizzate l'API esterna con HTML, verificate sempre che il codice HTML sia stato caricato completamente prima di tentare di chiamare qualsiasi metodo JavaScript.
Implementazione
public static function get available():BooleanAltri esempi
Esempio ( Come utilizzare questo esempio )
available per determinare se Flash Player si trova in un contenitore dotato di interfaccia esterna.
package {
import flash.text.TextField;
import flash.display.MovieClip;
import flash.external.ExternalInterface;
public class extint_test extends MovieClip {
public function extint_test() {
var isAvailable:Boolean = ExternalInterface.available;
var availTxt:TextField = new TextField();
availTxt.text = isAvailable.toString();
addChild(availTxt);
}
}
}
marshallExceptions | proprietà |
public static var marshallExceptions:Boolean = false| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9.0.115.0, Flash Lite 4 |
Indica se l'interfaccia esterna deve tentare di trasferire le eccezioni ActionScript al browser corrente e le eccezioni JavaScript al lettore. Dovete impostare esplicitamente questa proprietà su true per rilevare le eccezioni JavaScript in ActionScript e le eccezioni ActionScript in JavaScript.
Elementi API correlati
Esempio ( Come utilizzare questo esempio )
addCallback(). La nuova funzione solleva un'eccezione affinché il codice JavaScript in esecuzione nel browser possa rilevarla. Questo esempio contiene anche un'istruzione try..catch che intercetta le eventuali eccezioni generate dal browser quando viene chiamata la funzione throwit().
package
{
import flash.external.*
import flash.net.*;
import flash.display.*;
import flash.system.System;
public class ext_test extends Sprite {
function ext_test():void {
ExternalInterface.marshallExceptions = true;
ExternalInterface.addCallback("g", g);
try {
ExternalInterface.call("throwit");
} catch(e:Error) {
trace(e)
}
}
function g() { throw new Error("exception from actionscript!!!!") }
}
}
objectID | proprietà |
objectID:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Restituisce l'attributo id del tag object in Internet Explorer o l'attributo name del tag embed in Netscape.
Implementazione
public static function get objectID():StringAltri esempi
addCallback | () | metodo |
public static function addCallback(functionName:String, closure:Function):void| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Registra un metodo ActionScript come metodo chiamabile dal contenitore. Dopo una chiamata riuscita a addCallBack(), la funzione registrata nel lettore può essere chiamata dal codice JavaScript o ActiveX nel contenitore.
Nota: per il contenuto locale eseguito in un browser, le chiamate al metodo ExternalInterface.addCallback() funzionano solo se il file SWF e la pagina Web che lo contiene sono nella sandbox locale attendibile (local-trusted). Per ulteriori informazioni, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .
Parametri
functionName:String — Il nome con cui il contenitore può richiamare la funzione.
| |
closure:Function — La chiusura di funzione da richiamare. Può trattarsi di una funzione autonoma o della chiusura di un metodo che fa riferimento a un metodo di un'istanza di un oggetto. Passando la chiusura di un metodo, potete indirizzare il callback a un metodo di una determinata istanza di un oggetto.
Nota: una chiamata ripetuta a |
Genera
Error — Il contenitore non supporta le chiamate in entrata. Le chiamate in entrata sono supportate solo in Internet Explorer per Windows e nei browser che utilizzano l'API NPRuntime come Mozilla 1.7.5 e versioni successive o Firefox 1.0 e versioni successive.
| |
SecurityError — Una funzione callback con il nome specificato è già stata aggiunta da ActionScript a una sandbox a cui non potete accedere; non potete sovrascrivere tale funzione callback. Per risolvere questo problema, riscrivete il codice ActionScript che ha chiamato in origine il metodo addCallback(), in modo che chiami anche il metodo Security.allowDomain().
| |
SecurityError — L'ambiente contenitore appartiene a una funzione di sicurezza sandbox a cui il codice chiamante non può accedere. Per risolvere questo problema, procedete nel modo seguente:
|
Altri esempi
Elementi API correlati
call | () | metodo |
public static function call(functionName:String, ... arguments):*| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Chiama una funzione esposta dal contenitore SWF, che passa zero o più argomenti. Se la funzione non è disponibile, la chiamata restituisce null; in caso contrario, restituisce il valore fornito dalla funzione. La ricorsività non è consentita nei browser Opera o Netscape; su questi browser una chiamata ricorsiva genera una risposta null. La ricorsività è supportata nei browser Internet Explorer e Firefox.
Se il contenitore è una pagina HTML, questo metodo richiama una funzione JavaScript in un elemento script.
Se il contenitore è un altro contenitore ActiveX, questo metodo invia l'evento ActiveX FlashCall con il nome specificato e il contenitore elabora l'evento.
Se nel contenitore risiede il plug-in di Netscape, è possibile creare un supporto personalizzato per la nuova interfaccia NPRuntime o inserire un controllo HTML e incorporarvi il lettore. Se si inserisce un controllo HTML, è possibile comunicare con il lettore tramite un'interfaccia JavaScript per l'applicazione nativa del contenitore.
Nota: per il contenuto locale eseguito in un browser, le chiamate al metodo ExternalInterface.call() sono consentite solo se il file SWF e la pagina Web che lo contiene (se esiste) sono nella sandbox locale attendibile (local-trusted). È inoltre possibile impedire a un file SWF di utilizzare questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML in cui è presente il contenuto SWF. Per ulteriori informazioni, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .
Nota per le applicazioni Flash Player: in Flash Player 10 e Flash Player 9 Aggiornamento 5, alcuni browser Web limitano questo metodo se è abilitato il blocco dei pop-up. In tali casi, potete chiamare questo metodo solo in risposta a un evento utente (ad esempio, in un gestore di eventi per un clic del mouse o la pressione di un tasto).
Parametri
functionName:String — Il nome alfanumerico della funzione da chiamare nel contenitore. L'uso di un nome funzione non alfanumerico provoca un errore di runtime (errore 2155). Potete utilizzare un blocco try..catch per gestire l'errore.
| |
... arguments — Gli argomenti da passare alla funzione all'interno del contenitore. È possibile specificare zero o più parametri, separandoli mediante virgole. I parametri possono appartenere a qualunque tipo di dati ActionScript. Quando la chiamata è rivolta a una funzione JavaScript, i tipi ActionScript vengono automaticamente convertiti in tipi JavaScript; quando la chiamata viene rivolta a un altro contenitore ActiveX, i parametri vengono codificati nel messaggio di richiesta.
|
* — La risposta ricevuta dal contenitore. Se la chiamata dà esito negativo, ad esempio, se nel contenitore non è presente la funzione, se l'interfaccia non è disponibile, se si verifica una ricorsività (con un browser Netscape o Opera) o un problema di sicurezza, viene restituito il valore null e viene generato un errore.
|
Genera
Error — Il contenitore non supporta le chiamate in uscita. Le chiamate in uscita sono supportate solo in Internet Explorer per Windows e nei browser che utilizzano l'API NPRuntime come Mozilla 1.7.5 e versioni successive o Firefox 1.0 e versioni successive.
| |
SecurityError — L'ambiente contenitore appartiene a una funzione di sicurezza sandbox a cui il codice chiamante non può accedere. Per risolvere questo problema, procedete nel modo seguente:
|
Altri esempi
Chiamate al codice esterno da ActionScript
Controllo dell’accesso agli URL in uscita
Esempio ( Come utilizzare questo esempio )
//
// Requires:
// - A Flash Professional Label component on the Stage with an instance name of "lbl".
// - A Flash Professional Button component on the Stage with an instance name of "button".
//
var xmlResponse:String = "<invoke name=\"isReady\" returntype=\"xml\"><arguments><number>1</number><number>" + stage.stageWidth + "</number><number>" + stage.stageHeight + "</number></arguments></invoke>";
lbl.text = "ExternalInterface.available: " + ExternalInterface.available;
lbl.width = 200;
button.enabled = ExternalInterface.available;
button.addEventListener(MouseEvent.CLICK, button_click);
function button_click(evt:MouseEvent):void {
ExternalInterface.call("alert", xmlResponse);
}
package {
import flash.display.Sprite;
import flash.events.*;
import flash.external.ExternalInterface;
import flash.text.TextField;
import flash.utils.Timer;
import flash.text.TextFieldType;
import flash.text.TextFieldAutoSize;
import flash.system.Security;
public class ExternalInterfaceExample extends Sprite
{
private var input:TextField;
private var output:TextField;
private var sendBtn:Sprite;
public function ExternalInterfaceExample()
{
// constructor code
Security.allowDomain("*");
input = new TextField();
input.type = TextFieldType.INPUT;
input.background = true;
input.border = true;
input.width = 350;
input.height = 18;
addChild(input);
sendBtn = new Sprite();
sendBtn.mouseEnabled = true;
sendBtn.x = input.width + 10;
sendBtn.graphics.beginFill(0xcccccc);
sendBtn.graphics.drawRoundRect(0, 0, 80, 18, 10, 10);
sendBtn.graphics.endFill();
sendBtn.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(sendBtn);
output = new TextField();
output.y = 25;
output.width = 450;
output.height = 325;
output.multiline = true;
output.wordWrap = true;
output.border = true;
output.text = "Initializing...\n";
addChild(output);
if (ExternalInterface.available) {
try {
output.appendText("Adding callback...\n");
ExternalInterface.addCallback("sendToActionScript", receivedFromJavaScript);
if (checkJavaScriptReady()) {
output.appendText("JavaScript is ready.\n");
} else {
output.appendText("JavaScript is not ready, creating timer.\n");
var readyTimer:Timer = new Timer(100, 0);
readyTimer.addEventListener(TimerEvent.TIMER, timerHandler);
readyTimer.start();
}
} catch (error:SecurityError) {
output.appendText("A SecurityError occurred: " + error.message + "\n");
} catch (error:Error) {
output.appendText("An Error occurred: " + error.message + "\n");
}
} else {
output.appendText("External interface is not available for this container.");
}
}
private function receivedFromJavaScript(value:String):void {
output.appendText("JavaScript says: " + value + "\n");
}
private function checkJavaScriptReady():Boolean {
var isReady:Boolean = ExternalInterface.call("isReady");
return isReady;
}
private function timerHandler(event:TimerEvent):void {
output.appendText("Checking JavaScript status...\n");
var isReady:Boolean = checkJavaScriptReady();
if (isReady) {
output.appendText("JavaScript is ready.\n");
output.appendText("ExternalInterface.objectID = " + ExternalInterface.objectID + "\n");
Timer(event.target).stop();
}
}
private function clickHandler(event:MouseEvent):void {
if (ExternalInterface.available) {
ExternalInterface.call("sendToJavaScript", input.text);
}
}
}
}
<!-- saved from url=(0014)about:internet -->
<html lang="en">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>ExternalInterfaceExample</title>
<script language="JavaScript">
var jsReady = false;
function isReady() {
return jsReady;
}
function pageInit() {
jsReady = true;
document.forms["form1"].output.value += "\n" + "JavaScript is ready.\n";
}
function sendToActionScript(value) {
document.getElementById("ExternalInterfaceExample").sendToActionScript(value);
}
function sendToJavaScript(value) {
document.forms["form1"].output.value += "ActionScript says: " + value + "\n";
}
</script>
</head>
<body onload="pageInit();">
<object id="ExternalInterfaceExample" name="ExternalInterfaceExample"
type="application/x-shockwave-flash" data="ExternalInterfaceExample.swf" width="550" height="400">
<param name="movie" value="ExternalInterfaceExample.swf"/>
<param name="quality" value="high"/>
<param name="allowscriptaccess" value="always"/>
<a href="http://www.adobe.com/go/getflash">
<img src="http://www.adobe.com/images/shared/download_buttons/get_flash_player.gif" alt="Get Adobe Flash player"/>
</a>
</object>
<form name="form1" onsubmit="return false;">
<input type="text" name="input" value="" />
<input type="button" value="Send" onclick="sendToActionScript(this.form.input.value);" /><br />
<textarea cols="60" rows="20" name="output" readonly="true">Initializing...</textarea>
</form>
</body>
</html>
Tue Jun 12 2018, 02:44 PM Z