Clipboard  - AS3

Tableau de chaînes contenant les noms des formats de données disponibles dans cet objet Clipboard.

Les constantes de chaîne des noms des formats standard sont définies dans la classe ClipboardFormats. D’autres chaînes, définies par l’application, peuvent également être utilisées comme noms de format pour transférer les données sous forme d’objet.

Eléments de l’API associés

 var availableFormats:Array = Clipboard.generalClipboard.formats;

Presse-papiers du système d’exploitation.

Toutes les données collées dans le presse-papiers du système sont disponibles pour les autres applications. Cela peut comprendre le code distant non sécurisé s’exécutant dans un navigateur Web.

Remarque : dans les applications de Flash Player 10, une opération de collage à partir du presse-papiers implique tout d’abord un événement utilisateur (par exemple, utilisation du raccourci clavier de la commande Coller ou clic de souris sur la commande Coller d’un menu contextuel). Clipboard.getData() ne renvoie le contenu du presse-papiers que si InteractiveObject a reçu et exécute un événement coller. En aucun autre cas, l’appel à Clipboard.getData() ne peut échouer. La même restriction s’applique dans le contenu AIR qui se trouve en dehors du sandbox de l’application.

L’objet generalClipboard est créé automatiquement. Vous ne pouvez pas affecter une autre occurrence Clipboard à cette propriété. Vous pouvez par contre utiliser les méthodes getData() et setData() pour lire et écrire des données dans l’objet existant.

Il est toujours préférable d’effacer le presse-papiers avant d’y écrire de nouvelles données afin de s’assurer que les anciennes données de tous les formats sont effacées.

Il est impossible de transmettre l’objet generalClipboard à la classe NativeDragManager d’AIR. Créez un nouvel objet Clipboard pour les opérations de glisser-déposer natives dans une application AIR.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Indique si le format de Presse-papiers du fichier promis est pris en charge sur le système client.

Crée un objet Clipboard vide.

Créez des objets Clipboard permettant de contenir les données d’un mouvement de glisser-déposer natif dans Adobe AIR. Les objets Clipboard ne peuvent être utilisés que pour un seul mouvement de glisser-déposer. Il est impossible de les réutiliser.

Ne créez pas un objet Clipboard pour les opérations de copier-coller. Utilisez plutôt l’objet unique Clipboard.generalClipboard.

Eléments de l’API associés

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Supprime toutes les représentations de données dans cet objet Clipboard.

 Clipboard.generalClipboard.clear();

Supprime la représentation des données au format spécifié.

Paramètres

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Récupère les données du presse-papiers si elles sont présentes au format spécifié.

Avec Flash Player, la méthode getData() doit être appelée dans un gestionnaire d’événement paste. Dans AIR, cette restriction s’applique uniquement au contenu s’exécutant hors du sandbox de sécurité de l’application.

Lors d’un accès à un format de données standard, les données sont renvoyées sous forme de nouvel objet de type correspondant.

Lors d’un accès à un format défini par l’application, la valeur du paramètre transferMode détermine si une référence à l’objet original ou un objet anonyme contenant une copie sérialisée de l’objet original est renvoyé. Lorsqu’un mode originalPreferred ou clonePreferred est spécifié, Flash Player ou AIR renvoie l’autre version lorsque la version favorite n’est pas disponible. Lorsqu’un mode originalOnly ou cloneOnly est spécifié, Flash Player ou AIR renvoie null lorsque la version demandée n’est pas disponible.

Paramètres

Eléments de l’API associés

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Vérifie si des données sont présentes au format spécifié dans cet objet Clipboard.

Utilisez les constantes dans la classe ClipboardFormats pour référencer les noms de format standard.

Paramètres

Eléments de l’API associés

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Ajoute une représentation des informations à transférer dans le format de données spécifié.

Dans le sandbox de l’application d’Adobe AIR, setData() peut être appelée à tout moment. Dans d’autres contextes, setData() ne peut être appelée qu’en réponse à un événement généré par l’utilisateur, notamment lorsque celui-ci appuie sur une touche ou clique sur la souris.

Différentes représentations des mêmes informations peuvent être ajoutées au Presse-papiers dans divers formats. Ceci augmente la capacité des autres composants ou applications à exploiter les données disponibles. Par exemple, une image peut être ajoutée sous forme de données bitmap pour une utilisation dans des applications de retouche d’images, sous forme d’URL, et sous forme de fichier PNG codé pour un transfert vers le système de fichiers natif.

Le paramètre data doit être du type de données approprié pour le format spécifié :

