管理窗口

若要操作窗口，必须首先获取窗口实例。可以从以下任一位置获取窗口实例：

• 用于创建窗口的本机窗口构造函数：

  var win:NativeWindow = new NativeWindow(initOptions);

• 窗口舞台的 nativeWindow 属性：

  var win:NativeWindow = stage.nativeWindow;

• 窗口中显示对象的 stage 属性：

  var win:NativeWindow = displayObject.stage.nativeWindow;

• 由窗口调度的本机窗口事件的 target 属性：

  private function onNativeWindowEvent(event:NativeWindowBoundsEvent):void 
  { 
      var win:NativeWindow = event.target as NativeWindow; 
  }

• 窗口中显示的 HTML 页的 nativeWindow 属性：

  var win:NativeWindow = htmlLoader.window.nativeWindow;

• NativeApplication 对象的 activeWindow 和 openedWindows 属性：

  var nativeWin:NativeWindow = NativeApplication.nativeApplication.activeWindow; 
  var firstWindow:NativeWindow = NativeApplication.nativeApplication.openedWindows[0];

  NativeApplication.nativeApplication.activeWindow 引用应用程序的活动窗口（但如果该活动窗口不是此 AIR 应用程序的窗口，则返回 null ）。 NativeApplication.nativeApplication.openedWindows 数组包含 AIR 应用程序中尚未关闭的所有窗口。

由于 Flex mx:WindowedApplication 和 mx:Window 对象都是显示对象，因此使用 stage 属性即可轻松地在 MXML 文件中引用应用程序窗口，如下所示：

<?xml version="1.0" encoding="utf-8"?> 
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" applicationComplete="init();"> 
    <mx:Script> 
        <![CDATA[ 
            import flash.display.NativeWindow; 
 
            public function init():void{ 
                var appWindow:NativeWindow = this.stage.nativeWindow; 
                //set window properties 
                appWindow.visible = true; 
            } 
        ]]> 
    </mx:Script> 
</WindowedApplication

若要激活窗口，请调用 NativeWindow activate() 方法。激活窗口会将该窗口置于前面，为其提供键盘和鼠标焦点，并在必要时通过还原窗口或将 visible 属性设置为 true 来使其可见。激活窗口不会更改应用程序中其他窗口的顺序。调用 activate() 方法会导致窗口调度 activate 事件。

若要在不激活的情况下显示隐藏窗口，请将 visible 属性设置为 true 。此操作使该窗口置于前面，但不会向它分配焦点。

若要从视图中隐藏窗口，请将其 visible 属性设置为 false 。隐藏窗口会禁止窗口和任何相关任务栏图标的显示，并且在 Mac OS X 中还会禁止窗口菜单中条目的显示。

更改窗口的可见性时，该窗口所拥有的所有窗口的可见性也将发生更改。例如，如果隐藏窗口，则该窗口所拥有的所有窗口也将隐藏。

AIR 提供几种方法来直接更改窗口的显示顺序。可以将窗口的显示顺序向前或向后移动；可以将窗口移动到其他窗口的前面或后面。同时，用户可以通过激活窗口来对窗口进行重新排序。

可以通过将窗口的 alwaysInFront 属性设置为 true 来使该窗口位于其他窗口的前面。如果多个窗口都具有此设置，则这些窗口的显示顺序是它们相互之间的排序顺序，而且它们始终排序在 alwaysInFront 设置为 false 的窗口前面。

即使 AIR 应用程序未处于活动状态，最上面组中的窗口也显示在其他应用程序中窗口的前面。由于此行为会阻碍用户查看其他窗口，因此应仅在必要和适当时才能将 alwaysInFront 设置为 true 。经调整的使用示例包括：

• 工具提示、弹出列表、自定义菜单或组合框等控件的临时弹出窗口。 由于这些窗口在失去焦点后将关闭，因此可以避免阻碍用户查看其他窗口的不便。

• 极其紧急的错误消息和警告。在可能发生不可撤销的更改时，如果用户未及时响应，则可能调整为将警告窗口置于最前面。但是，可以按正常的窗口显示顺序处理大多数错误消息和警告。

• 短期弹出式窗口。

如果窗口拥有其他窗口，则这些窗口始终按顺序显示在该窗口前面。如果对拥有其他窗口的某个窗口调用 orderToFront() ，或者在该窗口上将 alwaysInFront 设置为 true ，则所有者窗口将显示在其他窗口前面，该窗口所拥有的窗口随该窗口一起重新排序，且所拥有的窗口仍显示在所有者的前面。

