在 AIR 中使用 File 物件

您可以使用 File 類別執行下列工作：

• 取得特殊目錄 (包括使用者目錄、使用者的文件目錄、應用程式的啟動目錄，以及應用程式目錄) 的路徑

• 複製檔案及目錄

• 移動檔案及目錄

• 刪除檔案及目錄 (或者將它們移至垃圾桶)

• 列出某個目錄中包含的檔案及目錄

• 建立暫存檔案及資料夾

一旦 File 物件指向某個檔案路徑，您就可以使用 FileStream 類別，經由這個路徑來讀取和寫入檔案資料。

File 物件可以指向還不存在的檔案或目錄路徑。因此，您可以使用這類 File 物件建立檔案或目錄。

每一個 File 物件都有兩個屬性，每一個屬性都會定義自己的路徑：

File 類別包含可在 Mac OS、Windows 和 Linux 中指向標準目錄的靜態屬性。這些屬性包括：

這些屬性在不同作業系統上各有不同的值。例如，Mac 和 Windows 對於使用者的桌面目錄各有不同的原生路徑。不過，File.desktopDirectory 屬性會指向每個平台上適當的目錄路徑。若要撰寫可跨平台使用的應用程式，請使用此屬性做為基礎，讓應用程式參照到所用的其他目錄和檔案。然後使用 resolvePath() 方法來修改路徑。例如，此程式碼會指向應用程式儲存目錄中的 preferences.xml 檔案：

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

雖然 File 類別可讓您指向特定檔案路徑，但這麼做會讓應用程式無法跨平台使用。例如，C:\Documents and Settings\joe\ 這個路徑僅適用於 Windows。因此，最好使用 File 類別的靜態屬性，如 File.documentsDirectory。

這些目錄的實際原生路徑將隨作業系統與電腦組態而異。在這個表格顯示的路徑為一般範例。您應該總是使用適當的靜態 File 類別屬性以參照這些目錄，這樣您的應用程式即可在任何平台上正常運作。在實際的 AIR 應用程式中，會從應用程式描述器取得表格中顯示的 applicationID 與 filename 值。如果您在應用程式描述器中指定發行者 ID，那麼發行者 ID 會附加至這些路徑中的應用程式 ID。userName 的值是安裝使用者的帳戶名稱。

若要為電視版 AIR 裝置的系統檔案提供安全性，AIR 應用程式只能存取一組受限的目錄。電視版 AIR 會禁止應用程式存取任何其他目錄。此外，電視版 AIR 會為每個 AIR 應用程式隔離每個使用者的使用者特定資料。

AIR 應用程式會使用僅適用於 ActionScript 3.0 的目錄名稱。這些名稱並不代表裝置上的實際目錄。電視版 AIR 會將這些 ActionScript 3.0 目錄名稱對應至實際的裝置目錄。這些對應會保護電視版 AIR 應用程式，使其避免在惡意或意外的情況下存取不屬於它們的本機檔案。

ActionScript 3.0 目錄名稱如下：

如果應用程式嘗試存取禁止的目錄，執行階段會擲出 ActionScript 程式碼可以捕捉的例外。

下表顯示各種 File 屬性與方法的 File.nativePath 值。這些值會反映裝置檔案系統的應用程式受限檢視。

另外請考慮下列方法在電視版 AIR 裝置的行為：

有多種方式可以將 File 物件設定為指向某個目錄。

有多種方式可以設定 File 物件指向的目標檔案。

您也可以呼叫 resolvePath() 方法，或者修改現有 File 物件的 nativePath 或 url 屬性，修改 File 物件的路徑，如下列範例所示 (適用於 Windows)：

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

使用 nativePath 屬性時，請使用正斜線 (/) 字元，做為路徑分隔字元。在 Windows 上，您亦可使用反斜線 (\) 字元，但不建議這麼做，因為這樣會導致程式碼無法跨平台運作。

在 AIR 中定義 File 物件的 url 屬性時，您可以使用下列任何 URL 配置：

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

您可以使用 getRelativePath() 方法，尋找兩個檔案之間的相對路徑：

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

getRelativePath() 方法的第二個參數 useDotDot 允許在結果中傳回 .. 語法，以指出上層目錄：

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

檔案和路徑名稱在 Windows 和 Mac OS 中不會區分大小寫。在下列範例中，兩個 File 物件會指向相同的檔案：

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

不過，文件和目錄名稱則包含大小寫。例如，下列範例會假設在 documents 目錄中有名為 AIR Test 的資料夾：

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

