PrintJobOptions  - AS3

Especifica la resolución para utilizar en mapas de bits, en píxeles por pulgada. El valor predeterminado es Number.NaN, que indica que debe utilizarse la resolución nativa de la impresora.

El valor de la resolución se aplica tanto a la impresión de mapa de bits y a la vectorial. Para la impresión de mapa de bits, controla la rasterización de toda la página. Para la impresión vectorial, la resolución controla cómo se rasteriza el contenido específico, por ejemplo, mapas de bits y degradados.

Especifica si el contenido del trabajo de impresión se imprime como mapa de bits o como vector. El valor predeterminado es false para la impresión vectorial.

Si el contenido que está imprimiendo incluye una imagen de mapa de bits, defina la propiedad printAsBitmap como true para incluir cualquier transparencia alfa y efectos de color. Si el contenido no incluye imágenes de mapa de bits, imprima el contenido en formato vectorial de calidad superior (opción predeterminada).

Por ejemplo, para imprimir el contenido como mapa de bits, utilice la siguiente sintaxis:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         

Nota: Adobe AIR no admite la impresión vectorial en Mac OS.

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Especifica que el motor de ejecución de Flash debe elegir el método de impresión más adecuado, o que que el autor desea seleccionar explícitamente la impresión vectorial o de mapa de bits.

Establezca la propiedad en uno de los siguientes valores definidos en la clase PrintMethod:

• PrintMethod.AUTO: este valor indica que la impresión vectorial o de mapa de bits se debe elegir automáticamente según el contenido que se va a imprimir. Se utilizará la impresión vectorial utilizará siempre que el contenido se pueda reproducir fielmente con dicho método. Si la transparencia u otros efectos están presentes, se utilizará la impresión de mapa de bits en su lugar.
• PrintMethod.VECTOR: especifica impresión vectorial. Este ajuste es los mismo que establecer printAsBitmap como false.
• PrintMethod.BITMAP: especifica impresión de mapa de bits. Equivale a establecer printAsBitmap como true.

Si se establece printMethod en uno de estos valores admitidos, se omitirá printAsBitmap.

El valor predeterminado es null; se utiliza la propiedad printAsBitmap.

Elementos de API relacionados

Crea un nuevo objeto PrintJobOptions. Pase este objeto al parámetro options del método PrintJob.addPage().

Elementos de API relacionados