数据类型

在较大的项目中通常建议使用编译时类型检查，因为随着项目变大，相对于尽早捕获类型错误，数据类型的灵活性通常会变得不那么重要。这就是为什么将 Flash Professional 和 Flash Builder 中的 ActionScript 编译器默认设置为在严格模式下运行的原因。

为了提供编译时类型检查，编译器需要知道代码中的变量或表达式的数据类型信息。为了显式声明变量的数据类型，请在变量名后面添加后跟数据类型的冒号运算符 ( : ) 作为其后缀。要将数据类型与参数相关联，应使用后跟数据类型的冒号运算符。例如，下面的代码向 xParam 参数中添加数据类型信息，并用显式数据类型声明变量 myParam ：

function runtimeTest(xParam:String) 
{ 
    trace(xParam); 
} 
var myParam:String = "hello"; 
runtimeTest(myParam);

在严格模式下，ActionScript 编译器将类型不匹配报告为编译器错误。例如，下面的代码声明一个 Object 类型的函数参数 xParam ，但是之后又尝试向该参数赋予 String 类型和 Number 类型的值。这在严格模式下会产生编译器错误。

function dynamicTest(xParam:Object) 
{ 
    if (xParam is String) 
    { 
        var myStr:String = xParam; // compiler error in strict mode 
        trace("String: " + myStr); 
    } 
    else if (xParam is Number) 
    { 
        var myNum:Number = xParam; // compiler error in strict mode 
        trace("Number: " + myNum); 
    } 
}

但是，即使在严格模式下，也可以选择不在赋值语句右侧指定类型，从而退出编译时类型检查。可以通过省略类型注释或使用特殊的星号 ( * ) 类型注释，来将变量或表达式标记为无类型。例如，如果对上一个示例中的 xParam 参数进行修改，使其不再有类型注释，则代码会在严格模式下进行编译：

function dynamicTest(xParam) 
{ 
    if (xParam is String) 
    { 
        var myStr:String = xParam; 
        trace("String: " + myStr); 
    } 
    else if (xParam is Number) 
    { 
        var myNum:Number = xParam; 
        trace("Number: " + myNum); 
    } 
} 
dynamicTest(100) 
dynamicTest("one hundred");

在 ActionScript 3.0 中，无论是在严格模式下还是在标准模式下编译，在运行时都将进行类型检查。请考虑以下情形：将值 3 作为一个参数传递给需要数组的函数。在严格模式下，编译器将生成一个错误，因为值 3 与 Array 数据类型不兼容。如果您禁用严格模式而在标准模式下运行，则编译器不会指出类型不匹配，但在运行时进行类型检查时会产生运行时错误。

下面的示例演示一个名为 typeTest() 的函数，该函数需要一个 Array 参数，但传递的值却是 3。在标准模式下这会产生运行时错误，因为值 3 不是参数声明的数据类型 (Array) 的成员。

function typeTest(xParam:Array) 
{ 
    trace(xParam); 
} 
var myNum:Number = 3; 
typeTest(myNum);  
// run-time error in ActionScript 3.0 standard mode

还可能会出现如下情形：即使在严格模式下运行，也可能会获得运行时类型错误。如果您使用严格模式，但是通过使用无类型变量而退出了编译时类型检查，就可能会出现上述情形。当您使用无类型变量时，并不会消除类型检查，而只是将其延迟到运行时执行。例如，如果上一个示例中的 myNum 变量没有已声明的数据类型，则编译器无法检测到类型不匹配，但代码会生成运行时错误，因为它会将 myNum 的运行时值（赋值语句将其设为 3）与 xParam 的类型（设置为 Array 数据类型）进行比较。

function typeTest(xParam:Array) 
{ 
    trace(xParam); 
} 
var myNum = 3; 
typeTest(myNum);  
// run-time error in ActionScript 3.0

与编译时类型检查相比，运行时类型检查还允许更灵活地使用继承。标准模式会将类型检查延迟到运行时执行，从而使您可以引用子类的属性，即使您 上传 也是如此。当您使用基类来声明类实例的类型，但是使用子类来实例化类实例时，就会发生上传。例如，您可以创建一个名为 ClassBase 的可扩展类（具有 final 属性的类不能扩展）：

class ClassBase 
{ 
}

随后，您可以创建一个名为 ClassExtender 的 ClassBase 子类，该子类具有一个名为 someString 的属性，如下所示：

class ClassExtender extends ClassBase 
{ 
    var someString:String; 
}

通过使用这两个类，可以创建一个使用 ClassBase 数据类型进行声明、但使用 ClassExtender 构造函数进行实例化的类实例。上传被视为安全操作，这是因为基类不包含子类中没有的任何属性或方法。

var myClass:ClassBase = new ClassExtender();

但是，子类中则包含其基类中没有的属性或方法。例如，ClassExtender 类中包含 someString 属性，该属性在 ClassBase 类中不存在。在 ActionScript 3.0 标准模式下，可以使用 myClass 实例来引用此属性，而不会生成编译时错误，如下面的示例所示：

