SQLStatement  - AS3

Indica si la declaración se está ejecutando.

Esta propiedad es true si se ha llamado a execute() y no se han devuelto todos los valores de la base de datos.

Elementos de API relacionados

Indica una clase (tipo de datos) que se utiliza para cada fila devuelta como resultado de la ejecución de la declaración.

De forma predeterminada, cada fila devuelta por una declaración SELECT se crea como una instancia de Object. Los nombres de los conjuntos de datos de resultados pasan a ser los nombres de las propiedades del objeto y el valor de cada columa se convierte en el valor de su propiedad asociada.

Al especificar una clase para la propiedad itemClass, cada fila devuelve una declaración SELECT ejecutada por esta instancia de SQLStatement se crea como una instancia de la clase designada. Cada propiedad de la instancia de itemClass se asigna al valor de la columna del mismo nombre que la propiedad.

Todas las clases asignadas a esta propiedad deben tener un constructor que no requiera parámetros. Además, la clase debe disponer de una propiedad para cada columna devuelta por la declaración SELECT. Se considera un error que una columna de la lista SELECT no tenga su nombre de propiedad correspondiente en la clase itemClass.

Elementos de API relacionados

// Employee class definition
package
{
    public class Employee
    {
        public var name:String;
        public var ssn:String;
        public var id:uint;
        public override function toString():String
        {
            return "id: "+ id.toString() + " name: " + name + " ssn: " + ssn;
        }
    }
}


// using the Employee class as SQLStatement.itemClass
var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    dbStatement.itemClass = Employee;
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var emp:Employee;
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            emp = result.data[i];
            trace(emp.toString());
        }
    }
}

Sirve de conjunto asociativo al que añadir valores para los parámetros especificados en la propiedad text de la declaración SQL. Las claves del conjunto son los nombres de los parámetros. Si se especifica un parámetro sin nombre en el texto de la declaración, su clave se convierte en el índice del parámetro.

En el texto de una declaración SQL, un parámetro se indica con uno de los siguientes caracteres: "?", ":" o "@".

Los símbolos ":" y "@" indican parámetros con nombre; los caracteres situados detrás del símbolo indican el nombre del parámetro.

Por ejemplo, en la siguiente declaración SQL, se especifica un parámetro llamado firstName mediante el carácter ":":

SELECT FROM employees WHERE firstName = :firstName

El símbolo "?" indica un parámetro indexado (numerado); cada parámetro adquiere automáticamente un índica en función de la secuencia de parámetros del texto de la declaración. Los valores de índice de los parámetros están basados en ceros. Dicho de otro modo, el índice del primer parámetro es 0.

Los parámetros se utilizan para poder realizar sustituciones de tipos de valores que son desconocidos en el momento en que se construye la declaración SQL. Utilizar los parámetros es el único modo de garantizar los valores transferidos a las clases de almacenamiento en la base de datos. Si no se utilizan parámetros, todos los valores se convierten de representación textual en clase de almacenamiento por tipo de columna asociada. Para obtener más información sobre las clases de almacenamiento y la afinidad de columnas, consulte la sección “Compatibilidad de tipos de datos” del apéndice “Compatibilidad de SQL en bases de datos locales”.

Los parámetros también se utilizan como medida de seguridad para impedir la ejecución de técnicas malintencionadas conocidas como ataques de inyección SQL. Durante un ataque de inyección SQL, un usuario accede al código SQL en una ubicación a la que el usuario tiene acceso (por ejemplo, un campo de introducción de datos). Si el código de la aplicación construye una declaración SQL concatenando directamente la entrada del usuario con el texto SQL, el código SQL introducido por el usuario se ejecuta en la base de datos. A continuación se muestra un ejemplo de concatenación de entrada del usuario en texto SQL. No se recomienda utilizar esta técnica:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = '" + username + "' " +
         "    AND password = '" + password + "'";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     

Si se utilizan parámetros de declaración y no la concatenación de valores introducidos por el usuario en el texto de la declaración, se impiden ataques de inyección SQL, ya que los valores de los parámetros se tratan explícitamente como valores sustituidos y no forman parte del texto literal de la declaración. A continuación se muestra una alternativa recomendada distinta a la anterior:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = :username " +
         "    AND password = :password";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     // set parameter values
     statement.parameters[":username"] = username;
     statement.parameters[":password"] = password;
     

Se deben establecer todos los valores de los parámetros para poder ejecutar la declaración. Los valores de los parámetros especificados en el conjunto parameters están vinculados (es decir, combinados con el texto de la declaración) cuando se llama al método execute(). Una vez realizada la llamada a execute(), los cambios sucesivos en los valores no se aplican a la declaración en ejecución. No obstante, sí se utilizarán los valores modificados en sucesivas llamadas a execute(). Si el texto de la declaración contiene un parámetro sin valor especificado en la propiedad parameters, se produce un error.

Para borrar todos los valores de los parámetros de la propiedad parameters, utilice el método clearParameters().

Elementos de API relacionados

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = :firstName";
employees.parameters[":firstName"] = "Sam";
employees.execute();

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = ?";
employees.parameters[0] = "Sam";
employees.execute();

El objeto SQLConnection que administra la conexión con las bases de datos en las que se ejecuta la declaración.

Texto SQL real de la declaración.

