索引陣列

您可以使用好幾種技巧來建立 Array 實體或 Vector 實體。不過，建立每一種陣列類型的技巧都有些許不同。

若要在索引陣列中加入元素，最基本的方式就是使用陣列存取 ( [] ) 運算子。若要設定索引陣列元素的值，請在指定陳述式左邊使用 Array 或 Vector 物件名稱和索引：

songTitles[5] = "Happy Birthday";

如果 Array 或 Vector 本來就沒有該索引及在該處存放的元素，則會建立該索引並於該處儲存這個值。如果該索引已經有值，則新的值會取代現有的值。

Array 物件可讓您在任何索引建立元素。不過如果是 Vector 物件，您就只能將值指定給現有的索引，或者指定給下一個可用的索引。下一個可用的索引會對應至 Vector 物件的 length 屬性。若要在 Vector 物件中加入新元素，最安全的方式就是使用如下所示的程式碼：

myVector[myVector.length] = valueToAdd;

您可以利用 push() 、 unshift() 和 splice() 這三種 Array 和 Vector 類別方法，將元素插入索引陣列中。 push() 方法會將一或多個元素附加到陣列結尾。換句話說，以 push() 方法插入的最後一個元素具有最高的索引編號。 unshift() 方法會在陣列開頭 (索引編號一定是 0) 插入一或多個元素；而 splice() 方法則會在陣列的指定索引位置插入任意數量的項目。

下列範例將示範這三種方法。在範例中，會建立名為 planets 的陣列，依照距離「太陽」的遠近順序儲存行星名稱。首先，會呼叫 push() 方法加入第一個項目 Mars 。其次，呼叫 unshift() 方法，插入屬於陣列前方的項目 Mercury 。最後，則會呼叫 splice() 方法將 Venus 和 Earth 項目插入 Mercury 之後、 Mars 之前。傳送給 splice() 的第一個引數 (整數 1) 會指示從索引 1 開始插入；傳送給 splice() 的第二個引數 (整數 0) 則會指示不要刪除任何項目；傳送給 splice() 的第三和第四個引數 Venus 和 Earth 則是要插入的項目。

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

push() 和 unshift() 方法都會傳回無正負號的整數，代表修改過的陣列長度。以 splice() 方法來插入元素時會傳回空陣列，乍看之下好像有點奇怪，但是從 splice() 方法的多功能性來看，就顯得相當合理。您不僅可以使用 splice() 方法將元素插入陣列，也能移除陣列中的元素。當您使用 splice() 方法移除元素時，會傳回包含所移除元素的陣列。

若要從索引陣列擷取元素的值，最簡單的方式就是使用陣列存取 ( [] ) 運算子。若要擷取索引陣列元素的值，請在指定陳述式右邊使用 Array 或 Vector 物件名稱和索引：

var myFavoriteSong:String = songTitles[3];

如果某一索引沒有元素，您仍然可以嘗試使用該索引從 Array 或 Vector 擷取值。在這種情況下，Array 物件會傳回 undefined 值，而且 Vector 會擲回 RangeError 例外。

您可以利用 pop() 、 shift() 和 splice() 這三種 Array 和 Vector 類別方法來移除元素。 pop() 方法會從陣列結尾移除元素。換句話說，它會移除索引編號最高的元素。 shift() 方法會從陣列開頭移除元素，也就是說，它固定會移除索引編號為 0 的元素。可用來插入元素的 splice() 方法，則會從傳送至這個方法的第一個引數所指定的索引編號開始，移除任意數目的元數。

下列範例會使用這三種方法來移除 Array 實體中的元素。在範例中，會建立名為 oceans 的 Array 來儲存大型水域的名稱。Array 中有些名稱是湖泊的名稱，而非海洋的名稱，因此這些屬於湖泊的名稱必須加以移除。

首先，會使用 splice() 方法移除 Aral 和 Superior 項目，並插入 Atlantic 和 Indian 這兩個項目。傳送至 splice() 的第一個引數 (整數 2) 會指出這項作業是從清單的第三個項目開始，也就是位於索引 2 的項目。第二個引數 2 則會指出要移除二個項目。其它引數 Atlantic 和 Indian 則是要插入索引 2 位置的值。

接下來，會使用 pop() 方法移除陣列中的最後一個元素 Huron 。之後，會使用 shift() 方法移除陣列的第一個項目 Victoria 。

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

pop() 和 shift() 方法都會傳回所移除的項目。對 Array 實體而言，傳回值的資料類型是 Object，因為陣列可以保留任何資料類型的值。對於 Vector 實體而言，傳回值的資料類型則是 Vector 的基底類型。 splice() 方法會傳回包含所移除之值的 Array 或 Vector。您可以變更 oceans Array 範例，這樣對 splice() 的呼叫就會將傳回的 Array 指定給新的 Array 變數，如下列範例所示：

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

您可能會遇到針對 Array 物件元素使用 delete 運算子的程式碼。 delete 運算子會將 Array 元素的值設定為 undefined ，但是不會將元素從 Array 中移除。例如，下列程式碼會將 delete 運算子用於 oceans Array 的第三個元素，但是 Array 的長度仍然是 5：

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

您可以使用陣列的 length 屬性截斷 Array 或 Vector。如果您為索引陣列之 length 屬性設定的長度比這個陣列的目前長度還小，這個陣列便會遭截斷，而且大於新的 length 值減 1 之索引編號的元素會遭移除。例如，如果 oceans 陣列在經過排序之後，所有有效的項目都位於陣列的開頭，您即可使用 length 屬性移除位於陣列結尾的項目，如下列程式碼所示：

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

您可以使用 reverse() 、 sort() 及 sortOn() 這三種方法，藉由排序或反向順序排序來變更索引陣列的順序。這三種方法都會修改現有的陣列。下表摘要列出這些方法，以及這些方法針對 Array 和 Vector 物件的行為：

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

concat() 、 join() 、 slice() 和 toString() 四種 Array 和 Vector 類別的方法都會向陣列查詢資訊，但是不會修改陣列。 concat() 和 slice() 方法會傳回新的陣列，而 join() 和 toString() 方法則會傳回字串。 concat() 方法會採用新的陣列或元素清單做為引數，並將它合併至現有陣列以建立新的陣列。 slice() 方法有兩個參數，即名符其實的 startIndex 和 endIndex ，它們會傳回新的陣列，當中包含自現有陣列「分割」出來的元素副本。此分割是從 startIndex 的元素開始，並結束於 endIndex 之前的元素。在此要重複提醒的是，位於 endIndex 的元素不會包含在傳回值中。

下列範例會使用 concat() 和 slice() ，利用其它陣列的元素來建立新的陣列：

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

您可以使用 join() 和 toString() 方法來查詢陣列，並傳回陣列內容做為字串。如果沒有對 join() 方法使用任何參數，這兩種方法的行為方式是相同的，亦即它們都會傳回字串，其中包含陣列內以逗點分隔的所有元素清單。 join() 方法與 toString() 方法不同，前者會採用名為 delimiter 的參數，可以讓您選擇符號，以做為傳回字串中每個元素之間的分隔符號。

下列範例會建立名為 rivers 的 Array，並同時呼叫 join() 和 toString() 以字串型式傳回 Array 中的值。使用 toString() 方法可傳回以逗點分隔的值 ( riverCSV )，而使用 join() 方法則可傳回以 + 字元分隔的值。

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

有關 join() 方法要注意的一點是，不管您為主要陣列元素指定了何種分隔符號，所有巢狀 Array 或 Vector 實體一律都會傳回以逗點分隔的值，如下列範例所示：

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e