File  - AS3

Dossier contenant les fichiers installés de l’application.

La propriété url de cet objet utilise le modèle d’URL app (pas le modèle d’URL file). Cela signifie que la chaîne url est spécifiée en commençant par "app:" (pas par "file:"). De même, si vous créez un objet File relatif au répertoire File.applicationDirectory (en utilisant la méthode resolvePath()), la propriété url de l’objet File utilise également le modèle d’URL app.

Remarque : vous ne pouvez pas écrire dans des fichiers ou des répertoires dont le chemin utilise le modèle d’URL app:. Vous ne pouvez pas non plus supprimer ni créer des fichiers ou des dossiers dont le chemin utilise le modèle d’URL app:. Pour des raisons de sécurité, il n’est pas conseillé de modifier le contenu du répertoire de l’application ; ce contenu est bloqué sur les systèmes d’exploitation de certaines plates-formes. Pour stocker des données spécifiques à l’application, pensez à utiliser son répertoire de stockage (File.applicationStorageDirectory). Si vous souhaitez qu’une partie du contenu du répertoire de stockage de l’application ait accès aux fonctionnalités de l’application (les API AIR), vous pouvez exposer cette fonctionnalité à l’aide d’un pont de sandbox.

La propriété applicationDirectory permet de référencer le répertoire de l’application de façon à ce qu’il fonctionne sur toutes les plateformes. Si vous définissez un objet File pour référencer le répertoire de l’application à l’aide de la propriété nativePath ou url, il ne fonctionne que sur la plateforme pour laquelle ce chemin est valide.

Sur Android, la propriété nativePath, d’un objet File pointant vers le répertoire de l’application est une chaîne vide. Utilisez la propriété url pour accéder aux fichiers d’application.

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

Répertoire de stockage privé de l’application.

Chaque application AIR possède un répertoire de stockage permanent et unique créé lors du premier accès à File.applicationStorageDirectory. Ce répertoire est propre à chaque application et utilisateur. Ce répertoire est très pratique pour stocker les données propres à l’utilisateur ou à l’application.

Lors de la désinstallation d’une application AIR, le programme de désinstallation peut supprimer le répertoire de stockage de l’application et ses fichiers ou les conserver, selon la plate-forme.

La propriété url de cet objet utilise le modèle d’URL app-storage (pas le modèle d’URL file). Cela signifie que la chaîne url est spécifiée en commençant par "app-storage:" (pas par "file:"). De même, si vous créez un objet File relatif au répertoire File.applicationStoreDirectory (en utilisant la méthode resolvePath()), l’url de l’objet File utilise également le modèle d’URL app-storage (comme dans l’exemple).

La propriété applicationStorageDirectory permet de référencer le répertoire de stockage de l’application de façon à ce qu’il fonctionne sur toutes les plateformes. Si vous définissez un objet File pour référencer le répertoire de stockage de l’application à l’aide de la propriété nativePath ou url, il ne fonctionne que sur la plateforme pour laquelle ce chemin est valide.

Remarque (Mac OS uniquement) : pour répondre aux exigences de l’App Store, l’emplacement physique de ce répertoire a changé entre AIR 3.2 et AIR 3.3:

• Espace de noms 3.2 et versions antérieures : ~/Bibliothèque/Préférences/appid/Local Store/
• Espace de noms 3.3 et versions ultérieures : chemin/Bibliothèque/Application Support/appid/Local Store/, où chemin est soit ~/Bibliothèque/Containers/bundle-id/Data (environnement de sandbox), soit ~ (exécution en dehors de l’environnement de sandbox)

Plus d’exemples

Informations complémentaires

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Répertoire de cache de l’application.

La propriété cacheDirectory permet de se référer au répertoire de cache. Votre application devrait utiliser le répertoire de cache pour y stocker les fichiers téléchargés depuis un serveur ou qu’il est possible de générer à nouveau. Par exemple, vous devriez placer dans le répertoire de cache les fichiers de cache de base de données et le contenu téléchargeable utilisé dans les applications de magazines, de journaux et de cartes.

