CameraRoll  - AS3

Déterminez si l’application a été autorisée à accéder à la pellicule.

Eléments de l’API associés

Indique si la méthode CameraRoll.addBitmapData() est prise en charge. Actuellement, cette fonction est uniquement prise en charge dans les applications AIR sur des périphériques mobiles.

Indique si la méthode CameraRoll.browseForImage() est prise en charge. Actuellement, cette fonction est uniquement prise en charge dans les applications AIR sur des périphériques mobiles.

Crée un objet CameraRoll.

Une seule bibliothèque multimédia est prise en charge par ActionScript. Tous les objets CameraRoll sont enregistrés dans le même référentiel d’images.

Ajoute une image au dossier Pellicule du périphérique.

Pour savoir si votre application prend en charge la méthode CameraRoll.addBitmapData() à l’exécution, vérifiez la propriété CameraRoll.supportsAddBitmapData.

Paramètres

Ouvre une boîte de dialogue d’explorateur d’images pour que l’utilisateur puisse sélectionner une image existante du dossier Pellicule du périphérique.

Lorsque l’utilisateur sélectionne une image, cette occurrence de CameraRoll distribue un événement select contenant un objet MediaEvent. Utilisez la propriété data de l’objet MediaEvent pour charger l’image. La propriété data est un objet MediaPromise que vous pouvez charger à l’aide de la méthode loadFilePromise() de la classe Loader. Notez que l’objet MediaPromise contient un objet de fichier valide sur certaines plates-formes (Blackberry Tablet OS), mais pas sur d’autres (iOS et Android). Lorsque vous utilisez la méthode loadFilePromise(), l’image est chargée correctement sur toutes les plates-formes. Pour accéder aux données brutes à partir de l’objet multimédia, vous pouvez ouvrir la source de données fournie par le média promis et lire les données à l’aide des méthodes de l’interface IDataInput.

Pour savoir si votre application prend en charge la méthode CameraRoll.browseForImage() à l’exécution, vérifiez la propriété CameraRoll.supportsBrowseForImage.

Sur iOS (et uniquement sur l’iPad) vous pouvez demander une taille spécifique pour la boîte de dialogue de l’explorateur d’images. Vous pouvez également spécifier une zone de l’écran que vous ne souhaitez pas que la boîte de dialogue de l’explorateur d’images couvre. Cette demande ne fonctionne que sur l’iPad, car sur ce périphérique l’explorateur d’images n’occupe pas la totalité de l’écran.

Pour demander des options de taille et de positionnement de l’explorateur d’images (iPad), transmettez un objet CameraRollBrowseOptions à la méthode browseForImage(). Si aucun paramètre n’est spécifié, cette méthode place la boîte de dialogue dans le coin supérieur gauche de l’écran à l’aide des paramètres système par défaut des dimensions de la boîte de dialogue.

Paramètres

Informations complémentaires

Eléments de l’API associés

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Demande l’autorisation d’accès à la bibliothèque multimédia du système ou au dossier Pellicule.

Distribué lorsqu’un utilisateur annule une opération de recherche d’image sans sélectionner d’image.

Les propriétés de cet événement sont les suivantes :

Indique qu’une opération addBitmapData() a été correctement effectuée.

Les propriétés de cet événement sont les suivantes :

L’événement error est distribué lorsqu’une erreur se produit.

Les sources d’erreurs sont les suivantes :

• Il est impossible d’ouvrir un explorateur d’images.
• Un explorateur d’images est en cours d’utilisation.
• L’application AIR tente de rechercher une image alors qu’elle se trouve dans l’arrière-plan.
• Il est impossible d’ajouter une image à la bibliothèque multimédia.
• Une méthode est appelée qui n’est pas prise en charge sur le périphérique.
• L’application AIR tente de charger une image distante sans connexion Internet.

Les propriétés de cet événement sont les suivantes :

Distribué lorsque l’application demande l’autorisation d’accéder à la pellicule. Vérifiez la valeur de la propriété status pour déterminer si l’autorisation a été accordée ou refusée.

Eléments de l’API associés

Distribué lorsqu’un utilisateur sélectionne une image de la bibliothèque multimédia du périphérique.

L’objet MediaEvent distribué pour cet événement permet d’accéder au fichier multimédia choisi.

Définit la valeur de la propriété type d’un objet d’événement MediaEvent. Les propriétés de cet événement sont les suivantes :