使用 AIR 中的 File 对象

您可以使用 File 类执行以下操作：

• 获取特殊目录的路径，包括用户目录、用户的文档目录、应用程序的启动目录以及应用程序目录

• 复制文件和目录

• 移动文件和目录

• 删除文件和目录（或将它们移到垃圾桶）

• 列出目录中包含的文件和目录

• 创建临时文件和文件夹

当 File 对象指向文件路径后，您可以通过 FileStream 类使用该 File 对象读取和写入文件数据。

File 对象可以指向尚不存在的文件或目录的路径。创建文件或目录时可以使用这种 File 对象。

每个 File 对象具有两个属性，各属性可分别定义该对象的路径：

File 类包括用于指向 Mac OS、Windows 和 Linux 中的标准目录的静态属性。这些属性包括：

这些属性在不同的操作系统上有不同的值。例如，对于用户的桌面目录，Mac 和 Windows 有各自不同的本机路径。然而，File.desktopDirectory 属性在每个平台上指向适当的目录路径。要编写可以跨平台正常工作的应用程序，在需要引用应用程序使用的其他目录和文件时，请以这些属性为基础，然后使用 resolvePath() 方法来完善路径。例如，此代码会指向应用程序存储目录中的 preferences.xml 文件：

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

尽管可以使用 File 类来指向特定文件路径，但这种做法会指向无法跨平台工作的应用程序。例如，路径 C:\Documents and Settings\joe\ 仅适用于 Windows。出于以上原因，最好使用 File 类的静态属性，如 File.documentsDirectory。

根据具体的操作系统和计算机配置，这些目录的实际本机路径也有所不同。此表中显示的路径是典型示例。您应该始终使用适当的静态 File 类属性引用这些目录，以便您的应用程序在任何平台上都能正常工作。在一个实际的 AIR 应用程序中，表中显示的 applicationID 和 filename 的值取自应用程序描述符。如果您在应用程序描述符中指定发布者 ID，则发布者 ID 在这些路径中会追加到应用程序 ID。userName 的值是安装用户的帐户名称。

为了保护用于电视的 AIR 设备上的系统文件，AIR 应用程序仅可访问一组有限的目录。用于电视的 AIR 禁止应用程序访问任何其他目录。而且，用于电视的 AIR 会为每个 AIR 应用程序隔离每个用户的特定数据。

AIR 应用程序使用仅供 ActionScript 3.0 使用的目录名称。这些名称不代表设备上的实际目录。用于电视的 AIR 会将这些 ActionScript 3.0 目录名称映射到实际设备目录。这样的映射将防止用于电视的 AIR 应用程序恶意或意外地访问不属于它们的本地文件。

ActionScript 3.0 目录名称为：

如果应用程序尝试访问禁止访问的目录，运行时将引发 ActionScript 代码可捕获的异常。

下表显示了各种 File 属性和方法的 File.nativePath 值。这些值反映了应用程序查看设备的文件系统时所受的限制。

此外，请考虑以下方法在用于电视的 AIR 设备上的行为：

可以采用多种不同方式设置 File 对象以使其指向某目录。

可采用多种不同方式设置 File 对象所指向的文件。

通过调用 resolvePath() 方法或通过修改对象的 nativePath 或 url 属性，您还可以修改现有 File 对象的路径，如以下示例中所示（在 Windows 中）：

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

使用 nativePath 属性时，请使用正斜杠 (/) 字符作为目录分隔符。在 Windows 上，还可以使用反斜杠 (\) 字符，但不应这样做，因为这会导致代码无法跨平台工作。

在 AIR 中定义 File 对象的 url 属性时，可以使用以下任一 URL 方案：

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

您可以使用 getRelativePath() 方法查找两个文件之间的相对路径：

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

getRelativePath() 方法的第二个参数 useDotDot 允许在结果中返回 .. 语法，以指示父目录：

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

文件名和路径名在 Windows 和 Mac OS 中不区分大小写。在以下示例中，两个 File 对象指向同一个文件：

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

不过，文档和目录名确实包括大小写。例如，以下代码假定在文档目录中有一个名为 AIR Test 的文件夹，如以下示例中所示：

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