Si vous configurez un fichier File de sorte qu’il fasse référence au répertoire de cache à l’aide de la propriété nativePath ou url, il ne fonctionne que sur les plates-formes où ce chemin est valide.

Si un système d’exploitation ne prend pas en charge les répertoires de cache, cacheDirectory est défini sur null.

Informations complémentaires

Répertoire Bureau de l’utilisateur.

La propriété desktopDirectory permet de référencer le répertoire Bureau de façon à ce qu’il fonctionne sur toutes les plateformes. Si vous définissez un objet File pour référencer le répertoire Bureau à l’aide de la propriété nativePath ou url, il ne fonctionne que sur la plateforme pour laquelle ce chemin est valide.

Si un système d’exploitation ne prend pas en charge un répertoire du bureau, un répertoire du système de fichiers est utilisé à la place.

Les périphériques AIR pour TV n’ont aucun concept d’un répertoire du bureau de l’utilisateur. Par conséquent, la propriété desktopDirectory fait référence au même emplacement de répertoire que la propriété File.userDirectory . Le répertoire de l’utilisateur est propre à l’application.

Plus d’exemples

Informations complémentaires

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Répertoire documents de l’utilisateur.

Sous Windows, il s’agit du répertoire Mes documents (par exemple C:\Documents and Settings\nomUtilisateur\Mes documents). Sous Mac OS, l’emplacement par défaut est le suivant : /Utilisateurs/nomUtilisateur/Documents. Sous Linux, l’emplacement par défaut est le suivant : /home/nomUtilisateur/Documents (système anglais) et la propriété tient compte du paramètre xdg-user-dirs.

La propriété documentsDirectory permet de référencer le répertoire documents de façon à ce qu’il fonctionne sur toutes les plateformes. Si vous définissez un objet File pour référencer le répertoire documents à l’aide de la propriété nativePath ou url, il ne fonctionne que sur la plateforme pour laquelle ce chemin est valide.

Si un système d’exploitation ne prend pas en charge un répertoire de documents, un répertoire du système de fichiers est utilisé à la place.

Les périphériques AIR pour TV n’ont aucun concept d’un répertoire de documents de l’utilisateur. Par conséquent, la propriété documentsDirectory fait référence au même emplacement de répertoire que la propriété File.userDirectory. Le répertoire de l’utilisateur est propre à l’application.

Plus d’exemples

Informations complémentaires

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Indique si le fichier ou le répertoire référencé a été téléchargé (depuis Internet) ou non.

Cette propriété est utile uniquement sur les systèmes d’exploitation dans lesquels les fichiers peuvent être marqués comme téléchargés :

• Windows XP Service Pack 2 et versions ultérieures, et Windows Vista
• Mac OS 10.5 et versions ultérieures

Sur les systèmes qui ne marquent pas les fichiers comme téléchargés, tels que Linux, cette propriété n’est pas utile (et est définie sur false).

Eléments de l’API associés

Indique si le fichier ou le répertoire référencé existe. La valeur est true si l’objet File pointe vers un fichier ou répertoire existant et false dans le cas contraire.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Objet Icon contenant les icônes définies pour le fichier. Un objet Icon est un tableau d’objets BitmapData correspondant aux différents états des icônes. Sous Linux, l’objet Icon ne contient aucune icône. Sur Android, la propriété icon est null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Indique si la référence pointe vers un répertoire. La valeur est true si l’objet File pointe vers un répertoire ; false dans le cas contraire.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indique si le fichier ou le répertoire référencé est « masqué ». La valeur est true si le fichier ou le répertoire référencé est masqué, et false dans le cas contraire.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indique si le répertoire référencé est un package.

La valeur est true si le fichier ou le répertoire est un package, et false dans le cas contraire. Notez que la classe File ne permet pas de créer des packages directement.

