影片剪辑示例：RuntimeAssetsExplorer

若要使浏览器与 SWF 库正确交互，运行时资源库的结构就必须具有一定程式。我们将通过创建一个接口来完成此过程（接口类似于类，因为接口也是用于区分预期结构的方法的蓝图；同时接口又与类不同，因为接口不包含方法体）。接口提供了在运行时库和浏览器之间相互通信的方法。加载到浏览器中的运行时资源的每个 SWF 都将实现此接口。有关接口及其使用方法的更多信息，请参阅《学习 ActionScript 3.0》中的“接口”。

RuntimeLibrary 接口非常简单 — 我们只需要一个函数，这个函数能够为浏览器提供类路径的数组以导出元件并使元件在运行时库中可用。为此，该接口具有单个方法： getAssets() 。

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

通过定义 RuntimeLibrary 接口，可以创建能够加载到另一个 SWF 文件中的多个资源库 SWF 文件。制作资源的单个 SWF 库包括四个任务：

• 为资源库 SWF 文件创建一个类

• 为库中包含的单个资源创建类

• 创建实际图形资源

• 将图形元素与类关联并发布库 SWF

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

要处理的最后一个功能性部分是资源浏览器的用户界面。在本示例中，运行时库的路径硬编码为一个名为 ASSETS_PATH 的变量。或者，您也可以使用 FileReference 类，例如，用来创建在硬盘驱动器上浏览特定 SWF 文件的接口。

成功加载运行时库后，Flash Player 会调用 runtimeAssetsLoadComplete() 方法：

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

在此方法中，变量 rl 表示已加载的 SWF 文件。代码将调用已加载的 SWF 文件的 getAssets() 方法，获取可用资源的列表，并通过调用 populateDropDown() 方法用这些资源填充具有可用资源列表的 ComboBox 组件。该方法会依次存储每个资源的完整类路径。单击用户界面上的“添加”按扭即会触发 addAsset() 方法：

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

此方法获取 ComboBox 中当前所选资源的类路径 ( assetNameCbo.selectedItem.data )，并使用 getDefinitionByName() 函数（来自 flash.utils 包）获取对该资源的类的实际引用，以创建该资源的新实例。