Création et gestion de programmes de travail

Utilisez la métabalise [Embed] pour intégrer le fichier swf de programme de travail dans le fichier swf principal sous forme d’objet ByteArray :

[Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")] 
private static var BgWorker_ByteClass:Class; 
private function createWorker():void 
{ 
    var workerBytes:ByteArray = new BgWorker_ByteClass(); 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

Le fichier swf de programme de travail est compilé dans le fichier swf principal sous forme de sous-classe ByteArray appelée BgWorker_ByteClass. Créez une occurrence de cette classe pour obtenir un objet ByteArray prérempli avec les octets du fichier swf de programme de travail.

Utilisez un objet URLLoader pour charger un fichier swf externe. Le fichier swf doit provenir du même domaine de sécurité ; il peut s’agir, par exemple, d’un fichier swf chargé depuis le même domaine Internet que le fichier swf principal ou inclus dans le package d’une application AIR.

var workerLoader:URLLoader = new URLLoader(); 
workerLoader.dataFormat = URLLoaderDataFormat.BINARY; 
workerLoader.addEventListener(Event.COMPLETE, loadComplete); 
workerLoader.load(new URLRequest("BgWorker.swf")); 
 
private function loadComplete(event:Event):void 
{ 
    // create the background worker 
    var workerBytes:ByteArray = event.target.data as ByteArray; 
    var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes); 
     
    // ... set up worker communication and start the worker 
}

Une fois que l’objet URLLoader termine le chargement du fichier swf, les octets du fichier swf sont disponibles dans la propriété data de l’objet URLLoader ( event.target.data dans l’exemple).

Vous pouvez utiliser un seul fichier swf comme fichier swf principal et fichier swf de programme de travail. Utilisez la propriété loaderInfo.bytes de la classe d’affichage principale pour accéder aux octets du fichier swf.

// The primordial worker's main class constructor 
public function PrimordialWorkerClass() 
{ 
    init(); 
} 
 
private function init():void 
{ 
    var swfBytes:ByteArray = this.loaderInfo.bytes; 
     
    // Check to see if this is the primordial worker or the background worker 
    if (Worker.current.isPrimordial) 
    { 
        // create a background worker 
        var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes); 
         
        // ... set up worker communication and start the worker 
    } 
    else // entry point for the background worker 
    { 
        // set up communication between workers using getSharedProperty() 
        // ... (not shown) 
         
        // start the background work 
    } 
}

Si vous utilisez cette technique, faites appel à une déclaration if pour relier le code du fichier swf au sein du constructeur de la classe principale ou d’une méthode qu’il appelle. Pour déterminer si le code s’exécute dans le programme de travail principal ou dans le programme de travail en arrière-plan, vérifiez la propriété isPrimordial de l’objet Worker actuel, comme indiqué dans l’exemple.