• Sous Mac OS, les répertoires peuvent être désignés comme des packages et s’affichent dans le Finder sous la forme d’un seul fichier plutôt que sous la forme d’un répertoire. Cette propriété est définie sur true si le répertoire référencé est un package, et sur false si le fichier n’est pas un répertoire, n’existe pas ou n’est pas un package.
• Sous les autres systèmes d’exploitation, cette propriété est toujours définie sur false.

Plus d’exemples

Indique si la référence est un lien symbolique.

La valeur est true si l’objet File pointe vers un lien symbolique, et false dans le cas contraire. Notez que la classe File ne permet pas de créer des liens symboliques directement.

Les liens symboliques permettent à un fichier de pointer vers un autre fichier ou un répertoire du disque. Bien que similaires, les liens symboliques ne correspondent pas aux alias de Mac OS ni aux raccourcis de Windows. Un alias ou un raccourci est toujours signalé sous forme de fichier (plutôt que sous forme de répertoire) et la lecture ou l’écriture dans un alias ou un raccourci n’affecte jamais le fichier ou le répertoire original cible. En revanche, un lien symbolique se comporte généralement comme le fichier ou le répertoire vers lequel il pointe. Il peut être signalé comme un fichier ou un répertoire, et la lecture ou l’écriture dans un lien symbolique affecte le fichier ou le répertoire vers lequel il pointe, pas le lien symbolique lui-même. Notez toutefois que la suppression d’un lien symbolique supprime le lien mais pas la cible du lien.

Mac^® OS^®, Linux et Windows^® Vista^® prennent en charge les liens symboliques. De plus, sous Windows, la propriété isSymbolicLink d’un objet File référençant un point de jonction (utilisé dans le système de fichiers NTFS) est définie sur true.

Suite de caractères de fin de ligne utilisée par le système d’exploitation hôte.

Sous Mac OS et Linux, il s’agit du caractère de changement de ligne (code hexadécimal 0x0A). Sous Windows, il s’agit du caractère de retour chariot (code hexadécimal 0x0D) suivi du caractère de changement de ligne (code hexadécimal 0x0A).

Informations complémentaires

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Chemin complet dans la représentation du système d’exploitation hôte. Sous Mac OS et Linux, la barre oblique (/) est utilisée comme séparateur de chemin. Toutefois, sous Windows, vous pouvez définir la propriété nativePath en utilisant le caractère barre oblique ou barre oblique inverse (\) comme séparateur de chemin, et AIR remplace automatiquement la barre oblique par le caractère barre oblique inverse approprié.

Avant d’écrire du code en vue de définir la propriété nativePath directement, tenez compte du fait que cela peut impliquer l’utilisation de code spécifique à une application. Par exemple, un chemin natif tel que "C:\\Documents and Settings\\bob\\Desktop" n’est valable que sous Windows. Il est donc préférable d’utiliser les propriétés statiques suivantes, qui représentent les répertoires les plus fréquemment utilisés et qui sont valables sur toutes les plateformes :

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Vous pouvez utiliser la méthode resolvePath() pour obtenir un chemin relatif à ces répertoires.

Certaines API de Flex, telles que la propriété source de la classe SWFLoader utilisent une URL (la propriété url d’un objet File), et non un chemin natif (la propriété nativePath).

Plus d’exemples

Informations complémentaires

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Répertoire qui contient le fichier ou le répertoire référencé par cet objet File.

Si le fichier ou le répertoire n’existe pas, la propriété parent renvoie toujours l’objet File pointant vers le répertoire conteneur, même si ce dernier n’existe pas.

Cette propriété est identique à la valeur renvoyée par resolvePath("..") si ce n’est que le parent d’un répertoire racine est null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Déterminez si l’application a été autorisée à accéder au système de fichiers.

Eléments de l’API associés

