組合及轉換 XML 物件

Flash Player 9 以及更新的版本，Adobe AIR 1.0 以及更新的版本

您可以使用 prependChild() 或 appendChild() 方法，將某個屬性加入 XML 物件之屬性清單的開頭或結尾處，如下列範例所示： 

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

您可以使用 insertChildBefore() 或 insertChildAfter() 方法，在所指定屬性之前或之後加入某個屬性，如下所示： 

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

如下列範例所示，您也可以使用大括號運算子 ( { 和 } )，在建構 XML 物件時，以傳址方式從其它變數傳遞資料： 

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

您可以使用 = 運算子，將屬性與特質指派給 XML 物件，如下所示： 

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

這會將 XML 物件 x 設定為如下： 

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

您可以使用 + 與 += 運算子，連接多個 XMLList 物件： 

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

這會將 XMLList 物件 xList 設定為如下： 

<a>test1</a> 
<b>test2</b> 
<c>test3</c>