Clipboard  - AS3

Un array di stringhe contenente i nomi di tutti i formati dati disponibili in questo oggetto Clipboard.

Le costanti di stringa relative ai nomi dei formati standard sono definite nella classe ClipboardFormats. Per trasferire i dati come oggetto, potete usare anche altre stringhe, definite dall'applicazione, come nomi di formato.

Elementi API correlati

 var availableFormats:Array = Clipboard.generalClipboard.formats;

Gli Appunti del sistema operativo.

Tutti di dati incollati negli Appunti del sistema operativo sono accessibili da altre applicazioni. Tali dati possono includere codice remoto non protetto in esecuzione su un browser web.

Nota: nelle applicazioni Flash Player 10, un'operazione Incolla dagli Appunti richiede prima un evento utente (una scorciatoia da tastiera per il comando Incolla o un clic del mouse sul comando Incolla del menu di scelta rapida). Clipboard.getData() restituisce il contenuto degli Appunti solo se InteractiveObject ha ricevuto e agisce su un evento incolla. La chiamata a Clipboard.getData() avrà esito negativo in qualsiasi altra circostanza. La stessa limitazione vale in AIR per i contenuti al di fuori della sandbox di sicurezza dell'applicazione.

L'oggetto generalClipboard viene creato automaticamente. Non potete assegnare un'altra istanza dell'oggetto Clipboard a questa proprietà. In alternativa potete usare i metodi getData() e setData() per leggere e scrivere dati sull'oggetto esistente.

Ricordate di cancellare sempre gli Appunti prima di scrivere nuovi dati, per fare in modo che i vecchi dati in tutti i formati vengano eliminati.

L'oggetto generalClipboard non può essere passato a NativeDragManager di AIR. Create un nuovo oggetto Clipboard per le operazioni "trascina e rilascia" native di un'applicazione AIR.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Indica se il formato Appunti di promessa file è supportato nel sistema client.

Crea un oggetto Clipboard vuoto.

Gli oggetti Clipboard contengono i dati dei gesti "trascina e rilascia" in Adobe AIR. Possono essere utilizzati per un solo gesto "trascina e rilascia" e non possono essere riutilizzati.

Non create un oggetto Clipboard per le operazioni "copia e incolla". Utilizzate invece l'oggetto singolo Clipboard.generalClipboard a questo scopo.

Elementi API correlati

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Elimina tutte le rappresentazioni di dati da questo oggetto Clipboard.

 Clipboard.generalClipboard.clear();

Elimina la rappresentazione di dati per il formato specificato.

Parametri

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Ottiene i dati degli Appunti se sono presenti dati nel formato specificato.

Flash Player richiede una chiamata al metodo getData() in un gestore dell'evento paste. In AIR questa limitazione si applica solo al contenuto al di fuori della sandbox dell'applicazione.

Quando si accede a un formato dati standard, i dati vengono restituiti come un nuovo oggetto del tipo di dati Flash corrispondente.

Quando viene effettuato l'accesso a un formato definito dall'applicazione, il valore del parametro transferMode determina se viene restituito un riferimento all'oggetto originale o un oggetto anonimo contenente una copia serializzata dell'oggetto originale. Se viene specificata la modalità originalPreferred o clonePreferred, Flash Player o AIR restituisce la versione alternativa se quella preferenziale non è disponibile. Se viene specificata la modalità originalOnly o cloneOnly, Flash Player o AIR restituisce il valore null quando la versione richiesta non è disponibile.

Parametri

Elementi API correlati

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Controlla se i dati nel formato specificato esistono in questo oggetto Clipboard.

Utilizzate le costanti nella classe ClipboardFormats per fare riferimento ai nomi di formato standard.

Parametri

Elementi API correlati

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Aggiunge una rappresentazione delle informazioni da trasferire nel formato dati specificato.

Nella sandbox dell'applicazione Adobe AIR, potete chiamare setData() in qualsiasi momento. In altri contesti, setData() può essere chiamato solo in risposta a un evento generato dall'utente, ad esempio la pressione di un tasto o il clic del mouse.

Potete inserire negli Appunti più rappresentazioni delle stesse informazioni in formati differenti, per incrementare le possibilità che altre applicazioni o altri componenti possano utilizzare tali dati. Un'immagine può essere inserita, ad esempio, sotto forma di dati bitmap per essere utilizzata da applicazioni di elaborazione immagini, come un URL e come file PNG codificato per il trasferimento al file system nativo.

Il parametro data deve corrispondere al tipo di dati appropriato per il formato specificato:

I nomi in formato personalizzato non possono iniziare con "air:" o "flash:". Per evitare conflitti tra i nomi quando si usano i formati personalizzati, potete utilizzare l'ID dell'applicazione o un nome di pacchetto come prefisso del formato, ad esempio, "com.example.applicationName.dataPacket".

Durante i trasferimenti tra applicazioni o al loro interno, il parametro serializable determina se saranno disponibili sia un riferimento che una copia dell'oggetto o se sarà disponibile solo un riferimento. Impostate serializable su true per rendere disponibili sia il riferimento che la copia dell'oggetto dati. Impostate serializable su false per rendere disponibile solo il riferimento all'oggetto. I riferimenti agli oggetti sono validi esclusivamente all'interno dell'applicazione corrente, di conseguenza, se impostate serializable su false, i dati in tale formato non sono disponibili in altre applicazioni Flash Player o AIR. Un componente può scegliere se richiamare il riferimento o la copia di un oggetto impostando la modalità di trasferimento negli Appunti appropriata quando accede ai dati di tale formato.

Nota: i formati standard vengono sempre convertiti in formati nativi nel momento in cui i dati vengono incollati o trascinati fuori da un'applicazione supportata, di conseguenza, il valore del parametro serializable non influisce sulla disponibilità dei dati nei formati standard in applicazioni non basate su Flash.

Per differire il rendering dei dati per un formato, utilizzate invece il metodo setDataHandler(). Se per aggiungere una rappresentazione dei dati con lo stesso nome di formato viene utilizzato sia il metodo setData() che il metodo setDataHandler(), la funzione del gestore non verrà mai chiamata.

Nota: in Mac OS, quando impostate il parametro format su ClipboardFormats.URL_FORMAT, l'URL viene trasferito solo se è un URL valido. In caso contrario, l'oggetto Clipboard viene svuotato e la chiamata a getData() restituisce null.

Parametri

Elementi API correlati

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Aggiunge un riferimento alla funzione del gestore che produce i dati da trasferire.

Utilizzate una funzione del gestore per differire la creazione o il rendering dei dati fino a quando non vi si accede.

La funzione del gestore deve restituire il tipo di dati appropriato per il formato specificato:

La funzione del gestore viene chiamata solo se i dati nel formato specificato vengono letti. Notate che in alcuni casi il sistema operativo chiama la funzione prima che si verifichi un evento drop. Quando utilizzate, ad esempio, una funzione del gestore per fornire i dati di un file trascinato da un’applicazione AIR nel file system, il sistema operativo chiama la funzione del gestore di dati non appena l’operazione di trascinamento viene completata nell’applicazione AIR. Ciò causa solitamente una pausa indesiderabile durante lo scaricamento o la creazione dei dati del file. A questo scopo, potete utilizzare invece URLFilePromise.

Tenete presente che, se l'applicazione utilizzata non provvede a proteggere i dati, i dati sottostanti possono cambiare dal momento in cui il gestore viene aggiunto al momento in cui i dati vengono letti. Il comportamento che si verifica quando non è garantito che i dati negli Appunti rappresentati da una funzione del gestore vengano letti più di una volta. Gli Appunti potrebbero restituire i dati generati dalla prima chiamata alla funzione o chiamare di nuovo la funzione. Non basatevi su l'uno o l'altro comportamento.

Nella sandbox dell'applicazione Adobe AIR, potete chiamare setDataHandler() in qualsiasi momento. In altri contesti, setDataHandler() può essere chiamato solo in risposta a un evento generato dall'utente, ad esempio la pressione di un tasto o il clic del mouse.

Per aggiungere dati direttamente a questo oggetto Clipboard, potete invece utilizzare il metodo setData(). Se sia il metodo setData() che il metodo setDataHandler() vengono chiamati con lo stesso nome di formato, la funzione del gestore non viene mai chiamata.

Nota: in Mac OS, quando impostate il parametro format su ClipboardFormats.URL_FORMAT, l'URL viene trasferito solo se la funzione del gestore restituisce un URL valido. In caso contrario, l'oggetto Clipboard viene svuotato e la chiamata a getData() restituisce null.

Parametri

Elementi API correlati

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Scrivete i dati, in questo caso una stringa, in Clipboard.generalClipboard.
2. Leggete il contenuto degli Appunti da Clipboard.generalClipboard.

Nota: a causa delle limitazioni di sicurezza per l'accesso ai dati degli Appunti, questo esempio non funziona in Flash Player. In Flash Player, potete chiamare solo il metodo getData() dell'oggetto Clipboard in un gestore dell'evento paste.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}