Indique si le moteur d’exécution empêche la sauvegarde de l’objet fichier dans le cloud.

Si cette propriété est définie sur true, le fichier n’est pas automatiquement sauvegardé sur une plate-forme en ligne. La valeur par défaut de la propriété est false.

Informations complémentaires

Caractère de séparation des composants du chemin du système d’exploitation hôte.

Sous Mac OS et Linux, il s’agit de la barre oblique (/). Sous Windows, il s’agit du caractère barre oblique inversée (\).

Remarque : lorsque vous utilisez le caractère barre oblique inversée dans une chaîne littérale, pensez à taper le caractère à deux reprises (comme dans "directory\\file.ext"). Chaque paire de barres obliques inversées insérée dans une chaîne représentent une seule barre oblique inversée dans la chaîne.

Informations complémentaires

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Espace disponible pour cet emplacement File, en octets.

Si l’objet File fait référence à un répertoire, spaceAvailable désigne l’espace pouvant être utilisé par des fichiers dans le répertoire. Si l’objet File fait référence à un fichier, spaceAvailable désigne l’espace que le fichier peut occuper. Si l’emplacement du fichier n’existe pas, spaceAvailable est défini sur 0. Si l’objet File fait référence à un lien symbolique, spaceAvailable désigne l’espace disponible à l’emplacement vers lequel pointe le lien symbolique.

En général, l’espace disponible pour un répertoire ou un fichier correspond à l’espace disponible sur le volume contenant le répertoire ou le fichier. Toutefois, l’espace disponible peut tenir compte de quotas et de limites par répertoire.

L’ajout d’un fichier ou d’un répertoire dans un volume nécessite généralement plus d’espace que la taille réelle du fichier ou du contenu du répertoire. Par exemple, le système d’exploitation peut requérir davantage d’espace pour stocker les informations d’index. De même, les secteurs du disque requis peuvent utiliser un espace supplémentaire. Enfin, l’espace disponible change de façon dynamique. Vous ne pouvez donc pas envisager d’affecter tout l’espace signalé au stockage des fichiers.

Plus d’exemples

Codage par défaut utilisé par le système d’exploitation hôte.

Les valeurs possibles comprennent "windows-1252" "shift-jis", "cn-gb", "iso-8859-1", etc. Pour obtenir la liste complète, voir la section Jeux de caractères pris en charge.

Vous pouvez utiliser cette valeur lorsque vous utilisez les méthodes readMultiByte() et writeMultiByte() de la classe FileStream.

Informations complémentaires

Eléments de l’API associés

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

URL de ce chemin de fichier.

S’il s’agit d’une référence à un chemin dans le répertoire de stockage de l’application, le modèle d’URL est "app-storage" ; s’il s’agit d’une référence à un chemin dans le répertoire de l’application, le modèle d’URL est "app" ; autrement le modèle est "file".

Vous pouvez utiliser des caractères d’espace vide (au lieu de "%20") lorsque vous affectez une valeur à la propriété url ; AIR encode automatiquement les chaînes (par exemple conversion des espaces en "%20").

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Répertoire de l’utilisateur.

Sous Windows, il s’agit du parent du répertoire Mes documents (par exemple C:\Documents and Settings\nomUtilisateur). Sous Mac OS, il s’agit de /Utilisateurs/nomUtilisateur. Sous Linux, il s’agit de /home/nomUtilisateur.

La propriété userDirectory permet de référencer le répertoire de l’utilisateur de façon à ce qu’il fonctionne sur toutes les plateformes. Si vous définissez la propriété nativePath ou url d’un objet File directement, elle ne fonctionne que sur la plateforme pour laquelle ce chemin est valide.

Si un système d’exploitation ne prend pas en charge un répertoire de l’utilisateur, un répertoire du système de fichiers est utilisé à la place.

Sur les périphériques AIR pour TV, la propriété userDirectory fait référence à un répertoire de l’utilisateur propre à l’application.