在同一窗口所拥有的窗口中，对拥有的窗口调用窗口顺序方法可正常工作，但同时会更改整个拥有的窗口组相对于该组之外的其他窗口的排序顺序。例如，如果对某个拥有的窗口调用 orderToFront() ，则该窗口、其所有者以及同一所有者所拥有的所有其他窗口都将移动到窗口显示列表的前面。

NativeWindow 类提供以下属性和方法来设置一个窗口相对于其他窗口的显示顺序：

在 Linux 操作系统中，不同的窗口管理器对于窗口显示顺序实施不同的规则：

• 在某些窗口管理器中，实用程序窗口始终显示于普通窗口之前。

• 在某些窗口管理器中，将 alwaysInFront 设置为 true 的全屏窗口始终显示于其他同样将 alwaysInFront 设置为 true 的窗口之前。

若要关闭窗口，请使用 NativeWindow.close() 方法。

关闭窗口会卸载该窗口的内容，但如果其他对象引用了此内容，则不会破坏内容对象。 NativeWindow.close() 方法以异步方式执行，该窗口中包含的应用程序在关闭过程中继续运行。该 close 方法在关闭操作完成时调度 close 事件。从技术角度而言，NativeWindow 对象仍然有效，但访问已关闭窗口上的大多数属性和方法会生成 IllegalOperationError。不能重新打开已关闭窗口。检查窗口的 closed 属性以测试窗口是否已关闭。若要仅从视图中隐藏窗口，请将 NativeWindow.visible 属性设置为 false 。

如果 Nativeapplication.autoExit 属性为 true （默认情况），则应用程序在其最后一个窗口关闭后退出。

当所有者关闭时，该所有者所拥有的所有窗口也将同时关闭。所拥有的窗口不会调度关闭事件，因此无法阻止关闭这些窗口。已调度 close 事件。

在窗口使用系统镶边时，可以通过侦听和取消相应事件的默认行为来取消用户与该窗口的交互。例如，在用户单击系统镶边关闭按钮后，将调度 closing 事件。如果任何已注册的侦听器调用了事件的 preventDefault() 方法，则该窗口不会关闭。

在窗口不使用系统镶边时，不会在执行预期更改之前自动调度这些更改的通知事件。因此，如果调用关闭窗口、更改窗口状态的方法，或者设置任何窗口范围属性，则无法取消更改。若要在执行窗口更改前通知应用程序中的组件，则应用程序逻辑可以使用窗口的 dispatchEvent() 方法调度相关的通知事件。

例如，以下逻辑实现窗口关闭按钮的可取消事件处理函数：

public function onCloseCommand(event:MouseEvent):void{ 
    var closingEvent:Event = new Event(Event.CLOSING,true,true); 
    dispatchEvent(closing); 
    if(!closingEvent.isDefaultPrevented()){ 
        win.close(); 
    } 
} 

如果侦听器调用事件的 preventDefault() 方法，则 dispatchEvent() 方法返回 false 。但是，由于其他原因，它还可以返回 false ，因此最好明确使用 isDefaultPrevented() 方法来测试是否应取消更改。

若要最大化窗口，请使用 NativeWindow maximize() 方法。

myWindow.maximize(); 

若要最小化窗口，请使用 NativeWindow minimize() 方法。

myWindow.minimize(); 

若要还原窗口（即，使其返回最小化或最大化操作之前的大小），请使用 NativeWindow restore() 方法。

myWindow.restore(); 

当所有者窗口最小化或还原时，所拥有的窗口也将最小化和还原。所拥有的窗口在最小化时不会调度任何事件，因为是对其所有者执行的最小化操作。

在 Linux 操作系统中，不同的窗口管理器对于设置窗口显示状态实施不同的规则：

• 在某些窗口管理器中无法将实用程序窗口最大化。

• 如果为窗口设置了最大大小，则某些窗口不允许将窗口最大化。某些其他窗口管理器将显示状态设置为最大化，但不调整窗口大小。在这两种情况下，都不会调度显示状态更改事件。

• 某些窗口管理器不遵守窗口的 maximizable 或 minimizable 设置。

以下简短的 MXML 应用程序演示 Window maximize() 、 minimize() 、 restore() 和 close() 方法：

<?xml version="1.0" encoding="utf-8"?> 
 
<mx:WindowedApplication  
    xmlns:mx="http://www.adobe.com/2006/mxml"  
    layout="vertical"> 
     
     
    <mx:Script> 
    <![CDATA[ 
    public function minimizeWindow():void 
    { 
        this.stage.nativeWindow.minimize(); 
    } 
 
    public function maximizeWindow():void 
    { 
        this.stage.nativeWindow.maximize(); 
    }           
     
    public function restoreWindow():void 
    { 
        this.stage.nativeWindow.restore(); 
    }           
 
    public function closeWindow():void 
    { 
        this.stage.nativeWindow.close(); 
    } 
    ]]> 
    </mx:Script> 
 
    <mx:VBox> 
        <mx:Button label="Minimize" click="minimizeWindow()"/> 
        <mx:Button label="Restore" click="restoreWindow()"/> 
        <mx:Button label="Maximize" click="maximizeWindow()"/> 
        <mx:Button label="Close" click="closeWindow()"/> 
    </mx:VBox> 
 