var myClass:ClassBase = new ClassExtender(); 
myClass.someString = "hello"; 
// no error in ActionScript 3.0 standard mode

is 运算符可用来测试变量或表达式是否为给定数据类型的成员。在早期的 ActionScript 版本中，此功能由 instanceof 运算符提供。但在 ActionScript 3.0 中，不应使用 instanceof 运算符来测试变量或表达式是否为数据类型的成员。对于手动类型检查，应用 is 运算符来代替 instanceof 运算符，因为表达式 x instanceof y 只是在 x 的原型链中检查 y 是否存在（在 ActionScript 3.0 中，原型链不能全面地描述继承层次）。

is 运算符检查正确的继承层次，不但可以用来检查对象是否为特定类的实例，而且还可以检查对象是否是用来实现特定接口的类的实例。下面的示例创建 Sprite 类的一个名为 mySprite 的实例，并使用 is 运算符来测试 mySprite 是否为 Sprite 和 DisplayObject 类的实例，以及它是否实现 IEventDispatcher 接口：

var mySprite:Sprite = new Sprite(); 
trace(mySprite is Sprite); // true 
trace(mySprite is DisplayObject);// true 
trace(mySprite is IEventDispatcher); // true

is 运算符检查继承层次，并正确地报告 mySprite 与 Sprite 和 DisplayObject 类兼容（Sprite 类是 DisplayObject 类的子类）。 is 运算符还检查 mySprite 是否是从实现 IEventDispatcher 接口的任意类继承的。由于 Sprite 类是从实现 IEventDispatcher 接口的 EventDispatcher 类继承的，因此 is 运算符会正确地报告 mySprite 也实现该接口。

下面的示例说明与上一个示例相同的测试，但使用的是 instanceof 运算符，而不是 is 运算符。 instanceof 运算符正确地识别出 mySprite 是 Sprite 或 DisplayObject 的实例，但是，当该运算符用于测试 mySprite 是否实现 IEventDispatcher 接口时，返回的却是 false 。

trace(mySprite instanceof Sprite); // true 
trace(mySprite instanceof DisplayObject);// true 
trace(mySprite instanceof IEventDispatcher); // false

as 运算符也可用来检查表达式是否为给定数据类型的成员。但是，与 is 运算符不同的是， as 运算符不返回布尔值。 as 运算符返回表达式的值（代替 true ）或 null （代替 false ）。下面的示例演示在检查 Sprite 实例是否为 DisplayObject、IEventDispatcher 和 Number 数据类型的成员这样的简单情况下，使用 as 运算符替代 is 运算符的结果。

var mySprite:Sprite = new Sprite(); 
trace(mySprite as Sprite);                 // [object Sprite] 
trace(mySprite as DisplayObject);                 // [object Sprite] 
trace(mySprite as IEventDispatcher);                 // [object Sprite] 
trace(mySprite as Number);                                       // null

在使用 as 运算符时，右侧的操作数必须是数据类型。如果尝试使用表达式（而非数据类型）作为右侧的操作数，将会产生错误。

Boolean 数据类型包含两个值： true 和 false 。对于 Boolean 类型的变量，其他任何值都是无效的。已经声明但尚未初始化的布尔变量的默认值是 false 。

int 数据类型在内部存储为 32 位整数，包含的整数集从

-2,147,483,648 (-2 ³¹ ) 至 2,147,483,647 (2 ³¹ - 1) 之间（两端包含在内）。早期的 ActionScript 版本仅提供 Number 数据类型，该数据类型既可用于整数又可用于浮点数。在 ActionScript 3.0 中，现在可以访问 32 位带符号整数和无符号整数的低位机器类型。如果您的变量不需要浮点数，那么，使用 int 数据类型来代替 Number 数据类型会更快更高效。

对于小于 int 的最小值或大于 int 的最大值的整数值，应使用 Number 数据类型。Number 数据类型可以处理 -9,007,199,254,740,992 和 9,007,199,254,740,992（53 位整数值）之间的值。int 数据类型的变量的默认值是 0。

Null 数据类型仅包含一个值： null 。这是 String 数据类型和用来定义复杂数据类型的所有类（包括 Object 类）的默认值。其他基元数据类型（如 Boolean、Number、int 和 uint）均不包含 null 值。在运行时，如果尝试将 null 分配给 Boolean、Number、int 或 uint 类型的变量，则值 null 会转换为相应的默认值。不能将 Null 数据类型用作类型注释。

在 ActionScript 3.0 中，Number 数据类型可以表示整数、无符号整数和浮点数。但是，为了尽可能提高性能，应将 Number 数据类型仅用于浮点数，或者用于 int 和 uint 类型可以存储的、大于 32 位的整数值。要存储浮点数，数字中应包括一个小数点。如果您省略小数点，数字将存储为整数。