Plus d’exemples

Informations complémentaires

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Fonction constructeur de la classe File.

Si vous transmettez un argument path, l’objet File pointe vers le chemin spécifié et les propriétés nativePath et url sont définies de manière à refléter ce chemin.

Bien que vous puissiez transmettre un argument path pour spécifier un chemin de fichier, cela peut impliquer l’utilisation de code spécifique à une plateforme. Par exemple, un chemin natif tel que "C:\\\\Documents and Settings\\bob\\Desktop" ou une URL telle que "file:///C:/Documents%20and%20Settings/bob/Desktop" n’est valable que sous Windows. Il est donc préférable d’utiliser les propriétés statiques suivantes, qui représentent les répertoires les plus fréquemment utilisés et qui sont valables sur toutes les plateformes :

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Vous pouvez alors utiliser la méthode resolvePath() pour obtenir un chemin relatif à ces répertoires. Par exemple, le code suivant définit un objet File de sorte qu’il pointe vers le fichier settings.xml du répertoire de stockage de l’application :

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Important : si vous transmettez une chaîne URL dans le paramètre path, l’URL est décodée pour résoudre le chemin du fichier. Par exemple, l’instruction new File("file:///c:/test/demo%20file%201%2e0.txt") crée un objet File avec le chemin natif "c:\test\demo file 1.0.txt". (Une URL utilise les préfixes file:, app: ou app-storage:.) Toutefois, en cas d’omission des préfixes d’URL corrects, la chaîne du chemin est traitée comme un chemin natif et aucun décodage n’est effectué. Vous devez tenir compte de ce comportement lors de la validation de chemins dérivés de sources potentiellement non approuvées. Si vous vous contentez de valider la chaîne d’entrée, le décodage de l’URL peut permettre à un attaquant d’échapper à vos contrôles de validation. Nous vous conseillons de toujours valider le chemin final de l’objet File instancié :

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Plus d’exemples

Eléments de l’API associés

Ouvre une boîte de dialogue permettant à l’utilisateur de sélectionner un répertoire. Lorsque l’utilisateur sélectionne le répertoire, l’événement select est distribué. La propriété target de l’événement select est l’objet File qui pointe vers le répertoire sélectionné.

La boîte de dialogue de sélection d’un répertoire n’est pas toujours affichée devant les fenêtres appartenant à une autre fenêtre (fenêtres dont la propriété owner n’est pas nulle). Pour éviter des problèmes de classement de fenêtres, masquez les fenêtres possédées avant d’appeler cette méthode.

Remarque : browseForDirectory() n’est pas prise en charge sur les périphériques Android. L’objet File distribue immédiatement un événement cancel.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Affiche la boîte de dialogue Ouvrir qui permet à l’utilisateur de sélectionner un fichier à ouvrir.

Lorsque l’utilisateur sélectionne le fichier, l’événement select est distribué. La propriété target de l’événement select est l’objet File qui pointe vers le fichier sélectionné.

La boîte de dialogue Ouvrir n’est pas toujours affichée devant les fenêtres appartenant à une autre fenêtre (fenêtres dont la propriété owner n’est pas nulle). Pour éviter des problèmes de classement de fenêtres, masquez les fenêtres possédées avant d’appeler cette méthode.

Remarque : il est impossible de définir le titre de la boîte de dialogue du fichier sur les périphériques Android. Le paramètre title est ignoré.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Affiche la boîte de dialogue Ouvrir qui permet à l’utilisateur de sélectionner un ou plusieurs fichiers à ouvrir.

Lorsque l’utilisateur sélectionne plusieurs fichiers, l’événement selectMultiple est distribué. La propriété target de l’événement select est cet objet File. Contrairement à browseForOpen(), avec la méthode browseForOpenMultiple(), cet objet File n’est pas mis à jour pour référencer l’un des fichiers choisis. A l’inverse, l’événement selectMultiple contient un tableau des fichiers choisis.

