使用对象

用于指定为响应特定事件而执行的特定操作的技术称为 事件处理 。在编写执行事件处理的 ActionScript 代码时，您需要识别三个重要元素：

• 事件源：发生该事件的是哪个对象？例如，单击了哪个按钮，或哪个 Loader 对象正在加载图像？事件源也称为 事件目标 。之所以有此名称，是因为它是计算机确定事件的目标位置的对象（也就是说，实际发生事件的位置）。

• 事件：将要发生什么事情，以及您希望响应什么事情？识别特定事件非常重要，因为许多对象都会触发多个事件。

• 响应：当事件发生时，您希望执行哪些步骤？

无论何时编写 ActionScript 代码来处理事件，都要求使用这三个元素。代码遵循以下基本结构（粗体元素是占位符，您要根据自己的具体情况填充）：

function eventResponse(eventObject:EventType):void 
{ 
    // Actions performed in response to the event go here. 
} 
  
eventSource.addEventListener(EventType.EVENT_NAME, eventResponse);

此代码完成两项任务。首先，定义一个函数，这是指定为响应事件而要执行的动作的方法。其次，调用源对象的 addEventListener() 方法。调用 addEventListener() 实质上是为指定事件“订阅”此函数。该事件发生时，将执行函数的动作。让我们更详细地讨论其中每个部分。

函数 是提供了一种方法，可以将若干个操作用类似快捷名称的单个名称组合在一起，通过这个单个名称执行这些操作。除了不必与特定类关联之外，函数与方法完全相同。（事实上，术语“方法”可定义为与特定类相关联的函数。）在创建用于事件处理的函数时，请选择函数名称（本示例中名为 eventResponse ）。还要指定一个参数（本示例中名为 eventObject ）。指定函数参数类似于声明变量，所以还必须指明参数的数据类型。（在本示例中，该参数的数据类型为 EventType 。）

您要侦听的每种事件类型都有一个与其相关联的 ActionScript 类。为函数参数指定的数据类型始终是与您要响应的特定事件关联的类。例如， click 事件（在用户使用鼠标单击某个项目时触发）与 MouseEvent 类相关联。若要为 click 事件编写侦听器函数，可使用数据类型为 MouseEvent 的参数定义侦听器函数。最后，在左大括号与右大括号之间 ( { ... } ) 编写希望计算机在事件发生时执行的指令。

事件处理函数已编写。下一步要告知事件源对象（发生该事件的对象，如按钮）您希望其在该事件发生时调用此函数。通过调用该事件源对象的 addEventListener() 方法向该对象注册您的函数（所有包含事件的对象也都具有 addEventListener() 方法）。 addEventListener() 方法有两个参数：

• 第一个参数是您希望响应的特定事件的名称。每个事件都与一个特定类相关联。每个事件类都为其中每一个事件定义了一个特殊的值，就像唯一名称。对第一个参数使用该值。

• 第二个参数是事件响应函数的名称。请注意，如果将函数名称作为参数进行传递，则在写入函数名称时不使用括号。

下面分步描述了创建事件侦听器时执行的过程。在本例中，您将创建一个侦听器函数，在单击名为 myButton 的对象时调用该函数。

程序员实际编写的代码如下所示：

function eventResponse(event:MouseEvent):void 
{ 
    // Actions performed in response to the event go here. 
} 
 
myButton.addEventListener(MouseEvent.CLICK, eventResponse);

下面是此代码运行时的实际工作方式：

1. 加载 SWF 文件时，计算机会注意到有一个名为 eventResponse() 的函数。

   查看完全大小图形

2. 计算机随后运行该代码（具体地说，是指不在函数中的代码行）。在本例中，只有一行代码：针对事件源对象（名为 myButton ）调用 addEventListener() 方法，并将 eventResponse 函数作为参数进行传递。

   查看完全大小图形

   在内部， myButton 保留正在监听其各个事件的函数的列表。调用 addEventListener() 方法时， myButton 将 eventResponse() 函数存储到其事件侦听器列表中。

   查看完全大小图形

3. 在某一时刻，用户单击 myButton 对象以触发其 click 事件（在代码中将其标识为 MouseEvent.CLICK ）。

   

   此时发生了以下事件：

   1. 创建对象，该对象是与发生的事件（此示例中为 MouseEvent）相关联的类的实例。对很多事件而言，此对象是 Event 类的实例。对鼠标事件而言，它是 MouseEvent 实例。对其他事件而言，它是与该事件关联的类的实例。创建的此对象称为 事件对象 ，包含有关所发生的事件的特定信息：事件类型、发生位置以及其他特定于事件的信息（如果适用）。

      查看完全大小图形

   2. 计算机随后查看 myButton 存储的事件侦听器的列表。它逐个查看这些函数，以调用每个函数并将事件对象作为参数传递给该函数。由于 eventResponse() 函数是 myButton 的侦听器之一，因此，计算机将在此过程中调用 eventResponse() 函数。

      查看完全大小图形

   3. 当调用 eventResponse() 函数时，将运行该函数中的代码，因此，将执行您指定的动作。

      查看完全大小图形

以下是事件处理代码的更多实际示例。给出这些示例，旨在提供关于编写事件处理代码时可以使用的一些常见事件元素及可用变体的建议：

• 单击按钮开始播放当前的影片剪辑。在下面的示例中， playButton 是按钮的实例名称，而 this 是表示“当前对象”的特殊名称：

  this.stop(); 
   
  function playMovie(event:MouseEvent):void 
  { 
      this.play(); 
  } 
   
  playButton.addEventListener(MouseEvent.CLICK, playMovie);

• 检测文本字段中的键入操作。在下面的示例中， entryText 是一个输入文本字段，而 outputText 是一个动态文本字段：

  function updateOutput(event:TextEvent):void 
  { 
      var pressedKey:String = event.text; 
      outputText.text = "You typed: " + pressedKey; 
  } 
   
  entryText.addEventListener(TextEvent.TEXT_INPUT, updateOutput);

• 单击按钮导航到一个 URL。在本例中， linkButton 是该按钮的实例名称：

  function gotoAdobeSite(event:MouseEvent):void 
  { 
      var adobeURL:URLRequest = new URLRequest("http://www.adobe.com/"); 
      navigateToURL(adobeURL); 
  } 
   
  linkButton.addEventListener(MouseEvent.CLICK, gotoAdobeSite);