Number 数据类型使用由 IEEE 二进制浮点算术标准 (IEEE-754) 指定的 64 位双精度格式。此标准规定如何使用 64 个可用位来存储浮点数。其中的 1 位用来指定数字是正数还是负数。11 位用于指数，以 2 为底进行存储。其余的 52 位用于存储 有效位数 （又称为 尾数 ），有效位数是 2 的 N 次幂，N 即前面所提到的指数。

可以将 Number 数据类型的所有位都用于有效位数，也可以将 Number 数据类型的某些位用于存储指数，后者可存储的浮点数比前者大得多。例如，如果 Number 数据类型使用全部 64 位存储有效位数，则可以存储的最大数字为 2 ⁶⁵ - 1。如果使用 11 位存储指数，则 Number 数据类型可以存储的最大有效数字为 2 ¹⁰²³ 。

Number 类型可以表示的最大值和最小值存储在 Number 类的名为 Number.MAX_VALUE 和 Number.MIN_VALUE 的静态属性中。

Number.MAX_VALUE == 1.79769313486231e+308 
Number.MIN_VALUE == 4.940656458412467e-324

尽管这个数字范围很大，但代价是此范围的精度有所降低。Number 数据类型使用 52 位来存储有效位数，因此，那些要求用 52 位以上的位数才能精确表示的数字（如分数 1/3）将只是近似值。如果应用程序要求小数达到绝对精度，则需要使用实现小数浮点算术（而非二进制浮点算术）的软件。

如果用 Number 数据类型来存储整数值，则仅使用 52 位有效位数。Number 数据类型使用这 52 位和一个特殊的隐藏位来表示从 -9,007,199,254,740,992 (-2 ⁵³ ) 到 9,007,199,254,740,992 (2 ⁵³ ) 的整数。

NaN 值不仅用作 Number 类型的变量的默认值，还用作应返回数字却没有返回数字的任何运算的结果。例如，如果您尝试计算负数的平方根，结果会是 NaN 。其他特殊的 Number 值包括 正无穷大 和 负无穷大 。

String 数据类型表示一个 16 位字符的序列。字符串在内部存储为 Unicode 字符，并使用 UTF-16 格式。字符串是不可改变的值，就像在 Java 编程语言中一样。对字符串值的操作返回字符串的一个新的实例。用字符串数据类型声明的变量的默认值是 null 。值 null 与空字符串 ( "" ) 不同。值 null 表示变量中未存储任何值，而空字符串表示变量中有一个 String 值，但其中不包含任何字符。

uint 数据类型在内部存储为 32 位无符号整数，包含的整数集介于 0 和 4,294,967,295 (2 ³² - 1) 之间（包括 0 和 4,294,967,295）。uint 数据类型可用于要求非负整数的特殊情形。例如，必须使用 uint 数据类型来表示像素颜色值，因为 int 数据类型有一个内部符号位，该符号位并不适合处理颜色值。对于大于 uint 的最大值的整数值，应使用 Number 数据类型，该数据类型可以处理 53 位整数值。uint 数据类型的变量的默认值是 0。

void 数据类型仅包含一个值： undefined 。在早期的 ActionScript 版本中， undefined 是 Object 类实例的默认值。在 ActionScript 3.0 中，Object 实例的默认值是 null 。如果您尝试将值 undefined 赋予 Object 类的实例，则该值会转换为 null 。您只能为无类型变量赋予 undefined 这一值。无类型变量是指缺乏类型注释或者使用星号 ( * ) 作为类型注释的变量。您可以将 void 只用作返回类型注释。

Object 数据类型是由 Object 类定义的。Object 类用作 ActionScript 中的所有类定义的基类。ActionScript 3.0 中的 Object 数据类型与早期版本中的 Object 数据类型存在以下三方面的区别：第一，Object 数据类型不再是指定给没有类型注释的变量的默认数据类型。第二，Object 数据类型不再包括 undefined 这一值，该值以前是 Object 实例的默认值。第三，在 ActionScript 3.0 中，Object 类实例的默认值是 null 。

在早期的 ActionScript 版本中，会自动为没有类型注释的变量赋予 Object 数据类型。ActionScript 3.0 现在包括真正无类型变量这一概念，因此不再为没有类型注释的变量赋予 Object 数据类型。没有类型注释的变量现在被视为无类型变量。如果您希望向代码的读者清楚地表明您是故意将变量保留为无类型，可以使用星号 ( * ) 表示类型注释，这与省略类型注释等效。下面的示例演示两条等效的语句，两者都声明一个无类型变量 x ：

var x 
var x:*

只有无类型变量才能保存值 undefined 。如果您尝试将值 undefined 赋给具有数据类型的变量，则运行时会将值 undefined 转换为该数据类型的默认值。对于 Object 数据类型的实例，默认值为 null ，这表示如果您尝试将 undefined 分配给 Object 实例，该值会转换为 null 。