Les noms de format personnalisé ne doivent pas commencer par « air: » ou « flash: ». Pour éviter les conflits de noms lorsque vous utilisez des formats personnalisés, vous pouvez utiliser l’ID de votre application ou un nom de package comme préfixe, par exemple « com.nomApplication.exemple.dataPacket ».

Dans le cas d’un transfert au sein d’une application ou entre applications, le paramètre serializable détermine si une référence et une copie doivent toutes deux être disponibles ou si seule une référence à un objet est disponible. Définissez serializable sur true pour que la référence et une copie de l’objet de données soient disponibles. Définissez serializable sur false pour que seule la référence de l’objet soit disponible. Les références d’objet n’étant valides que dans l’application en cours, le fait de définir serializable sur false implique également que les données de ce format ne soient pas disponibles pour les autres applications AIR ou Flash Player. Un composant peut choisir d’obtenir la référence ou la copie de l’objet en définissant le mode de transfert du presse-papiers approprié lors de l’accès aux données de ce format.

Remarque : les formats standard étant toujours convertis en formats natifs lorsque les données sont collées ou déplacées hors d’une application prise en charge, la valeur du paramètre serializable n’a aucune incidence sur la disponibilité des données aux formats standard pour les applications non Flash.

Pour différer le rendu des données pour un format, utilisez plutôt la méthode setDataHandler(). Si les méthodes setData() et setDataHandler() sont toutes deux utilisées pour ajouter une représentation de données avec le même nom de format, la fonction du gestionnaire n’est jamais appelée.

Remarque : sous Mac OS, lorsque vous définissez le paramètre format sur ClipboardFormats.URL_FORMAT, l’URL n’est transférée que s’il s’agit d’une URL valide. Dans le cas contraire, l’objet Clipboard est vidé (et l’appel de getData() renvoie null).

Paramètres

Eléments de l’API associés

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Ajoute une référence à une fonction de gestionnaire qui produit les données à transférer.

Utilisez une fonction de gestionnaire pour différer la création ou le rendu des données jusqu’à ce l’utilisateur y accèdent réellement.

La fonction du gestionnaire doit renvoyer le type de données approprié pour le format spécifié :

La fonction de gestionnaire n’est appelée que lorsque les données au format spécifié sont lues, et seulement à ce moment-là. Notez que dans certains cas, le système d’exploitation appelle la fonction avant qu’un dépôt ne se produise. Par exemple, lorsque vous utilisez une fonction de gestionnaire pour fournir des données à un fichier déplacé depuis une application AIR vers le système de fichiers, le système d’exploitation appelle la fonction de gestionnaire des données dès que le mouvement de glissement quitte l’application AIR, ce qui résulte généralement en une pause indésirable lors du téléchargement ou de la création des données du fichier. Vous pouvez pour cela utiliser une classe URLFilePromise.

Notez que les données sous-jacentes peuvent changer entre le moment où le gestionnaire est ajouté et le moment où les données sont lues, sauf si votre application prend des mesures pour protéger les données. Le comportement qui se produit lorsque les données du presse-papier représentées par une fonction du gestionnaire sont lues plusieurs fois n’est pas garanti. Le Presse-papiers peut renvoyer les données produites par le premier appel de la fonction ou rappeler la fonction. Ne comptez pas sur ces comportements.

Dans le sandbox de l’application d’Adobe AIR, setDataHandler() peut être appelée à tout moment. Dans d’autres contextes, setDataHandler() ne peut être appelée qu’en réponse à un événement généré par l’utilisateur, notamment lorsque celui-ci appuie sur une touche ou clique sur la souris.

Pour ajouter directement des données dans cet objet Clipboard, utilisez plutôt la méthode setData(). Si les méthodes setData() et setDataHandler() sont toutes deux appelées par le même nom de format, la fonction du gestionnaire n’est jamais appelée.

Remarque : sous Mac OS, lorsque vous définissez le paramètre format sur ClipboardFormats.URL_FORMAT, l’URL n’est transférée que s’il s’agit d’une URL valide. Dans le cas contraire, l’objet Clipboard est vidé (et l’appel de getData() renvoie null).

Paramètres

Eléments de l’API associés

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Ecrivez les données, dans ce cas une chaîne, dans Clipboard.generalClipboard.
2. Lisez le contenu du presse-papiers dans Clipboard.generalClipboard.

Remarque : en raison des restrictions d’accès aux données du Presse-papiers, cet exemple ne fonctionne pas dans Flash Player. Dans Flash Player, vous ne pouvez appeler que la méthode getData() de l’objet Presse-papiers dans un gestionnaire d’événement paste.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}