La boîte de dialogue Ouvrir n’est pas toujours affichée devant les fenêtres appartenant à une autre fenêtre (fenêtres dont la propriété owner n’est pas nulle). Pour éviter des problèmes de classement de fenêtres, masquez les fenêtres possédées avant d’appeler cette méthode.

Remarque : il est impossible de définir le titre de la boîte de dialogue du fichier sur les périphériques Android. Le paramètre title est ignoré.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Affiche la boîte de dialogue Enregistrer le fichier dans laquelle l’utilisateur peut sélectionner la destination du fichier.

Lorsque l’utilisateur sélectionne le fichier, l’événement select est distribué. La propriété target de l’événement select est l’objet File qui pointe vers la destination d’enregistrement sélectionnée.

La boîte de dialogue Enregistrer le fichier n’est pas toujours affichée devant les fenêtres appartenant à une autre fenêtre (fenêtres dont la propriété owner n’est pas nulle). Pour éviter des problèmes de classement de fenêtres, masquez les fenêtres possédées avant d’appeler cette méthode.

Remarque : il est impossible de définir le titre de la boîte de dialogue du fichier sur les périphériques Android. Le paramètre title est ignoré.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Annule toute opération asynchrone en attente.

Rend le chemin de l’objet File canonique.

Si l’objet File représente un fichier ou un répertoire existant, sa mise en forme canonique ajuste le chemin de sorte qu’il corresponde à la casse du nom réel du fichier ou du répertoire. Si l’objet File est un lien symbolique, sa mise en forme canonique ajuste le chemin de sorte qu’il corresponde au fichier ou au répertoire vers lequel pointe le lien, que ce fichier ou ce répertoire existe ou non. Sur les systèmes de fichiers sensibles à la casse (tels que Linux), lorsque plusieurs noms de fichier ne diffèrent que par la casse, la méthode canonicalize() ajuste le chemin de sorte qu’il corresponde au premier fichier détecté (dans l’ordre déterminé par le système de fichiers).

De plus, la mise en forme canonique convertit les noms de fichier courts en noms de fichier longs sous Windows.

Plus d’exemples

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Renvoie une copie de cet objet File. Les inscriptions d’événements ne sont pas copiées.

Remarque : cette méthode ne copie pas le fichier lui-même. Elle effectue simplement une copie de l’occurrence de l’objet File ActionScript. Pour copier un fichier, utilisez la méthode copyTo().

Copie le fichier ou le répertoire situé à l’emplacement spécifié par cet objet File à l’emplacement spécifié par le paramètre newLocation. Le processus de copie crée tous les répertoires parents requis (si possible). Lors du remplacement des fichiers à l’aide de copyTo(), les attributs des fichiers sont également remplacés.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Commence par copier le fichier ou le répertoire situé à l’emplacement spécifié par cet objet File à l’emplacement spécifié par le paramètre destination.

Lorsque l’opération est terminée, un événement complete (réussite) ou ioError (échec) est renvoyé. Le processus de copie crée tous les répertoires parent requis (si possible).

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Crée le répertoire spécifié et tous les répertoires parent nécessaires. Si le répertoire existe déjà, aucune action n’est effectuée.

Plus d’exemples

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Renvoie une référence à un nouveau répertoire temporaire. Il s’agit d’un nouveau répertoire dans le chemin de répertoire temporaire du système.

Cette méthode permet d’identifier un nouveau répertoire unique sans avoir à demander au système de vérifier qu’il est nouveau et unique.

Vous pouvez supprimer le répertoire temporaire avant de fermer l’application, puisqu’il n’est pas supprimé automatiquement sur certains périphériques.

Plus d’exemples

Eléments de l’API associés

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Renvoie une référence à un nouveau fichier temporaire. Il s’agit d’un nouveau fichier dans le chemin de répertoire temporaire du système.

