PrintJob  - AS3

Gibt an, ob zurzeit ein Druckauftrag aktiv ist. Ein Druckauftrag ist aktiv (der Wert der Eigenschaft ist true), wenn mindestens eine der beiden folgenden Bedingungen zutrifft:

• Es wird das Dialogfeld „Seite einrichten“ der „Drucken“ angezeigt.
• Die start()- oder start2()-Methode wurde mit einem Rückgabewert true aufgerufen und die Methode send() oder terminate() wurde nicht aufgerufen.

Wenn diese Eigenschaft den Wert true hat und Sie die Methode showPageSetupDialog(), start() oder start2() aufrufen, gibt die Laufzeitumgebung eine Ausnahme aus.

Verwandte API-Elemente

Die Anzahl der Kopien, die das Drucksystem von allen ggf. später zum Druckauftrag hinzugefügten Seiten druckt. Dies ist die Anzahl der Kopien, die vom Benutzer in das Druckdialogfeld des Betriebssystems eingegeben wurde. Wenn die Anzahl der Kopien im Druckdialogfeld nicht angezeigt oder das Dialogfeld nicht eingeblendet wurde, ist der Wert 1 (sofern er nicht vom Anwendungscode geändert wurde).

Die Seitenzahl der ersten Seite des Seitenbereichs, den der Benutzer im Druckdialogfeld des Betriebssystems eingegeben hat. Diese Eigenschaft hat den Wert Null, wenn der Benutzer anfordert, dass alle Seiten gedruckt werden, oder wenn der Seitenbereich nicht im Druckdialogfeld angezeigt wurde oder wenn das Druckdialogfeld nicht für den Benutzer eingeblendet wurde.

Gibt an, ob der zurzeit ausgewählte Drucker mit den aktuellen Druckeinstellungen farbig (true) oder Graustufen (false) druckt.

Wenn kein Farben-oder-Graustufen-Wert ermittelt werden kann, ist der Wert true.

Gibt an, ob die PrintJob-Klasse von der aktuellen Plattform unterstützt wird (true) oder nicht (false).

Der Name oder Titel des Druckauftrags. Der Auftragsname wird vom Betriebssystem typischerweise als Titel des Auftrags in der Druckwarteschlange oder als Standardname eines Auftrags, der in eine Datei gedruckt wird, verwendet.

Wenn Sie die Methode start() oder start2() nicht aufgerufen und keinen Wert für die Eigenschaft festgelegt haben, hat die Eigenschaft den Wert null.

Für jeden Druckauftrag, den Sie mit der PrintJob-Instanz ausführen, legen Sie diese Eigenschaft fest, bevor Sie die start()- oder start2()-Methode aufrufen.

Der Standardwert ist null.

Die Seitenzahl der letzten Seite des Seitenbereichs, den der Benutzer im Druckdialogfeld des Betriebssystems eingegeben hat. Diese Eigenschaft hat den Wert Null, wenn der Benutzer anfordert, dass alle Seiten gedruckt werden, oder wenn der Seitenbereich nicht im Druckdialogfeld angezeigt wurde oder wenn das Druckdialogfeld nicht für den Benutzer eingeblendet wurde.

Die physische Auflösung des ausgewählten Druckers in Pixel pro Zoll. Der Wert wird entsprechend den aktuellen Druckeinstellungen, die vom Betriebssystem gemeldet werden, berechnet.

Wenn die Auflösung nicht ermittelt werden kann, wird ein Standardwert verwendet. Der Standardwert ist 600 ppi unter Linux und 360 ppi unter Mac OS. Unter Windows ist die Druckerauflösung immer verfügbar, weshalb kein Standardwert erforderlich ist.

Die Bildausrichtung für den Druck. Die akzeptierten Werte sind als Konstanten in der PrintJobOrientation-Klasse definiert.

