Clipboard 資料格式

使用自訂資料格式將物件寫入至剪貼簿時，可以從剪貼簿將物件資料當做參考來讀取，或當做原始物件的序列化副本來讀取。有四種傳輸模式，供您判斷物件傳輸形式是一項參考或已序列化的副本：

在剪貼簿中寫入物件時，除了在 format 參數開頭保留當做前置詞使用的 air: 或 flash: 以外，您可以使用任何字串。使用代表該格式的相同字串即可讀取物件。下列範例說明如何在剪貼簿中讀取與寫入物件：

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

若要從剪貼簿物件中擷取已序列化的物件 (在執行放入或貼上作業後)，請使用相同的格式名稱以及 CLONE_ONLY 或 CLONE_PREFFERED 轉換模式。

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

參考一律會加入至 Clipboard 物件。若要 (在拖放或貼上作業之後) 從剪貼簿物件擷取參考，請使用 ORIGINAL_ONLY 或 ORIGINAL_PREFFERED 轉換模式，而不要使用經過序列化的副本：

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

物件參考只有在 Clipboard 物件源自目前的應用程式時才有效。使用 ORIGINAL_PREFFERED 轉換模式，即可在參考可用時存取參考；而無法使用參考時，則存取經過序列化的副本。

下列範例會說明如何實作延遲顯示函數。

當使用者按下「複製」按鈕時，應用程式會清除系統剪貼簿中的資料，確保不會留下任何之前剪貼簿作業所產生的資料。接著，setDataHandler() 方法會將 renderData() 函數設定為剪貼簿輸出器。

當使用者從目的地文字欄位的快顯選單選取「貼上」命令時，應用程式會存取剪貼簿並設定目的地文字。由於已經使用函數 (而非字串) 設定了剪貼簿中的文字資料格式，因此剪貼簿會呼叫 renderData() 函數。renderData() 函數傳回來源文字的內容，然後再指定給目標文字。

請注意，如果您編輯了來源文字後按「貼上」按鈕，貼上的文字就會反映編輯結果，即使您是在按下「複製」按鈕後才進行編輯也一樣。這是因為延遲顯示函數會等到您按「貼上」按鈕才複製來源文字 (若在實用性質的應用程式中使用延遲顯示函數，您可能需要設法儲存或保護來源文字以免發生此問題)。

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>