Cette méthode permet d’identifier un nouveau fichier unique sans avoir à demander au système de vérifier que le fichier est nouveau et unique.

Vous pouvez supprimer le fichier temporaire avant de fermer l’application puisqu’il n’est pas supprimé automatiquement.

Plus d’exemples

Eléments de l’API associés

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Supprime le répertoire. Si ce fichier est un lien symbolique à un répertoire, seul le lien (et non le répertoire) est supprimé.

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Supprime le répertoire de façon asynchrone. Si ce fichier est un lien symbolique à un répertoire, seul le lien (et non le répertoire) est supprimé.

Paramètres

Eléments de l’API associés

Supprime le fichier. Si ce fichier est un lien symbolique, seul le lien (et non le fichier cible) est supprimé.

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Supprime le fichier de façon asynchrone. Si ce fichier est un lien symbolique, seul le lien (et non le fichier cible) est supprimé.

Eléments de l’API associés

Renvoie un tableau d’objets File correspondant aux fichiers et aux répertoires du répertoire représenté par cet objet File. Cette méthode n’explore pas le contenu des sous-répertoires.

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Récupère de façon asynchrone un tableau d’objets File correspondant au contenu du répertoire représenté par cet objet File.

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Recherche le chemin relatif entre deux chemins File.

Le chemin relatif est la liste des composants qui peuvent être ajoutés (résolus par) à cette référence pour localiser la seconde référence (paramètre). Le chemin relatif est renvoyé avec le caractère de séparation « / ».

Les chemins relatifs peuvent éventuellement contenir des références « .. », mais de tels chemins ne traversent pas les limites de volumes visibles.

Paramètres

Plus d’exemples

Renvoie un tableau d’objets File, indiquant les répertoires racine du système de fichiers.

Sous Windows, par exemple, il s’agit de la liste des volumes tels que les lecteurs C: et D:. Les lecteurs vides, tels que des lecteurs CD ou DVD, dans lesquels aucun disque n’était inséré ne sont pas inclus dans ce tableau. Sous Mac et Linux, cette méthode renvoie le répertoire racine unique de la machine (le répertoire « / »).

Sur les systèmes de fichiers pour lesquels la racine n’est plus lisible, notamment le système de fichiers d’Android, les propriétés de l’objet File renvoyé ne reflètent pas toujours la valeur true. Par exemple, sur Android, la propriété spaceAvailable indique 0.

Informations complémentaires

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Déplace le fichier ou le répertoire situé à l’emplacement spécifié par cet objet File vers l’emplacement spécifié par le paramètre destination.

Pour renommer un fichier, définissez le paramètre destination de sorte qu’il pointe vers un chemin situé dans le répertoire du fichier, mais avec un autre nom.

Le processus de déplacement crée tous les répertoires parent requis (si possible).

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Commence par déplacer le fichier ou le répertoire situé à l’emplacement spécifié par cet objet File vers l’emplacement spécifié par le paramètre newLocation.

Pour renommer un fichier, définissez le paramètre destination de sorte qu’il pointe vers un chemin situé dans le répertoire du fichier, mais avec un autre nom.

Le processus de déplacement crée tous les répertoires parent requis (si possible).

Paramètres

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Déplace un fichier ou un répertoire vers la corbeille.

Remarque : sur les systèmes d’exploitation qui ne prennent pas en charge le concept d’un dossier de corbeille récupérable, ces fichiers sont immédiatement supprimés.

Plus d’exemples

Eléments de l’API associés

Déplace un fichier ou un répertoire vers la corbeille de façon asynchrone.

Remarque : sur les systèmes d’exploitation qui ne prennent pas en charge le concept d’un dossier de corbeille récupérable, ces fichiers sont immédiatement supprimés.

Eléments de l’API associés

Ouvre le fichier dans l’application désignée par le système d’exploitation pour ouvrir ce type de fichier.