Hinweis: Für AIR 2 oder höher legen Sie diese Eigenschaft fest, bevor Sie einen Druckauftrag starten, um die Standardausrichtung in den Dialogfeldern „Seite einrichten“ und „Drucken“ einzustellen. Legen Sie die Eigenschaft fest, während ein Druckauftrag ausgeführt wird (nach dem Aufrufen von start() oder start2(), um die Ausrichtung für einen Seitenbereich innerhalb des Druckauftrags festzulegen.

Verwandte API-Elemente

Die Höhe des größten Bereichs, der im aktuellen druckbaren Bereich der Seite zentriert werden kann, in Punkt. Alle benutzerdefinierten Randeinstellungen werden ignoriert. Diese Eigenschaft ist nur nach einem Aufruf der PrintJob.start()-Methode verfügbar.

Hinweis: Für AIR 2 oder höher ist diese Eigenschaft veraltet. Verwenden Sie stattdessen printableArea, womit der druckbare Bereich in gebrochenen Punkt gemessen wird und nicht zentrierte Druckbereiche genau beschrieben werden.

Verwandte API-Elemente

Die Breite des größten Bereichs, der im aktuellen druckbaren Bereich der Seite zentriert werden kann, in Punkt. Alle benutzerdefinierten Randeinstellungen werden ignoriert. Diese Eigenschaft ist nur nach einem Aufruf der PrintJob.start()-Methode verfügbar.

Hinweis: Für AIR 2 oder höher ist diese Eigenschaft veraltet. Verwenden Sie stattdessen printableArea, womit der druckbare Bereich in gebrochenen Punkt gemessen wird und nicht zentrierte Druckbereiche genau beschrieben werden.

Verwandte API-Elemente

Die Grenzen des Druckermediums in Punkt. Dieser Wert verwendet dasselbe Koordinatensystem, das für nachfolgende Aufrufe von addPage() verwendet wird.

Die Gesamthöhe des Papiers in Punkt. Diese Eigenschaft ist nur nach einem Aufruf der PrintJob.start()-Methode verfügbar.

Hinweis: Für AIR 2 oder höher ist diese Eigenschaft veraltet. Verwenden Sie stattdessen paperArea, womit die Abmessungen des Papiers in gebrochenen Punkt gemessen werden.

Verwandte API-Elemente

Die Gesamtbreite des Papiers in Punkt. Diese Eigenschaft ist nur nach einem Aufruf der PrintJob.start()-Methode verfügbar.

Hinweis: Für AIR 2 oder höher ist diese Eigenschaft veraltet. Verwenden Sie stattdessen paperArea, womit die Abmessungen des Papiers in gebrochenen Punkt gemessen werden.

Verwandte API-Elemente

Die Grenzen des druckbaren Bereichs des Druckermediums in Punkt. Dieser Wert verwendet dasselbe Koordinatensystem, das für nachfolgende Aufrufe von addPage() verwendet wird.

Ruft den Drucker ab, der für die folgenden Druckaufträge verwendet werden soll, oder legt diesen fest. Der String, der an den Setter übergeben und vom Getter zurückgegeben wird, sollte mit einem der Strings im Array, das von der printers()-Methode zurückgegeben wird, übereinstimmen. Um anzugeben, das der Standarddrucker verwendet werden soll, legen Sie den Wert null fest. Bei Betriebssystemen, in denen kein Standarddrucker bestimmt werden kann, hat diese Eigenschaft den Wert null.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Wenn Sie den Wert dieser Eigenschaft festlegen, wird sofort versucht, diesen Drucker auszuwählen. Wenn der Drucker nicht ausgewählt werden kann, wird diese Eigenschaft auf den zuvor verwendeten Wert zurückgesetzt. Sie können ermitteln, ob das Festlegen des Druckerwerts erfolgreich ist, indem Sie den Wert nach dem Versuch, ihn zu senden, lesen und überprüfen, ob der mit dem zuvor eingestellten Wert übereinstimmt.

Die printer-Eigenschaft eines aktiven Druckauftrags kann nicht geändert werden. Wenn Sie versuchen, ihn nach dem erfolgreichen Aufrufen der start()- oder start2()-Methode und vor dem Aufrufen von send() oder terminate() zu ändern, schlägt dies fehl.

Stellt eine Liste der verfügbaren Drucker als Stringnamenwerte bereit. Die Liste wird nicht im Voraus berechnet; sie wird generiert, wenn die Funktion aufgerufen wird. Wenn keine Drucker verfügbar sind oder das System Druckvorgänge nicht unterstützt, ist der Wert null. Wenn das System den Druck zwar unterstützt aber keine Liste mit Druckern zurückgeben kann, ist der Wert ein Vektor mit einem einzelnen Element (seine length-Eigenschaft ist 1). In diesem Fall hat das einzelne Element den tatsächlichen Druckernamen oder einen Standardnamen, wenn der Name des aktuellen Druckers nicht ermittelt werden kann.

Gibt an, ob die Flash-Laufzeitumgebung ein separates Dialogfeld "Seite einrichten" unterstützt. Wenn diese Eigenschaft den Wert true hat, können Sie die showPageSetupDialog()-Methode aufrufen, um das Dialogfeld „Seite einrichten“ des Betriebssystems anzuzeigen.

Verwandte API-Elemente

Erstellt ein PrintJob-Objekt, mit dem Sie eine oder mehrere Seiten drucken können. Nach dem Erstellen eines PrintJob-Objekts müssen Sie (in der folgenden Reihenfolge) die Methoden PrintJob.start(), PrintJob.addPage() und anschließend PrintJob.send() verwenden, um den Druckauftrag an den Drucker zu senden.

Sie können beispielsweise den Text für den Platzhalter [params] für die Aufrufe der myPrintJob.addPage()-Methode durch benutzerdefinierte Parameter ersetzen, wie dies im folgenden Code dargestellt ist:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

In AIR 2 oder höher können Sie mehrere PrintJob-Instanzen erstellen und verwenden. Die für die PrintJob-Instanz festgelegten Eigenschaften bleiben auch nach Abschluss des Druckvorgangs erhalten. Auf diese Weise können Sie eine PrintJob-Instanz wiederverwenden und die vom Benutzer ausgewählten Druckeinstellungen beibehalten, während für andere Inhalte in Ihrer Anwendung andere Druckeinstellungen angeboten werden können. Für Inhalte in Flash Player und in AIR-Versionen vor AIR 2 können Sie kein zweites PrintJob-Objekt erstellen, während das erste noch aktiv ist. Wenn Sie (durch Aufrufen von new PrintJob()) ein zweites PrintJob-Objekt erstellen möchten, während das erste Objekt noch aktiv ist, wird das zweite PrintJob-Objekt nicht erstellt. Überprüfen Sie daher vor dem Erstellen eines zweiten PrintJob-Objekts den Wert von myPrintJob.

Verwandte API-Elemente

Sendet das angegebene Sprite-Objekt als einzelne Seite an die Druckwarteschlange. Vor der Verwendung dieser Methode müssen Sie ein PrintJob-Objekt erstellen und dann start() oder start2() verwenden. Senden Sie nach dem einmaligen oder mehrfachen Aufrufen von addPage() für einen Druckauftrag anschließend die Seiten in der Druckwarteschlange mithilfe von send() an den Drucker. Mit anderen Worten: Nach dem Erstellen eines PrintJob-Objekts verwenden Sie (in der folgenden Reihenfolge) die Methoden start() oder start2(), addPage() und dann send(), um den Druckauftrag an den Drucker zu senden. Sie können addPage() mehrere Male nach einem einfachen Aufruf von start() aufrufen, um mehrere Seiten in einem Druckauftrag zu drucken.

Wenn durch addPage() eine Ausnahme in Flash Player ausgelöst wird (z. B. wenn start() nicht aufgerufen wurde oder der Benutzer den Druckauftrag abbricht), schlagen alle nachfolgenden Aufrufe von addPage() fehl. Wenn vorherige Aufrufe von addPage() jedoch erfolgreich waren, sendet der abschließende Befehl send() alle Seiten in der Warteschlange an den Drucker.

Wenn der addPage()-Vorgang im Druckauftrag 15 Sekunden überschreitet, wird beim nächsten Aufruf von addPage() eine Ausnahme in Flash Player ausgelöst.

Wenn Sie einen Wert für den printArea-Parameter übergeben, werden die Koordinaten x und y des printArea-Rechtecks relativ zur oberen linken Ecke (Koordinaten 0, 0) des druckbaren Seitenbereichs festgelegt. Die schreibgeschützten Eigenschaften pageHeight und pageWidth beschreiben den druckbaren Bereich, der von start() festgelegt wird. Da die Ausrichtung des Ausdrucks an der oberen linken Ecke des druckbaren Bereichs der Seite erfolgt, wird er gegebenenfalls rechts und/oder unten in dem durch printArea definierten Bereich beschnitten, wenn der in printArea festgelegte Bereich größer ist als der druckbare Bereich der Seite. Wenn Sie in Flash Professional für printArea keinen Wert übergeben und die Bühne größer als der druckbare Bereich ist, wird der Ausdruck auch zugeschnitten. Wenn Sie in Flex oder Flash Builder für printArea keinen Wert übergeben und der Bildschirm größer als der druckbare Bereich ist, wird der Ausdruck auch beschnitten.

Wenn Sie ein Sprite-Objekt vor dem Drucken skalieren möchten, legen Sie die Skaliereigenschaften (siehe flash.display.DisplayObject.scaleX und flash.display.DisplayObject.scaleY) fest, bevor Sie diese Methode aufrufen, und setzen sie danach auf ihre ursprünglichen Werte zurück. Die Skalierung eines Sprite-Objekts hat keinen Bezug auf printArea. Wenn Sie beispielsweise einen Druckbereich mit der Größe 50 x 50 Pixel festlegen, werden 2500 Pixel gedruckt. Wenn Sie das Sprite-Objekt skalieren, werden dieselben 2500 Pixel in der skalierten Größe gedruckt.

Die Druckfunktion im Flash Player unterstützt PostScript- und Nicht-PostScript-Drucker. Bei Nicht-PostScript-Druckern werden die Vektoren in Bitmaps umgewandelt.

Parameter

Verwandte API-Elemente

Legt das Papierformat fest. Die akzeptierten Werte für den paperSize-Parameter sind Konstanten in der PaperSize-Klasse. Das Aufrufen dieser Methode beeinflusst die Druckeinstellungen, als ob der Benutzer ein Papierformat im Dialogfeld „Seite einrichten“ oder „Drucken“ auswählt.

Sie können diese Methode jederzeit aufrufen. Rufen Sie diese Methode auf, bevor ein Druckvorgang gestartet wird, um das Standardpapierformat in den Dialogfeldern „Seite einrichten“ oder „Drucken“ festzulegen. Rufen Sie diese Methode auf, während ein Druckvorgang ausgeführt wird, um das Papierformat für einen Seitenbereich innerhalb des Druckauftrags festzulegen.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parameter

Verwandte API-Elemente

Sendet nach erfolgreichen Aufrufen der Methoden start() oder start2() und addPage() gespoolte Seite an den Drucker.

Diese Methode ist nicht erfolgreich, wenn der Aufruf der start()- oder start2()-Methode fehlschlägt oder wenn ein Aufruf der addPage()-Methode eine Ausnahme ausgibt. Um einen Fehler zu vermeiden, überprüfen Sie, ob die start()- oder start2()-Methode true zurückgibt und fangen Sie alle addPage()-Ausnahmen ab, bevor Sie diese Methode aufrufen. Das folgende Beispiel zeigt, wie vor dem Aufrufen dieser Methode korrekt auf Fehler überprüft wird:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Verwandte API-Elemente

Zeigt das Dialogfeld „Seite einrichten“ des Betriebssystems an, falls dies von der aktuellen Umgebung unterstützt wird. Verwenden Sie die supportsPageSetupDialog-Eigenschaft, um festzustellen, ob das Dialogfeld „Seite einrichten“ unterstützt wird.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Verwandte API-Elemente

Zeigt das Druckdialogfeld des Betriebssystems an und beginnt mit dem Spooling. Der Benutzer kann die Druckeinstellungen im Druckdialogfeld ändern. Wenn die PrintJob.start()-Methode erfolgreich zurückgegeben wird (der Benutzer klickt im Druckdialogfeld auf "OK"), sind die folgenden Eigenschaften angegeben, welche die vom Benutzer gewählten Druckeinstellungen darstellen.

Hinweis: Wenn der Benutzer das Druckdialogfeld durch „Abbrechen“ schließt, werden die Eigenschaften nicht eingetragen.

Wenn der Benutzer im Dialogfeld „Drucken“ auf „OK“ klickt, beginnt der Player damit, den Druckauftrag an die Druckwarteschlange des Betriebssystems zu übergeben. Da im Betriebssystem dann Informationen zum Druckstatus angezeigt werden, sollten Sie möglichst bald PrintJob.addPage() und PrintJob.send() aufrufen, damit Seiten an die Druckwarteschlange gesendet werden. Sie können die schreibgeschützten, mit dieser Methode angegebenen Eigenschaften für Höhe, Breite und Ausrichtung zum Formatieren des Ausdrucks verwenden.

Überprüfen Sie zunächst, ob diese Methode true zurückgibt (nachdem der Benutzer im Druckdialogfeld des Betriebssystems auf „OK“ geklickt hat), und rufen Sie erst dann PrintJob.addPage() und PrintJob.send() auf:

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Wenn eines der folgenden Intervalle bei der angegebenen Instanz des Druckauftrags ein Zeitlimit von 15 Sekunden überschreitet, wird beim darauf folgenden Aufruf von PrintJob.start() der Wert false zurückgegeben.

• PrintJob.start() und die erste PrintJob.addPage()
• eine PrintJob.addPage() und die nächste PrintJob.addPage()
• die letzte PrintJob.addPage() und PrintJob.send()

Verwandte API-Elemente

Zeigt optional das Druckdialogfeld des Betriebssystems an, startet den Spoolvorgang und ändert möglicherweise die schreibgeschützten Eigenschaftswerte für das PrintJob-Objekt.

Der uiOptions-Parameter ermöglicht es dem Aufrufer zu steuern, welche Optionen im Dialogfeld „Drucken“ angezeigt werden. Lesen Sie dazu den Abschnitt zur PrintUIOptions-Klasse. Dieser Parameter wird ignoriert, wenn showPrintDialog den Wert „false“ hat.

Auch wenn showPrintDialog den Wert true hat, kann sich das Verhalten dieser Methode von der start()-Methode unterscheiden. Bei einigen Betriebssystemen zeigt start() das Dialogfeld „Seite einrichten“ gefolgt vom Dialogfeld „Drucken an“. Im Gegensatz dazu zeigt start2() nie das Dialogfeld „Seite einrichten“ an.

Im folgenden Beispiel werden die Einstellungen für die niedrigste und die höchste Seitenzahl im Dialogfeld „Drucken“ festgelegt, bevor das Dialogfeld für den Benutzer angezeigt wird:

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parameter

Verwandte API-Elemente

Gibt an, dass der Druckauftrag beendet werden soll, ohne dass er gesendet wird. Verwenden Sie diese Methode, wenn ein Druckauftrag bereits durch einen Aufruf von start() oder start2() eingeleitet wurde, aber keine Seiten an den Drucker gesendet werden sollen. Typischerweise wird terminate() nur zur Wiederherstellung nach Fehlern verwendet.

Nach dem Aufrufen dieser Methode kann die PrintJob-Instanz wiederverwendet werden. Wo immer dies möglich ist, werden die Druckeinstellungen zur späteren Verwendung erhalten.

1. Deklarieren Sie zwei Variablen vom Typ „Sprite“ mit den Namen sheet1 und sheet2.
2. Rufen Sie danach init() auf, womit sowohl sheet1 als auch sheet2 eine neue Sprite-Instanz zugewiesen wird. Anschließend wird createSheet() mithilfe von anderen Argumenten aufgerufen.
3. createSheet() bewirkt Folgendes:
   1. Mithilfe des übergebenen Sprite-Objekts wird bei x = 0 und y = 0 ein Rechteck gezeichnet, und zwar mit einer Breite von 100 Pixel und einer Höhe von 200 Pixel, einem hellgrauen Hintergrund und einem schwarzen Rand mit einer Breite von 1 Pixel.
   2. Es wird ein neues TextField-Objekt mit dem Namen txt erstellt. Es weist die gleichen Abmessungen wie das Sprite-Objekt auf, die wordWrap-Eigenschaft ist auf true gesetzt, und die text-Eigenschaft ist auf den String gesetzt, der als Argument an createSheet() übergeben wurde.
   3. Wenn das übergebene Object-Argument nicht null ist, wird eine neue Sprite-Instanz mit dem Namen img erstellt. Mithilfe dieser Sprite-Instanz und der Koordinaten- und Abmessungseigenschaften des übergebenen „Object“ wird ein weißes Rechteck gezeichnet. Das weiße Rechteck wird zur Anzeigeliste des Sprite-Objekts mithilfe von addChild() hinzugefügt.
   4. Das TextField-Objekt mit dem Namen txt wird zur Anzeigeliste des Sprite-Objekts mithilfe von addChild() hinzugefügt.
4. Im Konstruktor wird die aktivierte Druckmethode (nicht auskommentiert) aufgerufen. Da sich die Methoden sehr ähneln, wird printOnePerPage() unten beschrieben.
5. printOnePerPage() bewirkt Folgendes:
   1. Deklariert ein neues PrintJob-Objekt mit dem Namen pj und pagesToPrint als „uint“.
   2. Öffnet das Druckdialogfeld des Betriebssystems, und wartet darauf, dass der Benutzer auf OK klickt.
   3. Überprüft die Ausrichtung und falls „Querformat“ gewählt wurde, wird ein Fehler ausgegeben und der Vorgang beendet.
   4. Stellt die Höhe und Breite der Seite für sheet1 und sheet2 ein.
   5. Sendet sheet1 und sheet2 mithilfe von addPage() an die Druckwarteschlange.
   6. Wenn die Zahl der zu druckenden Seiten größer 0 ist, werden alle Seiten in der Druckwarteschlange gedruckt.
6. Die draw()-Methode wird aufgerufen, mit der die Größe der beiden Sprite-Eigenschaften geändert wird, sodass es auf die Bühne passt. Außerdem wird sheet2 verschoben, und zwar an eine Position unmittelbar rechts nebensheet1.

Hinweis: Der Konstruktor bietet drei Druckmethoden zur Auswahl an: ein Blatt pro Seite, zwei Blätter pro Seite oder Drucken auf die obere Hälfte der Seite. Dieses Beispiel kann nur korrekt ausgeführt werden, wenn zwei der Druckmethoden mithilfe von Code-Kommentaren deaktiviert wurden. Das Beispiel wurde so eingerichtet, dass printOnePerPage() aufgerufen wird.

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}