canonicalize() 方法會轉換 nativePath 物件，為檔案或目錄名稱使用正確的大小寫。在區分大小寫的檔案系統上 (例如 Linux)，當同時存在多個僅名稱大小寫不同的檔案時，canonicalize() 方法就會調整路徑來對應所找到的第一個檔案 (尋找的順序由檔案系統決定)。

您也可以使用 canonicalize() 方法，將短檔名 (「8.3」名稱) 轉換為長檔名 (適用於 Windows)，如下列範例所示：

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

各種作業系統都支援套件檔案和符號連結檔案：

套件—在 Mac OS 中，目錄可以指定為套件，並在 Mac OS Finder 中顯示為單一檔案，而非顯示為目錄。

符號連結—Mac OS、Linux 和 Windows Vista 皆支援符號連結。符號連結可讓檔案指向磁碟上的另一個檔案或目錄。符號連結與別名相似，但卻不同。別名一定會回報為檔案 (而非目錄)，而且讀取或寫入別名或捷徑絕不會影響它所指向的原始檔案或目錄。另一方面，符號連結的行為和它所指向的符號或目錄完全相同。它可以回報為檔案或目錄，而且讀取或寫入符號連結會影響它所指向的原始檔案或目錄，而非符號連結本身。此外，在 Windows 中，對於參考連接點 (在 NTFS 檔案系統中使用) 的 File 物件，isSymbolicLink 屬性是設定為 true。

File 類別包含 isPackage 和 isSymbolicLink 屬性，可用於檢查 File 物件參考的是套件還是符號連結。

下列程式碼會重複執行使用者的桌面目錄，並列出「不是」套件的子目錄：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !!desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

下列程式碼會重複執行使用者的桌面目錄，並列出「不是」符號連結的檔案和目錄：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

canonicalize() 方法會變更符號連結的路徑，使其指向該連結所參考的檔案或目錄。下列程式碼會重複執行使用者的桌面目錄，並回報本身為符號連結之檔案所參考的路徑：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

File 物件的 spaceAvailable 屬性表示在 File 位置的可用空間 (以位元組為單位)。例如，下列程式碼會檢查應用程式儲存目錄中的可用空間：

trace(File.applicationStorageDirectory.spaceAvailable); 

如果 File 物件參考目錄，則 spaceAvailable 屬性會指出目錄中檔案可使用的空間。如果 File 物件參考檔案，則 spaceAvailable 屬性會指出檔案可成長的空間。如果檔案位置不存在，spaceAvailable 屬性會設定為 0。如果 File 物件參考符號連結，則 spaceAvailable 屬性會設定為符號連結所指向位置的可用空間。

目錄或檔案的可用空間通常與包含目錄或檔案之磁碟中的可用空間相同。不過，可用空間可能會將帳戶配額和每個目錄限制納入考量。

將檔案或目錄加入至磁碟，通常需要比檔案實際大小或目錄內容大小更大的空間。例如，作業系統可能需要更多空間來儲存索引資訊。必要的磁區也可能會使用額外的空間。此外，可用空間會動態變更。因此，您無法預期為檔案儲存區配置「所有」空間。如需有關在檔案系統中寫入資料的詳細資訊，請參閱讀取和寫入檔案。

StorageVolumeInfo.getStorageVolumes() 方法提供掛接式儲存體磁碟區的詳細資訊 (請參閱使用儲存空間)。

在 AIR 2 中，您可以使用作業系統註冊的應用程式來開啟檔案。例如，AIR 應用程式可以使用註冊的應用程式來開啟 DOC 檔案。使用 File 物件的 openWithDefaultApplication() 方法開啟檔案。例如，以下程式碼使用 DOC 檔案的預設應用程式來開啟使用者桌面上名稱為 test.doc 檔案：

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

以下程式碼可以讓使用者瀏覽 mp3 檔案，然後使用 mp3 檔案的預設播放應用程式來開啟它。

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

您不可以將 openWithDefaultApplication() 方法用於應用程式目錄中的檔案。

AIR 會禁止您使用 openWithDefaultApplication() 方法開啟特定的檔案。在 Windows 上，AIR 會禁止開啟特定檔案類型的檔案，例如 EXE 或 BAT。在 Mac OS 和 Linux 上，AIR 會讓您無法開啟以特定應用程式啟動的檔案 (這些包括 Mac OS 上的 Terminal 和 AppletLauncher，以及 Linux 上的 csh、bash 或 ruby)。嘗試使用 openWithDefaultApplication() 方法開啟這些檔案會產生例外。如需禁止的檔案類型詳細清單，請參閱 File.openWithDefaultApplication() 方法的語言參考項目。