使用 AIR 中的 File 对象

您可以将 File 对象指向用户的主目录。以下代码将设置 File 对象以使其指向主目录中的 AIR Test 子目录：

var file:File = File.userDirectory.resolvePath("AIR Test"); 

您可以将 File 对象指向用户的文档目录。以下代码设置 File 对象以指向文档目录中的 AIR Test 子目录：

var file:File = File.documentsDirectory.resolvePath("AIR Test");

您可以使 File 对象指向桌面。以下代码设置 File 对象以使其指向桌面的 AIR Test 子目录：

var file:File = File.desktopDirectory.resolvePath("AIR Test");

您可以使 File 对象指向应用程序存储目录。对于每个 AIR 应用程序，有一个唯一的关联路径用于定义应用程序存储目录。此目录对每个应用程序和用户是唯一的。您可以使用此目录存储特定于用户、特定于应用程序的数据（如用户数据或首选参数文件）。例如，以下代码将使 File 对象指向应用程序存储目录中包含的首选参数文件 prefs.xml：

var file:File = File.applicationStorageDirectory; 
file = file.resolvePath("prefs.xml");

应用程序存储目录位置通常基于用户名称和应用程序 ID。此处提供了下列文件系统位置以帮助您调试应用程序。您应该始终使用 File.applicationStorage 属性或 app-storage: URI 方案解析此目录中的文件：

• 在 Mac 操作系统上 — 因 AIR 版本而异：

  AIR 3.2 和早期版本 ： /Users/user name/Library/Preferences/ applicationID /Local Store/

  AIR 3.3 和更高版本 ： path /Library/Application Support/ applicationID /Local Store ，其中 path 为 /Users/ username /Library/Containers/ bundle-id /Data （沙箱环境）或 /Users/ username （在沙箱环境外运行时）

  例如 (AIR 3.2)：

  /Users/babbage/Library/Preferences/com.example.TestApp/Local Store

• 在 Windows 中，位于 Documents and Settings 目录下的以下位置：

  C:\Documents and Settings\user name \Application Data\ applicationID \Local Store\

  例如：

  C:\Documents and Settings\babbage\Application Data\com.example.TestApp\Local Store

• 在 Linux 中位于：

  /home/ user name /.appdata/ applicationID /Local Store/

  例如：

  /home/babbage/.appdata/com.example.TestApp/Local Store

• 在 Android 上，在以下位置：

  /data/data/ androidPackageID / applicationID/Local Store

  例如：

  /data/data/air.com.example.TestApp/com.example.TestApp/Local Store

通过 File.applicationStorageDirectory 创建的 File 对象的 URL（和 url 属性）将使用 app-storage URL 方案（请参阅 支持的 AIR URL 方案 ），如下所示：

var dir:File = File.applicationStorageDirectory; 
dir = dir.resolvePath("preferences"); 
trace(dir.url); // app-storage:/preferences

您可以使 File 对象指向应用程序的安装目录，即应用程序目录。您可以使用 File.applicationDirectory 属性引用此目录。您可以使用此目录检查应用程序描述符文件或与应用程序一起安装的其他资源。例如，以下代码将使 File 对象指向应用程序目录中名为 images 的目录：

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 

通过 File.applicationDirectory 创建的 File 对象的 URL（和 url 属性）将使用 app URL 方案（请参阅 支持的 AIR URL 方案 ），如下所示：

var dir:File = File.applicationDirectory; 
dir = dir.resolvePath("images"); 
trace(dir.url); // app:/images

您可以使用 File.cacheDirectory 属性使 File 对象指向操作系统的临时目录或缓存目录。该目录包含的是对应用程序运行并非必需的临时文件，因此删除这些文件时不会产生问题或对用户造成数据损失。

在大多数操作系统中，缓存目录都是临时目录。在 iOS 上，缓存目录对应于应用程序库的 Caches 目录。该目录中的文件不会备份到在线存储中，如果设备的可用存储空间过少，操作系统可能会将这些文件删除。有关详细信息，请参阅 控制文件的备份和缓存 。

File.getRootDirectories() 方法列出所有根卷，如 Windows 计算机中的 C: 和已装好的卷。在 Mac OS 和 Linux 中，此方法始终返回计算机的唯一根目录（“/”目录）。 StorageVolumeInfo.getStorageVolumes() 方法提供有已关装的存储卷的更多详细信息（请参阅 使用存储卷 ）。

通过设置 File 对象的 nativePath 属性，可以使 File 对象指向某个明确的目录，如以下示例中所示（在 Windows 中）：

var file:File = new File(); 
file.nativePath = "C:\\AIR Test";

