文本布局框架模型

您可以通过属性分配对任何 FlowElement 设置格式。FlowElement 类实现 ITextLayoutFormat 接口，因此 FlowElement 类的任一子类也必须实现该接口。此要求意味着文本流层次中的任何元素都包含与 ITextLayoutFormat 接口定义的格式相对应的属性。

例如，以下代码显示如何为 ParagraphElement 实例指定单个格式：

var p:ParagraphElement = new ParagraphElement(); 
p.fontSize = 18; 
p.fontFamily = "Arial";

您可以使用 TextLayoutFormat 类向 FlowElement 应用格式。可使用此类创建包含所需的所有格式设置值的特定格式设置对象。然后，将该对象指定给任何 FlowElement 对象的 format 属性。TextLayoutFormat 和 FlowElement 都实现 ITextLayoutFormat 类。这种安排确保两个类都包含同样的格式属性。

首先，创建 TextLayoutFormat 类的实例来存储格式设置信息。以后可以将该格式设置对象指定给任意一个 FlowElement 实例：

var fmt:TextLayoutFormat = new TextLayoutFormat(); 

然后，为 TextLayoutFormat 属性指定值，以反映要为文本设置的样式。TextLayoutFormat 类包含几十个属性，可对应常见的样式（例如，字体大小和边距）。

fmt.fontSize = 18; 
fmt.fontFamily = "Arial";

第三，将该 TextLayoutFormat 对象指定给 FlowElement 的格式属性：

var p:ParagraphElement = new ParagraphElement(); 
p.format = fmt;

在设置 format 属性的值后，可将 TextLayoutFormat 对象的当前状态应用到 FlowElement。如果稍后更改 TextLayoutFormat 对象，FlowElement 中不会反映这些更改，除非重新分配它。

p.textIndent = 15; 
var fmt:TextLayoutFormat = new TextLayoutFormat(); 
fmt.fontSize = 18; // Note this does NOT set the value of the textIndent property 
p.format = fmt;

格式继承与文本流层次一致。如果将 TextLayoutFormat 的实例指定给带有子代的 FlowElement 实例，框架将启动一个称为级联的过程。在级联过程中，框架递归检查从您的 FlowElement 继承的层次中的每个节点。然后，它确定是否将继承的值指定给各格式设置属性。在级联过程中应用下列规则：

例如，如果在 TextFlow 级别设置 fontSize 值，则该设置将应用于 TextFlow 中的所有元素。换句话说，这些值按照文本流层次向下级联。不过，您可以通过直接对给定元素指定新值来覆盖该元素中的值。举个反例，如果您在 TextFlow 级别设置 backgroundColor 值，TextFlow 的子项不继承该值。backgroundColor 属性不是级联期间从其父项继承的。通过将每一子项中的 backgroundColor 属性设置为 flashx.textLayout.formats.FormatValue.INHERIT，可以覆盖此行为。

格式继承和指定（直接指定及通过格式设置对象指定）的交叉可能导致意外的结果。对 FlowElement 指定 TextLayoutFormat 对象可覆盖以前设置的任何值。进行这种覆盖时不考虑以前的值如何设置。例如，如果直接使用 SpanElement 的 fontSize 属性指定 SpanElement 的 fontSize 值，随后创建一个 TextLayoutFormat 对象并将该对象指定给 SpanElement 的 format 属性，则 SpanElement 将采用 TextLayoutFormat 对象中的 fontSize 值。这非常重要，因为 TextLayoutFormat 对象的各个属性的默认值都是 undefined。如果您忘记设置 TextLayoutFormat 对象的 fontSize 属性，则可能会意外更改 SpanElement 的字体大小。下例显示的是此情况的示例，在该例中，通过指定 TextLayoutFormat 对象将 fontSize 属性设置为 undefined：

var span:SpanElement = new SpanElement(); 
span.text = "Hello, World"; 
span.fontSize = 48; 
var ca:TextLayoutFormat = new TextLayoutFormat(); 
ca.fontFamily = "Helvetica"; 
span.format = ca;

指定 TextLayoutFormat 对象会将 fontSize 的值重置为 undefined，这意味着该值现在继承自祖先元素。要保持 fontSize 属性的值，请将 SpanElement 的现有 TextLayoutFormat 对象作为参数发送给 TextLayoutFormat 的构造函数：