El texto puede estar en cualquier tipo de SQL admitido. Para obtener una descripción completa del lenguaje SQL admitido en las bases de datos SQL locales, consulte el apéndice “Compatibilidad de SQL en bases de datos locales”.

Crea una instancia de SQLStatement.

Cancela la ejecución de esta declaración. Al igual que ocurre con SQLConnection.cancel(), este método se utiliza para detener una consulta que lleve mucho tiempo ejecutándose o para cancelar consultas que aún no hayan finalizado. No obstante, y al contrario de lo que ocurre con SQLConnection.cancel(), este método cancela únicamente la declaración. Si la declaración no se está ejecutando en ese momento, la llamada al método no servirá de nada.

No se distribuyen eventos como respuesta directa a la finalización de la operación de cancel(). Sin embargo, una vez finalizada la operación de cancel() y cancelada la ejecución de la declaración, la instancia de SQLStatement distribuye un evento error para indicar que la ejecución de la declaración (la llamada a execute() o a next()) no se ha completado. Como alternativa, si se especificó un valor para el parámetro responder de la llamada a execute() o a next(), se llamará al método concreto de control de errores. En cualquier caso, la instancia de SQLError que se transfiere a los detectores tiene una propiedad errorID con un valor de 3118 (operación fallida).

Borra toda la configuración actual de los parámetros.

Elementos de API relacionados

Ejecuta el SQL en la propiedad text comparándola con la base de datos conectada al objeto SQLConnection de la propiedad sqlConnection.

Si el argumento responder no es null, el objeto Responder especificado designa los métodos a los que se llama para controlar los resultados de la operación. En modo de ejecución asíncrono, si el argumento responder es null, se distribuye un evento result si la operación se realiza correctamente, o un evento error si la operación falla.

Para acceder a los resultados de una declaración, como las filas de resultados de una declaración SELECT o la clave principal generada de la base de datos de una declaración INSERT, llame al método getResult(). Los resultados están disponibles inmediatamente después de la ejecución de la declaración en modo sincrónico y cuando el evento result se distribuye en modo asíncrono.

Cada declaración debe estar preparada (compilada) para poder ejecutarse. La primera vez que se llama al método execute() de una instancia de SQLStatement, el motor de ejecución prepara la declaración. Una vez preparada, no es necesario volverla a preparar, a no ser que la propiedad text cambie. Si establece uno o varios valores de parámetros, no es necesario volver a preparar la declaración.

Parámetros

Elementos de API relacionados

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

var conn:SQLConnection;
var dbStatement:SQLStatement;
var employeeResponder:Responder;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    employeeResponder = new Responder(resultHandler, errorHandler);
    dbStatement.execute(-1, employeeResponder);
}

function resultHandler(result:SQLResult):void
{
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(error:SQLError):void
{
    trace("An error occured while executing the statement.");
}

Proporciona acceso a un objeto SQLResult que contiene los resultados de la ejecución de la declaración. Incluye todos las filas de resultados desde una declaración SELECT y el resto de información sobre la ejecución de todas las declaraciones. En mood de ejecución asíncrono, la información de los resultados no está disponible hasta que se distribuye el evento result.

Cuando se ejecuta una declaración SELECT, si se llama al método execute() con el argumento prefetch en su valor predeterminado de -1, el objeto SQLResult devuelto contiene todo el conjunto de resultados de la consulta.

Cuando se especifica un argumento prefetch para una llamada al método execute() o next(), el método getResult() se comporta como una cola en la que los resultados se producen a medida que entran los datos. Cada vez que se distribuye el evento result, se añade a la cola un nuevo objeto SQLResult. Cada vez que se llama al método getResult(), el objeto SQLResult más antiguo (el que se añadió a la lista en primer lugar) se devuelve y se elimina de la cola. Si ya no quedan objetos SQLResult en la cola, getResult() devuelve null.

Tenga en cuenta que, a no ser que se eliminen llamando a getResult(), los objetos SQLResult permanecen en la cola. Por ejemplo, si se llama varias veces al método execute() sin llamar a getResult(), los objetos SQLResult asociados a cada llamada a execute() permanecen en la cola.

Elementos de API relacionados

Recupera la siguiente porción del conjunto de resultados de una declaración SELECT. Si ya no hay más filas en el conjunto de resultados, se distribuye un evento result pero no se añaden más objetos SQLResult a la cola getResult().

En modo de ejecución asíncrono, si el argumento responder no es null, el objeto Responder indica a los métodos llamados que deben controlar los resultados de la operación. Si el argumento responder es null, se distribuye un evento result si la operación se realiza correctamente, o un evento error si la operación falla.

Sólo se puede llamar a este método si la declaración sigue ejecutándose. Si la declaración es una consulta SELECT y se especifica un argumento prefetch mayor que cero, se considera que la declaración está en ejecución hasta que se devuelve todo el conjunto de resultados, o hasta que se llama al método SQLStatement.cancel() o SQLConnection.cancel().

Parámetros

Elementos de API relacionados

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute(10);
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
        if (!result.complete)
        {
            dbStatement.next(10);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

Se distribuye cuando se produce un error durante la operación.

Elementos de API relacionados

Se distribuyen cuando la operación de llamada a los métodos execute() o next() finaliza correctamente. Una vez distribuido el evento result, es posible llamar al método getResult() para recuperar los resultados de la declaración.

Elementos de API relacionados