</mx:WindowedApplication>

以下用于 Flash 的 ActionScript 示例创建四个可单击的文本字段，这些字段分别触发 NativeWindow minimize() 、 maximize() 、 restore() 和 close() 方法：

package 
{ 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import flash.text.TextField; 
     
    public class MinimizeExample extends Sprite 
    { 
        public function MinimizeExample():void  
        { 
            var minTextBtn:TextField = new TextField(); 
            minTextBtn.x = 10; 
            minTextBtn.y = 10; 
            minTextBtn.text = "Minimize"; 
            minTextBtn.background = true; 
            minTextBtn.border = true; 
            minTextBtn.selectable = false; 
            addChild(minTextBtn); 
            minTextBtn.addEventListener(MouseEvent.CLICK, onMinimize); 
         
            var maxTextBtn:TextField = new TextField(); 
            maxTextBtn.x = 120; 
            maxTextBtn.y = 10; 
            maxTextBtn.text = "Maximize"; 
            maxTextBtn.background = true; 
            maxTextBtn.border = true; 
            maxTextBtn.selectable = false; 
            addChild(maxTextBtn); 
            maxTextBtn.addEventListener(MouseEvent.CLICK, onMaximize); 
         
            var restoreTextBtn:TextField = new TextField(); 
            restoreTextBtn.x = 230; 
            restoreTextBtn.y = 10; 
            restoreTextBtn.text = "Restore"; 
            restoreTextBtn.background = true; 
            restoreTextBtn.border = true; 
            restoreTextBtn.selectable = false; 
            addChild(restoreTextBtn); 
            restoreTextBtn.addEventListener(MouseEvent.CLICK, onRestore); 
             
            var closeTextBtn:TextField = new TextField(); 
            closeTextBtn.x = 340; 
            closeTextBtn.y = 10; 
            closeTextBtn.text = "Close Window"; 
            closeTextBtn.background = true; 
            closeTextBtn.border = true; 
            closeTextBtn.selectable = false; 
            addChild(closeTextBtn); 
            closeTextBtn.addEventListener(MouseEvent.CLICK, onCloseWindow); 
        } 
        function onMinimize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.minimize(); 
        } 
        function onMaximize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.maximize(); 
        } 
        function onRestore(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.restore(); 
        } 
        function onCloseWindow(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.close(); 
        } 
    } 
}

在窗口使用系统镶边时，该镶边提供用于调整窗口大小和在桌面范围内移动窗口的拖动控件。如果窗口不使用系统镶边，则必须添加您自己的控件以允许用户调整窗口大小和移动窗口。

以下示例说明如何对窗口启动调整大小和移动操作：

package 
{ 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import flash.display.NativeWindowResize; 
 
    public class NativeWindowResizeExample extends Sprite 
    { 
        public function NativeWindowResizeExample():void 
        { 
            // Fills a background area. 
            this.graphics.beginFill(0xFFFFFF); 
            this.graphics.drawRect(0, 0, 400, 300); 
            this.graphics.endFill(); 
     
            // Creates a square area where a mouse down will start the resize. 
            var resizeHandle:Sprite =  
                createSprite(0xCCCCCC, 20, this.width - 20, this.height - 20); 
            resizeHandle.addEventListener(MouseEvent.MOUSE_DOWN, onStartResize); 
     
            // Creates a square area where a mouse down will start the move. 
            var moveHandle:Sprite = createSprite(0xCCCCCC, 20, this.width - 20, 0); 
            moveHandle.addEventListener(MouseEvent.MOUSE_DOWN, onStartMove); 
        } 
     
        public function createSprite(color:int, size:int, x:int, y:int):Sprite 
        { 
            var s:Sprite = new Sprite(); 
            s.graphics.beginFill(color); 
            s.graphics.drawRect(0, 0, size, size); 
            s.graphics.endFill(); 
            s.x = x; 
            s.y = y; 
            this.addChild(s);     
            return s;         
        } 
     
        public function onStartResize(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.startResize(NativeWindowResize.BOTTOM_RIGHT); 
        } 
 
        public function onStartMove(event:MouseEvent):void 
        { 
            this.stage.nativeWindow.startMove(); 
        } 
    } 
}