移動影片片段範例：RuntimeAssetsExplorer

為使 Explorer 可以與 SWF 元件庫適當地互動，必須先將執行階段資源元件庫的結構形式化。為完成這項作業，我們將先建立一個介面，它與類別類似，因為它是用來界定預期結構的方法藍圖，但與類別不同的是，它不包括方法主體。此介面可提供一種方法，讓執行階段元件庫與 Explorer 互相通訊。載入至瀏覽器的每一個執行階段資源 SWF 都將實作這個介面。如需有關介面以及它們如何能更有用的詳細資訊，請參閱「學習 ActionScript 3.0」中的「介面」。

RuntimeLibrary 介面會很簡單，只需要使用一個函數，就可以將要匯出並可在執行階段元件庫中使用的元件類別路徑陣列提供給結構檢視器。在最後的結果中，這個介面將具有一個方法： getAssets() 。

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

藉由定義 RuntimeLibrary 介面，便可以建立多個能夠載入至其它 SWF 檔的資源元件庫 SWF 檔。建立 SWF 資源元件庫包括四項工作：

• 建立資源元件庫 SWF 檔的類別

• 為元件庫中包含的個別資源建立類別

• 建立實際的圖像資源

• 將圖像元素與類別建立關聯，然後發佈這個元件庫 SWF

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

最後要處理的函數部分是資源檢視器的使用者介面。在此範例中，執行階段元件庫的路徑是以硬式編碼的方式編碼為 ASSETS_PATH 變數。或者，您也可以使用 FileReference 類別。例如，建立介面來瀏覽硬碟中特定的 SWF 檔。

成功載入執行階段元件庫後，Flash Player 就會呼叫 runtimeAssetsLoadComplete() 方法：

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

在此方法中，變數 rl 代表被載入端 SWF 檔。程式碼會呼叫被載入端 SWF 檔的 getAssets() 方法，以取得可用的資源清單，並呼叫 populateDropDown() 方法，將清單中的可用資源填入 ComboBox 組件。該方法接著會儲存每個資源的完整類別路徑。按一下使用者介面上的「增加」按鈕會觸發 addAsset() 方法：

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

這會取得 ComboBox ( assetNameCbo.selectedItem.data ) 中目前選取之資源的類別路徑，並且為了建立該資源的新實體，還會使用 getDefinitionByName() 函數 (來自於 flash.utils 套件) 取得該資源之類別的實際參考。