AIR vous empêche d’utiliser la méthode File.openWithDefaultApplication() pour ouvrir certains fichiers. Sous Windows, AIR vous empêche d’ouvrir les fichiers d’un certain type (fichiers avec des extensions spécifiques, répertoriées ci-dessous). Sous Mac OS et Linux, AIR vous empêche d’ouvrir les fichiers qui s’ouvrent dans des applications spécifiques, indiquées ci-dessous. Toute tentative d’ouvrir l’un de ces fichiers à l’aide de la méthode openWithDefaultApplication() renvoie une exception. Toutefois, les applications AIR installées avec un programme d’installation natif (applications dotées d’un profil étendu de bureau) ne sont pas soumises à ces limitations et peuvent ouvrir tous types de fichiers.

Vous ne pouvez pas ouvrir les documents à partir du répertoire de l’application.

Les tableaux ci-dessous répertorient les extensions de fichier qui ne sont pas autorisées sous Windows, ainsi que les applications non autorisées sous Mac OS et Linux :

Plus d’exemples

Eléments de l’API associés

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Demande l’autorisation d’accès au système de fichiers.

Crée un nouvel objet File avec un chemin relatif au chemin de cet objet File, en fonction du paramètre path (une chaîne).

Vous pouvez utiliser un chemin relatif ou absolu comme paramètre path.

Si vous spécifiez un chemin relatif, le paramètre path fourni est ajouté à la fin du chemin de l’objet File. Toutefois, l’utilisation de « .. » dans le paramètre path peut renvoyer un chemin résultant qui n’est pas un enfant de l’objet File. La référence résultante n’a pas besoin de faire référence à un emplacement réel du système de fichiers.

Si vous spécifiez une référence de fichier absolu, la méthode renvoie l’objet File pointant vers ce chemin. La référence de fichier absolu doit utiliser une syntaxe de chemin native valide pour le système d’exploitation de l’utilisateur (par exemple "C:\\test" sous Windows). N’utilisez pas d’URL (par exemple "file:///c:/test") comme paramètre path.

Tous les chemins résultants sont normalisés comme suit :

• Tout élément « . » est ignoré.
• Tout élément « .. » détruit son entrée parent.
• Aucune référence « .. » qui atteint la racine du système de fichiers ou la racine de stockage de l’application ne passe ce noeud ; elle est ignorée.

Veillez à toujours utiliser la barre oblique ( / ) comme séparateur de chemin. Sous Windows, vous pouvez également utiliser la barre oblique inverse (\), bien que cela ne soit pas recommandé. Si vous utilisez la barre oblique inverse, certaines applications risquent de ne pas fonctionner sur d’autres plates-formes.

Sous Linux, les noms de fichier et les noms de répertoire sont sensibles à la casse.

Paramètres

Plus d’exemples

Distribué lorsqu’une opération asynchrone en attente est annulée.

Les propriétés de cet événement sont les suivantes :

Distribué lorsqu’une opération asynchrone se termine.

Les propriétés de cet événement sont les suivantes :

Distribué lorsqu’une liste de répertoires est disponible après un appel à la méthode getDirectoryListingAsync().

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lorsqu’une erreur se produit au cours d’une opération de fichier asynchrone.

Les propriétés de cet événement sont les suivantes :

Distribué lorsque l’application demande l’autorisation d’accéder au système de fichiers. Vérifiez la valeur de la propriété status pour déterminer si l’autorisation a été accordée ou refusée.

Eléments de l’API associés

Distribué lorsqu’une opération viole une contrainte de sécurité.

Les propriétés de cet événement sont les suivantes :

Distribué lorsque l’utilisateur sélectionne un fichier ou un répertoire dans une boîte de dialogue de recherche de fichier ou de répertoire.

Les propriétés de cet événement sont les suivantes :

Distribué lorsque l’utilisateur sélectionne des fichiers dans la boîte de dialogue ouverte par un appel à la méthode browseForOpenMultiple().

Eléments de l’API associés