其他优化

当使用 TextField 类的 text 属性时，请使用 appendText() 方法，而不是 += 运算符。使用 appendText() 方法可改进性能。

例如，以下代码使用 += 运算符，循环需要 1120 毫秒才能完成：

addChild ( myTextField ); 
  
myTextField.autoSize = TextFieldAutoSize.LEFT; 
var started:Number = getTimer(); 
  
for (var i:int = 0; i< 1500; i++ ) 
{ 
    myTextField.text += "ActionScript 3"; 
} 
  
trace( getTimer() - started ); 
// output : 1120 

在以下示例中， += 运算符被替换为 appendText() 方法：

var myTextField:TextField = new TextField(); 
addChild ( myTextField ); 
myTextField.autoSize = TextFieldAutoSize.LEFT; 
  
var started:Number = getTimer(); 
  
for (var i:int = 0; i< 1500; i++ ) 
{ 
    myTextField.appendText ( "ActionScript 3" ); 
} 
 
trace( getTimer() - started ); 
// output : 847 

现在，代码只需 847 毫秒即可完成。

通过简单的技术即可进一步优化此代码。在每个循环中更新文本字段会使用很多内部处理。通过仅连接一个字符串并将其分配给循环外的文本字段，可大大减少运行代码所需的时间。此代码现在仅需要 2 毫秒即可完成：

var myTextField:TextField = new TextField(); 
addChild ( myTextField ); 
myTextField.autoSize = TextFieldAutoSize.LEFT; 
 
var started:Number = getTimer(); 
var content:String = myTextField.text; 
  
for (var i:int = 0; i< 1500; i++ ) 
{ 
    content += "ActionScript 3"; 
} 
  
myTextField.text = content; 
  
trace( getTimer() - started ); 
// output : 2 

处理 HTML 文本时，前一种方法速度太慢，以致在某些情况下可能会在 Flash Player 中引发 Timeout 异常。例如，如果基础硬件速度太慢，则可能会引发异常。

var myTextField:TextField = new TextField(); 
addChild ( myTextField ); 
myTextField.autoSize = TextFieldAutoSize.LEFT; 
  
var started:Number = getTimer(); 
  
for (var i:int = 0; i< 1500; i++ ) 
{ 
    myTextField.htmlText += "ActionScript <b>2</b>"; 
} 
 
trace( getTimer() - started ); 

通过将此值分配给循环外的字符串，此代码将仅需要 29 毫秒即可完成：

var myTextField:TextField = new TextField(); 
addChild ( myTextField ); 
myTextField.autoSize = TextFieldAutoSize.LEFT; 
  
var started:Number = getTimer(); 
var content:String = myTextField.htmlText; 
  
for (var i:int = 0; i< 1500; i++ ) 
{ 
    content += "<b>ActionScript<b> 3"; 
} 
  
myTextField.htmlText = content; 
  
trace ( getTimer() - started ); 
// output : 29 

使用中括号运算符可能会降低性能。将您的引用存储在本地变量中可避免使用该运算符。以下代码示例演示了使用中括号运算符的效率很低：

var lng:int = 5000; 
var arraySprite:Vector.<Sprite> = new Vector.<Sprite>(lng, true); 
var i:int; 
  
for ( i = 0; i< lng; i++ ) 
{ 
    arraySprite[i] = new Sprite(); 
} 
  
var started:Number = getTimer(); 
  
for ( i = 0; i< lng; i++ ) 
{ 
    arraySprite[i].x = Math.random()*stage.stageWidth; 
    arraySprite[i].y = Math.random()*stage.stageHeight; 
    arraySprite[i].alpha = Math.random(); 
    arraySprite[i].rotation = Math.random()*360; 
} 
  
trace( getTimer() - started ); 
// output : 16 

以下优化的版本减少了对中括号运算符的使用：

var lng:int = 5000; 
var arraySprite:Vector.<Sprite> = new Vector.<Sprite>(lng, true); 
var i:int; 
  
for ( i = 0; i< lng; i++ ) 
{ 
    arraySprite[i] = new Sprite(); 
} 
  
var started:Number = getTimer(); 
var currentSprite:Sprite; 
  
for ( i = 0; i< lng; i++ ) 
{ 
    currentSprite = arraySprite[i]; 
     currentSprite.x = Math.random()*stage.stageWidth; 
     currentSprite.y = Math.random()*stage.stageHeight; 
     currentSprite.alpha = Math.random(); 
     currentSprite.rotation = Math.random()*360; 
} 
  
trace( getTimer() - started ); 
// output : 9 

调用函数成本很高。尝试通过移动内联代码来减少函数的调用次数。移动内联代码是优化代码以获得良好性能的一种好方法。但请注意，使用内联代码可能会使代码很难重复使用，还会增加 SWF 文件的大小。一些函数调用（如 Math 类方法）很容易以内联的方式移动。以下代码使用 Math.abs() 方法计算绝对值：

const MAX_NUM:int = 500000; 
var arrayValues:Vector.<Number>=new Vector.<Number>(MAX_NUM,true); 
var i:int; 
  
for (i = 0; i< MAX_NUM; i++) 
{ 
    arrayValues[i] = Math.random()-Math.random(); 
} 
  
var started:Number = getTimer(); 
var currentValue:Number; 
  
for (i = 0; i< MAX_NUM; i++) 
{ 
    currentValue = arrayValues[i]; 
    arrayValues[i] = Math.abs ( currentValue ); 
} 
  
trace( getTimer() - started ); 
// output : 70

由 Math.abs() 执行的计算可以手动完成并以内联方式移动：

const MAX_NUM:int = 500000; 
var arrayValues:Vector.<Number>=new Vector.<Number>(MAX_NUM,true); 
var i:int; 
  
for (i = 0; i< MAX_NUM; i++) 
{ 
    arrayValues[i] = Math.random()-Math.random(); 
} 
  
var started:Number = getTimer(); 
var currentValue:Number; 
  
for (i = 0; i< MAX_NUM; i++) 
{ 
    currentValue = arrayValues[i]; 
    arrayValues[i] = currentValue > 0 ? currentValue : -currentValue; 
} 
  
trace( getTimer() - started ); 
// output : 15

以内联方式移动函数调用可使代码运行速度提高四倍以上。这种方法适用于多种情况，但要注意它对可重用性和可维护性的影响。

不计算循环中的语句也可实现优化。以下代码遍历数组，但未进行优化，因为在每次遍历时都需要计算数组长度：

for (var i:int = 0; i< myArray.length; i++) 
{ 
}

最好存储该值并重复使用：

var lng:int = myArray.length; 
 
for (var i:int = 0; i< lng; i++) 
{ 
}

以相反顺序进行 while 循环的速度比正向循环快：

var i:int = myArray.length; 
 
while (--i > -1) 
{ 
}

这些技巧提供了几种优化 ActionScript 的方法，说明了单行代码如何影响性能和内存。还可能存在许多其他的 ActionScript 优化。有关详细信息，请参阅以下链接： http://www.rozengain.com/blog/2007/05/01/some-actionscript-30-optimizations/ 。

Twitter™ 与 Facebook 中的内容不在 Creative Commons 的条款约束之下。