var span:SpanElement = new SpanElement(); 
span.text = "Hello, World"; 
span.fontSize = 48; 
var fmt:TextLayoutFormat = new TextLayoutFormat(span.format); 
fmt.fontFamily = "Helvetica"; 
span.format = fmt;

文本布局框架可以导入纯文本、简单 HTML 文本或文本布局标记格式的 XML。

要导入纯文本，请使用 importToFlow() 静态方法中的第二个参数指定该格式。在以下示例中，将纯文本指定为 importToFlow() 方法的第二个参数，并省略可选的第三个参数：

var text:String = "Hello World, this is plain text"; 
var tf:TextFlow = TextConverter.importToFlow(text, TextConverter.PLAIN_TEXT_FORMAT);

HTML 导入支持旨在匹配 TextField 类提供的简单 HTML 支持。例如，以下代码导入一段简单的 HTML 文本：

var hyperText:String = "<p><span>Hello, World</span></p>"; 
var tf:TextFlow = TextConverter.importToFlow(hyperText, TextConverter.HTML_FORMAT);

文本布局标记是文本布局框架中存储的文本的 XML 表示形式。XML 会对流层次的结构进行镜像，并为该框架支持的文本和格式设置提供最高的保真度。要导入文本布局标记格式的文本，可将 TextConverter.TEXT_LAYOUT_FORMAT 指定为 importToFlow() 方法的第二个参数，如以下示例所示：

var markup:XML = <TextFlow><p><span>Hello, World</span></p></TextFlow>; 
var tf:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);

文本布局框架还可以将文本导出为以下四种格式之一：纯文本、HTML、FXG 或文本布局标记。要从现有 TextFlow 实例导出，可调用 TextConverter.export() 方法。

export() 方法包含三个必需参数和一个可选参数。第一个参数是您要从中导出的 TextFlow 实例。第二个参数是要应用于导出文本的三种格式（纯文本、FXG 或文本布局标记）之一。第三个参数用于指定导出文本的数据类型。可以选择 String 类型或 XML 类型。第四个参数即最后一个参数是可选的，用于指定 ImportExportConfiguration 类的实例。

以下示例导入纯文本格式的字符串，并将该字符串导出为文本布局标记格式的 XML 对象：

var ptext:String = "Hello, World"; 
var flow:TextFlow = TextConverter.importToFlow(ptext, TextConverter.PLAIN_TEXT_FORMAT); 
var out:XML = TextConverter.export(flow, TextConverter.TEXT_LAYOUT_FORMAT, 
                                ConversionType.XML_TYPE );

文本布局框架标记使 TextFlow 中的文本具有高保真表示形式，因为标记语言不仅为每个 TextFlow 层次的基本元素提供标签，而且为可用于 TextLayoutFormat 类的所有格式设置属性提供属性。

下表包含可以在 TLF 标记中使用的标签。

格式设置属性位于 TextLayoutFormat 类中，可作为 XML 属性直接指定给元素标签。例如，在以下文本布局框架标记中，整个 TextFlow 的 fontSize 是 14。第二个段落是蓝色的，但最后的 SpanElement 除外。最后一个 SpanElement 是红色的，因为最后一个 SpanElement 中的颜色属性覆盖了层次结构中其父级的颜色属性。

<TextFlow xmlns="http://ns.adobe.com/textLayout/2008" fontSize="14"> 
    <p>This is an example of Text Layout Framework Markup.</p> 
    <p color="#0000ff"> 
        <span>This is the first span of the second paragraph.</span> 
        <span color="#ff0000">This is the second span of the second                                         paragraph.</span> 
    </p> 
</TextFlow>;

您也可以使用格式标签创建一个命名格式设置属性集，其行为类似于 TextLayoutFormat 类的实例。在以下示例中，将名为“English”的命名属性集应用到一段行内文本。

<TextFlow xmlns="http://ns.adobe.com/textLayout/2008" fontSize="14"> 
    <format id="English" locale="en" fontFamily="Minion Pro"/> 
    <p paragraphSpaceAfter="15"><span>This is supposed to use the default font</span></p> 
    <p paragraphSpaceAfter="15"><span format="English">This is supposed to be in Minion Pro via a named format</span></p> 
    <p><span fontFamily="Minion Pro">This is supposed to be in Minion Pro via a fontFamily attribute</span></p> 
</TextFlow>

如果同时使用命名集和通过直接指定元素标签来设置属性，则应用直接指定的值。