使用 Capabilities 类

Flash Player 9 和更高版本，Adobe AIR 1.0 和更高版本

开发人员可通过 Capabilities 类来确定正在运行应用程序的环境。使用 Capabilities 类的多种属性，您可以了解用户的系统分辨率，用户的系统是否支持辅助软件、用户操作系统的语言，以及当前安装的 Flash 运行时版本。

通过检查 Capabilities 类的属性，可以自定义应用程序，使其以最佳方式与特定用户环境配合工作。例如，通过检查 Capabilities.screenResolutionX 和 Capabilities.screenResolutionY 属性，可以确定用户系统所使用的显示分辨率，并确定最合适的视频大小。或者，在尝试加载外部 mp3 文件之前，可以检查 Capabilities.hasMP3 属性以查看用户系统是否支持 mp3 播放。

以下代码使用正则表达式分析客户端正在使用的 Flash 运行时版本：

var versionString:String = Capabilities.version; 
var pattern:RegExp = /^(\w*) (\d*),(\d*),(\d*),(\d*)$/; 
var result:Object = pattern.exec(versionString); 
if (result != null) 
{ 
    trace("input: " + result.input); 
    trace("platform: " + result[1]); 
    trace("majorVersion: " + result[2]); 
    trace("minorVersion: " + result[3]);     
    trace("buildNumber: " + result[4]); 
    trace("internalBuildNumber: " + result[5]); 
} 
else 
{ 
    trace("Unable to match RegExp."); 
}

如果要向某个服务器端脚本发送用户的系统功能，以便将信息存储在数据库中，可以使用下面的 ActionScript 代码：

var url:String = "log_visitor.cfm"; 
var request:URLRequest = new URLRequest(url); 
request.method = URLRequestMethod.POST; 
request.data = new URLVariables(Capabilities.serverString); 
var loader:URLLoader = new URLLoader(request);