擷取鍵盤輸入

顯示物件如果從 InteractiveObject 類別繼承了物件的互動模式，則可以透過事件偵聽程式回應鍵盤事件。例如，您可以將事件偵聽程式放置在「舞台」上，以偵聽並回應鍵盤輸入。在下列程式碼中，事件偵聽程式會擷取按鍵按下動作，並顯示按鍵名稱與按鍵碼屬性：

function reportKeyDown(event:KeyboardEvent):void 
{ 
    trace("Key Pressed: " + String.fromCharCode(event.charCode) +         " (character code: " + event.charCode + ")"); 
} 
stage.addEventListener(KeyboardEvent.KEY_DOWN, reportKeyDown);

某些按鍵 (例如 Ctrl 鍵) 就算按下之後不會出現文字，也會產生事件。

在上一個程式碼範例中，鍵盤事件偵聽程式擷取了整個「舞台」的鍵盤輸入。您也可以針對「舞台」上的特定顯示物件撰寫事件偵聽程式；一旦物件成為焦點就可觸發這個事件偵聽程式。

在下列範例中，只有當使用者在 TextField 實體中輸入時，「輸出」面板才會反映按鍵動作。按住 Shift 鍵則會暫時將 TextField 的邊框顏色變為紅色。

這個程式碼會假定「舞台」上有名為 tf 的 TextField 實體。

tf.border = true; 
tf.type = "input"; 
tf.addEventListener(KeyboardEvent.KEY_DOWN,reportKeyDown); 
tf.addEventListener(KeyboardEvent.KEY_UP,reportKeyUp); 
 
function reportKeyDown(event:KeyboardEvent):void 
{ 
    trace("Key Pressed: " + String.fromCharCode(event.charCode) +         " (key code: " + event.keyCode + " character code: "         + event.charCode + ")"); 
    if (event.keyCode == Keyboard.SHIFT) tf.borderColor = 0xFF0000; 
} 
 
function reportKeyUp(event:KeyboardEvent):void 
{ 
    trace("Key Released: " + String.fromCharCode(event.charCode) +         " (key code: " + event.keyCode + " character code: " +         event.charCode + ")"); 
    if (event.keyCode == Keyboard.SHIFT) 
    { 
        tf.borderColor = 0x000000; 
    } 
}

這個 TextField 類別也會回報 textInput 事件，您可以在使用者輸入文字時偵聽這個事件。如需詳細資訊，請參閱擷取文字輸入。