canonicalize() 方法可以转换 nativePath 对象，以使用文件名或目录名的正确大写形式。在区分大小写的文件系统（如 Linux）上，当多个文件的名称只有大小写不同时，canonicalize() 方法将调整路径以匹配最先找到的文件（以文件系统确定的顺序）。

在 Windows 中，您还可以使用 canonicalize() 方法将短文件名（“8.3”名称）转换为长文件名，如以下示例中所示：

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

多种操作系统支持包文件和符号链接文件：

包 — 在 Mac OS 中，可以指定目录作为包，并且目录可以作为单个文件而非目录出现在 Mac OS Finder 中。

符号链接 — Mac OS、Linux 和 Windows Vista 支持符号链接。通过符号链接，文件可以指向磁盘上的另一个文件或目录。尽管符号链接与别名类似，不过它们并不相同。别名始终报告为文件（而不是目录），读取或写入别名或快捷方式从不影响它指向的原始文件或目录。另一方面，符号链接的行为则完全与它指向的文件或目录类似。可以将符号链接报告为文件或目录，并且读写符号链接影响的是符号链接所指向的文件或目录，而不影响其本身。此外，在 Windows 中，引用交接点（用于 NTFS 文件系统中）的 File 对象的 isSymbolicLink 属性设置为 true。

File 类包括 isPackage 和 isSymbolicLink 属性，用于检查 File 对象是否引用包或符号链接。

以下代码将遍历用户的桌面目录，列出不是 包的子目录：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !!desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

以下代码将遍历户的桌面目录，列出不是 符号链接的文件和目录：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

canonicalize() 方法可更改符号链接的路径，以指向该链接所引用的文件或目录。以下代码将遍历用户的桌面目录，报告由是符号链接的文件引用的路径：

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

File 对象的 spaceAvailable 属性是 File 位置的可用空间（以字节为单位）。例如，以下代码检查应用程序存储目录中的可用空间：

trace(File.applicationStorageDirectory.spaceAvailable); 

如果 File 对象引用一个目录，则 spaceAvailable 属性将指示可供文件使用的目录空间。如果 File 对象引用一个文件，则 spaceAvailable 属性将指示可供该文件使用的空间。如果 File 位置不存在，则 spaceAvailable 属性将设置为 0。如果 File 对象引用一个符号链接，则 spaceAvailable 属性将设置为符号链接指向的位置的可用空间。

通常，目录或文件的可用空间与包含该目录或文件的卷上的可用空间相同。不过，可用空间与磁盘配额及每个目录的空间限制有关。

将文件或目录添加到卷中通常需要比文件的实际大小或目录中内容的实际大小更多的空间。例如，操作系统可能需要更多空间来存储索引信息。或者，所需的磁盘扇区可能会使用额外的空间。此外，可用空间是动态变化的。因此，您不能期望为文件存储分配报告的全部空间。有关写入文件系统的信息，请参阅读取和写入文件。

StorageVolumeInfo.getStorageVolumes() 方法提供有关已安装的存储卷的更多详细信息（请参阅使用存储卷）。

在 AIR 2 中，您可以使用操作系统注册的用来打开某文件的应用程序打开该文件。例如，AIR 应用程序可以使用注册的用来打开文档文件的应用程序打开一个文档文件。使用 File 对象的 openWithDefaultApplication() 方法打开该文件。例如，以下代码打开用户桌面上名为 test.doc 的文件，并且打开该文件所用的是与文档文件相对应的默认应用程序：

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

以下代码使用户可以导航到一个 mp3 文件，并在用于播放 mp3 文件的默认应用程序中打开它：

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

无法对位于应用程序目录中的文件使用 openWithDefaultApplication() 方法。

AIR 会阻止您使用 openWithDefaultApplication() 方法打开某些文件。在 Windows 中，AIR 会阻止您打开某些文件类型的文件，例如 EXE 或 BAT。在 Mac OS 和 Linux 中，AIR 阻止您打开将在某些应用程序中启动的文件。（其中包括 Mac OS 中的 Terminal 和 AppletLauncher 以及 Linux 中的 csh、bash 或 ruby。）尝试使用 openWithDefaultApplication() 方法打开其中一个文件将导致异常。有关阻止打开的文件类型的完整列表，请参阅 File.openWithDefaultApplication() 方法的语言参考条目。