重要说明： 通过这种方式指向明确的路径会导致代码无法跨平台使用。例如，上面的示例仅适用于 Windows。您可以使用 File 类的静态属性（如 File.applicationStorageDirectory ）来定位跨平台工作的目录。然后使用 resolvePath() 方法（请参阅下一节）导航到相对路径。

您可以使用 resolvePath() 方法获取相对于其他给定路径的路径。例如，以下代码将设置 File 对象以使其指向用户主目录中的“AIR Test”子目录：

var file:File = File.userDirectory; 
file = file.resolvePath("AIR Test");

您还可以使用 File 对象的 url 属性以使该对象指向基于 URL 字符串的目录，如下所示：

var urlStr:String = "file:///C:/AIR Test/"; 
var file:File = new File() 
file.url = urlStr; 

有关详细信息，请参阅 修改文件路径 。

File 类包括 browseForDirectory() 方法，它表示系统对话框，在该对话框中用户可以选择要分配给对象的目录。 browseForDirectory() 方法为异步方法。如果用户选择一个目录并单击“打开”按钮，File 对象将调度一个 select 事件；如果用户单击“取消”按钮，它将调度一个 cancel 事件。

例如，以下代码能使用户选择一个目录，并在选择后输出目录路径：

var file:File = new File(); 
file.addEventListener(Event.SELECT, dirSelected); 
file.browseForDirectory("Select a directory"); 
function dirSelected(e:Event):void { 
    trace(file.nativePath); 
}

通过检查调用应用程序时所调度的 InvokeEvent 对象的 currentDirectory 属性，可以获取从中调用应用程序的目录位置。有关详细信息，请参阅 捕获命令行参数 。

重要说明： 指向明确的路径会导致代码无法跨平台工作。例如，路径 C:/foo.txt 仅适用于 Windows。您可以使用 File 类的静态属性（如 File.applicationStorageDirectory ）来定位跨平台工作的目录。然后使用 resolvePath() 方法（请参阅 修改文件路径 ）导航到相对路径。

您可以使用 File 对象的 url 属性以使该对象指向基于 URL 字符串的文件或目录，如下所示：

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File() 
file.url = urlStr; 

您还可以将 URL 传递到 File() 构造函数，如下所示：

var urlStr:String = "file:///C:/AIR Test/test.txt"; 
var file:File = new File(urlStr); 

url 属性始终返回 URL 的 URI 编码版本（例如，空格替换为 %20 ）：

file.url = "file:///c:/AIR Test"; 
trace(file.url); // file:///c:/AIR%20Test 

您还可以使用 File 对象的 nativePath 属性设置明确的路径。例如，在 Windows 计算机中运行以下代码，可以设置 File 对象以使其指向 C: 驱动器的 AIR Test 子目录中的 test.txt 文件：

var file:File = new File(); 
file.nativePath = "C:/AIR Test/test.txt"; 

您还可以将此路径传递到 File() 构造函数，如下所示：

var file:File = new File("C:/AIR Test/test.txt"); 

请使用正斜杠 (/) 字符作为 nativePath 属性的路径分隔符。在 Windows 上，还可以使用反斜杠 (\) 字符，但这会导致应用程序无法跨平台工作。

有关详细信息，请参阅 修改文件路径 。

您可以使用 File 对象的 getDirectoryListing() 方法获取指向位于某目录根级的文件和子目录的 File 对象数组。有关详细信息，请参阅 枚举目录 。

File 类包括以下方法，它们表示系统对话框，在该对话框中用户可以选择要分配给对象的文件：

• browseForOpen()

• browseForSave()

• browseForOpenMultiple()

这些方法均为异步方法。当用户选择一个文件时（或者，对于 browseForSave() 选择一个目标路径时）， browseForOpen() 和 browseForSave() 方法将调度 select 事件。对 browseForOpen() 和 browseForSave() 方法，在进行选择后目标 File 对象将指向所选的文件。当用户选择多个文件时， browseForOpenMultiple () 方法调度一个 selectMultiple 事件。 selectMultiple 事件的类型是 FileListEvent，它具有一个 files 属性，该属性是一个 File 对象数组（指向所选的文件）。

例如，以下代码向用户显示“Open”对话框，在该对话框中用户可以选择文件：

var fileToOpen:File = File.documentsDirectory; 
selectTextFile(fileToOpen); 
 
function selectTextFile(root:File):void 
{ 
    var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml"); 
    root.browseForOpen("Open", [txtFilter]); 
    root.addEventListener(Event.SELECT, fileSelected); 
} 
 
function fileSelected(event:Event):void 
{ 
    trace(fileToOpen.nativePath); 
} 

当您调用浏览方法时，如果应用程序已打开了其他浏览器对话框，则运行时会引发一个错误异常。